I_AllocationRun

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'IALLOCATIONRUN'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Allocation Run'

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M

@VDM.viewType: #BASIC

define view I_AllocationRun
  as select from alloc_run_info

  association [0..*] to I_AllocationRunStatusText    as _StatusText      on $projection.AllocationRunStatus = _StatusText.AllocationRunStatus

  association [0..*] to I_AllocActualPlanVariantText as _ActualPlanText  on $projection.AllocationActualPlanVariant = _ActualPlanText.AllocationActualPlanVariant

  association [1]    to I_UserContactCard            as _UserContactCard on $projection.AllocationRunUser = _UserContactCard.ContactCardID

  association [0..1] to I_AllocationContextType      as _Context         on $projection.AllocationType = _Context.AllocationType

  association [0..*] to I_AllocationPostingTypeText  as _PostingTypeText on $projection.AllocationPostingType = _PostingTypeText.AllocationPostingType

  association [0..*] to P_AllocationRunTestText      as _TestText        on _TestText.AllocationRunIsTest = $projection.AllocationRunIsTest

  association [0..*] to P_AllocationRunReversedText  as _ReversedText    on _ReversedText.AllocationRunIsReversed = $projection.AllocationRunIsReversed

{
  key run_id                                                         as UniversalAllocationRun,
      name                                                           as UniversalAllocationRunName,
      start_date                                                     as AllocationRunStartDate,
      start_time                                                     as AllocationRunStartTime,
      run_duration                                                   as AllocationRunDurationInSeconds, //AllocationRunDuration,

      end_date                                                       as AllocationRunEndDate,
      end_time                                                       as AllocationRunEndTime,
      book_date                                                      as AllocationRunBookingDate,
      book_time                                                      as AllocationRunBookingTime,
      book_duration                                                  as AllocRunBkgDurationInSeconds, //AllocationRunBookingDuration,

      cast(run_user as fco_alloc_run_executed_user preserving type ) as AllocationRunUser,
      ledger                                                         as Ledger,
      alloc_context                                                  as AllocationType,
      _Context._Text[1:Language = $session.system_language].AllocationContextTypeText,
      alloc_type                                                     as AllocationPostingType,
      _PostingTypeText[1:Language = $session.system_language].AllocationPostingTypeText,
      actual_plan                                                    as AllocationActualPlanVariant,
      _ActualPlanText[1:Language = $session.system_language].AllocActualPlanVariantText,
      status                                                         as AllocationRunStatus,
      _StatusText[1:Language = $session.system_language].AllocationRunStatusText,
      fiscal_year                                                    as FiscalYear,
      start_period                                                   as AllocationRunStartPeriod,
      end_period                                                     as AllocationRunEndPeriod,
      ref_start_period                                               as AllocRunReferenceStartPeriod,
      ref_end_period                                                 as AllocRunReferenceEndPeriod,
      ref_fiscal_year                                                as AllocRunRefStartFiscalYear,
      ref_to_fiscal_year                                             as AllocRunRefEndFiscalYear,
      cumulative                                                     as AllocRunHasCumulatedRefPeriods,
      test_run                                                       as AllocationRunIsTest,
      _TestText[1:Language = $session.system_language].AllocationRunIsTestText,
      reversed                                                       as AllocationRunIsReversed,
      _ReversedText[1:Language = $session.system_language].AllocationRunIsReversedText,
      document_type                                                  as DocumentType,
      cast(jobcount as fco_alloc_job_id preserving type )            as AllocationRunScheduledJob,
      cast(jobname  as fco_alloc_job_name preserving type )          as AllocationRunJob,
      stored_ref_data                                                as AllocationRunHasReferenceData,
      cast(case
        when run_type is initial and test_run = 'X'
          then 'T'
        when run_type is initial and test_run = ' '
          then 'R'
        else run_type
        end as fco_alloc_run_type preserving type )                  as AllocationRunType,
      //      run_type                                              as AllocationRunType,

      note_exists                                                    as HasNote,
      cumulative_run                                                 as AllocationRunIsCumulative,
      incremental_processing                                         as AllocRunHasIncrmtlProcessing,
      trigger_source                                                 as AllocationRunTriggerSource,

      _UserContactCard,
      _Context

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ALLOCACTUALPLANVARIANTTEXT",
"I_ALLOCATIONCONTEXTTYPE",
"I_ALLOCATIONCONTEXTTYPETEXT",
"I_ALLOCATIONPOSTINGTYPETEXT",
"I_ALLOCATIONRUNSTATUSTEXT",
"P_ALLOCATIONRUNREVERSEDTEXT",
"P_ALLOCATIONRUNTESTTEXT",
"ALLOC_RUN_INFO"
],
"ASSOCIATED":
[
"I_ALLOCACTUALPLANVARIANTTEXT",
"I_ALLOCATIONCONTEXTTYPE",
"I_ALLOCATIONPOSTINGTYPETEXT",
"I_ALLOCATIONRUNSTATUSTEXT",
"I_USERCONTACTCARD",
"P_ALLOCATIONRUNREVERSEDTEXT",
"P_ALLOCATIONRUNTESTTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/