I_AllocationSenderElementTP

@AbapCatalog.sqlViewName: 'ALOSENELEMENTTP'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking:#NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Allocation Sender Element TP'

@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #M

@VDM.viewType: #TRANSACTIONAL
@ObjectModel:
{
  transactionalProcessingEnabled:true,
  writeDraftPersistence: 'ALOSENELEMENTTPD',
  semanticKey: ['AllocationType', 'AllocationCycle', 'AllocationCycleStartDate', 'AllocationCycleSegment', 'AllocElementSequenceNumber' ],
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true

//  entityChangeStateId: 'LastChangeTime'

}
define view I_AllocationSenderElementTP as 
select from I_AllocationElement
  inner join I_AllocationContextType as Context on Context.AllocationType = I_AllocationElement.AllocationType

  association [1..1] to I_AllocationSegmentTP   as _Segment                           on  $projection.AllocationType           = _Segment.AllocationType
                                                                                      and $projection.AllocationCycle          = _Segment.AllocationCycle
                                                                                      and $projection.AllocationCycleStartDate = _Segment.AllocationCycleStartDate
                                                                                      and $projection.AllocationCycleSegment   = _Segment.AllocationCycleSegment
                                                                                      
  association [1..1] to I_AllocationCycleTP     as _Cycle                             on  $projection.AllocationType           = _Cycle.AllocationType
                                                                                      and $projection.AllocationCycle          = _Cycle.AllocationCycle
                                                                                      and $projection.AllocationCycleStartDate = _Cycle.AllocationCycleStartDate                                                                                      
{ 
  key I_AllocationElement.AllocationType,
  key AllocationCycle,
  key AllocationCycleStartDate,
  key AllocationCycleSegment,
  key AllocElementSequenceNumber,
  AllocationElement1,
  AllocationElement2,
  AllocationElement3,
  AllocationElement4,
  AllocationElement5,
  AllocationElement6,
  AllocationElement7,
  AllocationElement8,
  AllocationElement9,
  AllocationElement10,
  AllocationElementValue,
  AllocSenderReceiverVariant,
  
  I_AllocationElement._Segment.AllocationCurrency,
  
  @ObjectModel.association.type: #TO_COMPOSITION_PARENT
  _Segment,
  @ObjectModel.association.type: #TO_COMPOSITION_ROOT
  _Cycle
}
where AllocSenderReceiverVariant = 'S'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ALLOCATIONCONTEXTTYPE",
"I_ALLOCATIONELEMENT",
"I_ALLOCATIONSEGMENT"
],
"ASSOCIATED":
[
"I_ALLOCATIONCYCLETP",
"I_ALLOCATIONSEGMENTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/