I_AllocationKeyField

@AbapCatalog.sqlViewName: 'ALLOCKEYFIELD'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking:#NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Allocation Key Field'

@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #M

@VDM.viewType: #BASIC
define view I_AllocationKeyField 
  as select from t811k

  association [1] to I_AllocationCycle as _Cycle   on $projection.AllocationType           = _Cycle.AllocationType
                                                  and $projection.AllocationCycle          = _Cycle.AllocationCycle
                                                  and $projection.AllocationCycleStartDate = _Cycle.AllocationCycleStartDate
                                                 
  association [1] to I_AllocationSegment as _Segment on $projection.AllocationType           = _Segment.AllocationType
                                                    and $projection.AllocationCycle          = _Segment.AllocationCycle
                                                    and $projection.AllocationCycleStartDate = _Segment.AllocationCycleStartDate
                                                    and $projection.AllocationCycleSegment   = _Segment.AllocationCycleSegment 

{
  key cast(tab as fco_allocation_type) as AllocationType,         
  key cycle   as AllocationCycle,      
  key cast( sdate as fco_alloc_valid_from ) as AllocationCycleStartDate,      
  key seqnr   as AllocationCycleSegment,
  key setkind as AllocationSetType,
  key pos     as AllocDocumentSequenceNumber, 
  field       as AllocationFieldName, 
  setname     as AllocationSetName,
  valmin      as AllocationFieldMinimumValue,  
  valmax      as AllocationFieldMaximumValue, 
  setid       as AllocationSetId,
  cast( case when valmin = '#' then 'X' else '' end as boolean ) as  AllocKeyFieldIsInitial,
  cast( case when valmin = '*' then 'X' else '' end as boolean ) as AllocKeyFieldIsAllValues,
  
  _Cycle,
  _Segment 
} 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T811K"
],
"ASSOCIATED":
[
"I_ALLOCATIONCYCLE",
"I_ALLOCATIONSEGMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/