I_AssetClassByCompanyCode

@AbapCatalog: {sqlViewName: 'ICOMPCODEASSETCL', preserveKey: true}
@EndUserText.label: 'Asset Class related to Company Code'
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: { representativeKey: 'AssetClass',
                usageType.serviceQuality: #C,
                usageType.sizeCategory: #S,
                usageType.dataClass: #CUSTOMIZING }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions: true

@Search.searchable: true


define view I_AssetClassByCompanyCode
  as select from P_AssetClassByCompanyCode

  association [0..1] to I_AssetClass     as _AssetClass  on $projection.AssetClass = _AssetClass.AssetClass
  association [1..1] to I_CompanyCode    as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..*] to I_AssetClassText as _Text        on $projection.AssetClass = _Text.AssetClass
  association [0..1] to I_Language       as _Language    on $projection.language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
  key CompanyCode,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key AssetClass,

      FixedAssetGroup, //Not supported with inactive BF

      AssetScreenLayout, //Not supported with inactive BF

      AssetClassDownPaymentIsAllowed, //Not supported with inactive BF

      AssetClassIsBlocked, //Not supported with inactive BF

      InventoryIsCounted, //Not supported with inactive BF

      FixedAssetPropertyType, //Not supported with inactive BF

      PropertyClass, //Not supported with inactive BF

      AreaSizeUnit, //Not supported with inactive BF


      @Semantics.text
      _AssetClass._Text[1:Language = $session.system_language].AssetClassName,
      @ObjectModel.foreignKey.association: '_Language'
      @Consumption: {filter.hidden: true, hidden: true}
      _AssetClass._Text[1:Language = $session.system_language].Language,


      @Consumption.hidden: true
      AssetAuthorizationContext, //Needed for DCL


      _CompanyCode,
      _AssetClass,
      _Text,
      _Language
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ASSETCLASS",
"I_ASSETCLASSTEXT",
"P_ASSETCLASSBYCOMPANYCODE"
],
"ASSOCIATED":
[
"I_ASSETCLASS",
"I_ASSETCLASSTEXT",
"I_COMPANYCODE",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/