I_AddressTP

@AbapCatalog.sqlViewName: 'IADDRTP'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #TRANSACTIONAL
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Address Reuse Component Transactional'

@ObjectModel: {
  usageType: { serviceQuality: #C,
               sizeCategory:   #L,
               dataClass:      #TRANSACTIONAL },
  compositionRoot: true,
  semanticKey:  'AddressID',
  transactionalProcessingEnabled : true,
  createEnabled: true,
  deleteEnabled: true,
  updateEnabled: true,
  draftEnabled:true,
  writeDraftPersistence: 'ADDR_D',
 entityChangeStateId:'LastChangeDateTime'
}


define view I_AddressTP
  as select from I_Address_2 as Address
  association [0..1] to I_LanguageText as _LanguageText on  _LanguageText.Language     = $projection.CorrespondenceLanguage
                                                        and _LanguageText.LanguageCode = $projection.CorrespondenceLanguage

{
       @ObjectModel.readOnly: true
  key  Address.AddressID,
       Address.AddressObjectType,
       Address.CareOfName,
       cast ( Address.StreetSuffixName2 as ad_lctn preserving type )                                          as AdditionalStreetSuffixName,
       Address.CorrespondenceLanguage,
       Address.PrfrdCommMediumType,
       Address.POBox,
       Address.POBoxIsWithoutNumber,
       Address.POBoxPostalCode,
       Address.POBoxLobbyName,
       Address.POBoxDeviatingCityName,
       Address.POBoxDeviatingRegion,
       Address.POBoxDeviatingCountry,
       Address.DeliveryServiceTypeCode,
       Address.DeliveryServiceNumber,
       Address.AddressTimeZone,
       cast( Address.AddresseeFullName as caaddr_fullname preserving type )                                   as FullName,
       Address.CityName,
       Address.DistrictName                                                                                   as DistrictName,
       Address.DistrictName                                                                                   as District,
       Address.CityNumber                                                                                     as CityCode,
       Address.VillageName                                                                                    as HomeCityName,
       Address.PostalCode,
       Address.CompanyPostalCode,
       Address.StreetName,
       Address.StreetPrefixName1                                                                              as StreetPrefixName,
       Address.StreetPrefixName2                                                                              as AdditionalStreetPrefixName,
       Address.StreetSuffixName1                                                                              as StreetSuffixName,
       Address.HouseNumber,
       Address.HouseNumberSupplementText,
       Address.Building,
       Address.Floor,
       Address.RoomNumber,
       cast( Address.Country as caaddr_country preserving type )                                              as Country,
       Address.Region,
       Address.SecondaryRegionName                                                                            as SecondaryRegionName,
       Address.SecondaryRegionName                                                                            as County,
       Address.SecondaryRegion                                                                                as CountyCode,
       Address.FormOfAddress,
       _OrganizationAddress.AddresseeName1                                                                    as BusinessPartnerName1,
       _OrganizationAddress.AddresseeName2                                                                    as BusinessPartnerName2,
       Address.AddressRepresentationCode                                                                      as Nation,
       cast ( _CurrentDfltLandlinePhoneNmbr.PhoneAreaCodeSubscriberNumber as caaddr_phonenr preserving type ) as PhoneNumber,
       _CurrentDfltFaxNumber.FaxAreaCodeSubscriberNumber                                                      as FaxNumber,
       Address.AddressSearchTerm1                                                                             as SearchTerm1,
       cast( '' as ad_mc_strt)                                                                                as StreetSearch,
       cast( '' as ad_mc_city)                                                                                as CitySearch,
       _OrganizationAddress.AddresseeName3                                                                    as BusinessPartnerName3,
       _OrganizationAddress.AddresseeName4                                                                    as BusinessPartnerName4,
       Address.TaxJurisdiction,
       Address.TransportZone,
       Address.AddressPersonID                                                                                as Person,

       cast( '' as ad_adrtype )                                                                               as AddressType,
       cast( '' as ad_objkey )                                                                                as AddressOwnerObjectID,
       cast( '' as boolean)                                                                                   as AddressIsChangedManually,

       cast( '' as ad_addrnum )                                                                               as ActiveAddressID,
       cast( '' as boolean )                                                                                  as ActiveAddressIsManual, //The address draft stores both field names (for reference address and manual address).

                                                                                                                                        //This field decides which address owner field name is used for the active address

       cast( '' as ad_appltab )                                                                               as AddressOwnerTableName,
       cast( '' as ad_applfld )                                                                               as AddressOwnerReferenceFieldName,
       cast( '' as ad_applfld )                                                                               as AddressOwnerManualFieldName,

       cast( '' as ad_addrnum )                                                                               as ReferenceAddressID,
       cast( '' as ad_objkey )                                                                                as ReferenceObjectID,
       cast( '' as caaddr_e_type )                                                                            as ReferenceAddressType,

       //cast ( '' as char30 ) as LastChangeDateTime,

       cast ( _CurrentDfltEmailAddress.EmailAddress as caaddr_smtpadr preserving type )                       as EmailAddress,
       cast ( 1 as vdm_lastchangedon )                                                                        as LastChangeDateTime,

       _OrganizationAddress,
       _PhoneNumber,
       _CurrentDfltEmailAddress,

       _CurrentDfltMobilePhoneNumber,
       _CurrentDfltLandlinePhoneNmbr,
       _CurrentDfltFaxNumber,
       _MainWebsiteURL,


       //       _DefaultPhoneNumber,

       //       _DefaultMobilePhoneNumber,

       //       _DefaultFaxNumber,

       //      _DefaultEmailAddress,

       //       _DefaultURLAddress,


       //       _Region,

       //       _Country,

       //       _CountyCode, // to be aligned: better without "Code"?

       //       _CityCode, // to be aligned: better without "Code"?

       //       _FormOfAddress,

       _LanguageText

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRCURDEFAULTEMAILADDRESS",
"I_ADDRCURDEFAULTFAXNUMBER",
"I_ADDRCURDFLTLANDLINEPHONENMBR",
"I_ADDRESS_2",
"I_ORGANIZATIONADDRESS"
],
"ASSOCIATED":
[
"I_ADDRCURDEFAULTEMAILADDRESS",
"I_ADDRCURDEFAULTFAXNUMBER",
"I_ADDRCURDFLTLANDLINEPHONENMBR",
"I_ADDRCURDFLTMOBILEPHONENUMBER",
"I_ADDRESSMAINWEBSITEURL",
"I_ADDRESSPHONENUMBER_2",
"I_LANGUAGETEXT",
"I_ORGANIZATIONADDRESS"
],
"BASE":
[
"I_ADDRESS_2"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/