I_AirborneAgentNameText

@EndUserText.label: 'Airborne Agent Name'
@Analytics.dataExtraction.enabled: true
@VDM.viewType: #BASIC
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'AirborneAgentRevisionUUID'
@AccessControl.authorizationCheck: #NOT_REQUIRED

@AbapCatalog.sqlViewName: 'IABAGTTXT'
@AbapCatalog.compiler.compareFilter: true

// Client handling by session 

@ClientHandling.algorithm: #SESSION_VARIABLE

// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #C,        // < 15 msec   

                         sizeCategory:  #L,         // < 10.000.000

                         dataClass: #MASTER }

define view I_AirborneAgentNameText as select from ehhssd_abagt_txt
  association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
  /*+[hideWarning] { "IDS" :  [ "CARDINALITY_CHECK" ] } */  
  association [1..1] to I_AirborneAgentRevision as _AirborneAgentRevision on $projection.AirborneAgentRevisionUUID = _AirborneAgentRevision.AirborneAgentRevisionUUID
                                                                              and $projection.AirborneAgentUUID = _AirborneAgentRevision.AirborneAgentUUID

  association [1..1] to I_AirborneAgentRoot as _AirborneAgentRoot  on $projection.AirborneAgentUUID = _AirborneAgentRoot.AirborneAgentUUID
{
    @ObjectModel.foreignKey.association: '_AirborneAgentRoot' 
    key root_key as AirborneAgentUUID, // TODO EHHSS_ABAGT_KEY_REF

    _AirborneAgentRoot,

    key parent_key as AirborneAgentRevisionUUID,
    _AirborneAgentRevision,

    @Semantics.businessDate.to
    key _AirborneAgentRevision.RevisionEndDate,

    @Semantics.language: true
    @ObjectModel.foreignKey.association: '_Language' 
    key cast( language as sylangu preserving type ) as Language,
    _Language,

    @Semantics.businessDate.from
    _AirborneAgentRevision.RevisionStartDate,

    @Semantics.text:true
    text as AirborneAgentName
}                                
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_AIRBORNEAGENTREVISION",
"EHHSSD_ABAGT_TXT"
],
"ASSOCIATED":
[
"I_AIRBORNEAGENTREVISION",
"I_AIRBORNEAGENTROOT",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0
}
}*/