I_AddressPostalAddress

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Postal Address'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.representativeKey: 'AddressID'
@Analytics.technicalName: 'IADPOSTALADDRESS'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #BASIC
define view entity I_AddressPostalAddress
  as select from I_AddrOrgNamePostalAddress
  association [0..1] to I_Region                       as _Region                        on  $projection.Region  = _Region.Region
                                                                                         and $projection.Country = _Region.Country

  association [0..1] to I_Country                      as _Country                       on  $projection.Country = _Country.Country

  association [0..1] to I_AddressNonDeliverableReason  as _POBoxAddrNonDeliverableReason on  $projection.POBoxAddrNonDeliverableReason = _POBoxAddrNonDeliverableReason.AddressNonDeliverableReason

  association [0..1] to I_AddressNonDeliverableReason  as _StreetAddrNonDeliverableRsn   on  $projection.StreetAddrNonDeliverableReason = _StreetAddrNonDeliverableRsn.AddressNonDeliverableReason

  association [0..1] to I_TransportationZone           as _TransportationZone            on  $projection.TransportZone = _TransportationZone.TransportZone
                                                                                         and $projection.Country       = _TransportationZone.CountryCode

  association [0..1] to I_Region                       as _POBoxDeviatingRegion          on  $projection.POBoxDeviatingRegion  = _POBoxDeviatingRegion.Region
                                                                                         and $projection.POBoxDeviatingCountry = _POBoxDeviatingRegion.Country

  association [0..1] to I_Country                      as _POBoxDeviatingCountry         on  $projection.POBoxDeviatingCountry = _POBoxDeviatingCountry.Country

  association [0..1] to I_AddressCommunicationMethod   as _PrfrdCommMediumType           on  $projection.PrfrdCommMediumType = _PrfrdCommMediumType.CommunicationMediumType

  association [0..1] to I_AddressDeliveryServiceType   as _DeliveryServiceTypeCode       on  $projection.DeliveryServiceTypeCode = _DeliveryServiceTypeCode.DeliveryServiceTypeCode

  association [0..1] to I_Language                     as _CorrespondenceLanguage        on  $projection.CorrespondenceLanguage = _CorrespondenceLanguage.Language

  association [0..1] to I_AddressRepresentation        as _AddressRepresentationCode     on  $projection.AddressRepresentationCode = _AddressRepresentationCode.AddressRepresentationCode

  association [0..1] to I_TimeZone                     as _TimeZone                      on  $projection.AddressTimeZone = _TimeZone.TimeZoneID

  association [0..1] to I_SecondaryRegion              as _SecondaryRegion               on  $projection.SecondaryRegion = _SecondaryRegion.SecondaryRegion
                                                                                         and $projection.Country         = _SecondaryRegion.Country
                                                                                         and $projection.Region          = _SecondaryRegion.Region

  association [0..1] to I_TertiaryRegion               as _TertiaryRegion                on  $projection.TertiaryRegion  = _TertiaryRegion.TertiaryRegion
                                                                                         and $projection.SecondaryRegion = _TertiaryRegion.SecondaryRegion
                                                                                         and $projection.Country         = _TertiaryRegion.Country
                                                                                         and $projection.Region          = _TertiaryRegion.Region

  association [0..1] to I_PostalCity                   as _PostalCity                    on  $projection.CityNumber = _PostalCity.CityNumber
                                                                                         and $projection.Country    = _PostalCity.Country

  association [0..1] to I_RegionalStructureCheckStatus as _RegionalStructureCheckStatus  on  $projection.RegionalStructureCheckStatus = _RegionalStructureCheckStatus.RegionalStructureCheckStatus

  association [0..1] to I_Street                       as _Street                        on  $projection.Country = _Street.Country
                                                                                         and $projection.Street  = _Street.Street
{
  key AddressID,
  key AddressRepresentationCode,
      AddressIsPersonAddress,
      CorrespondenceLanguage,
      PrfrdCommMediumType,
      CityNumber,
      CityName,
      DistrictName,
      VillageName,
      PostalCode,
      CompanyPostalCode,
      POBox,
      POBoxAddrNonDeliverableReason,
      POBoxIsWithoutNumber,
      POBoxPostalCode,
      POBoxLobbyName,
      POBoxDeviatingCityName,
      POBoxDeviatingRegion,
      POBoxDeviatingCountry,
      Street,
      StreetName,
      StreetAddrNonDeliverableReason,
      StreetPrefixName1,
      StreetPrefixName2,
      StreetSuffixName1,
      StreetSuffixName2,
      HouseNumber,
      HouseNumberSupplementText,
      Building,
      Floor,
      RoomNumber,
      Country,
      Region,
      CareOfName,
      TaxJurisdiction,
      TransportZone,
      DeliveryServiceTypeCode,
      DeliveryServiceNumber,
      AddressTimeZone,
      SecondaryRegion,
      SecondaryRegionName,
      TertiaryRegion,
      TertiaryRegionName,
      AddressSearchTerm1,
      AddressSearchTerm2,
      RegionalStructureCheckStatus,
      
      /* Associations */
      _Region,
      _Country,
      _StreetAddrNonDeliverableRsn,
      _POBoxAddrNonDeliverableReason,
      _TransportationZone,
      _POBoxDeviatingRegion,
      _POBoxDeviatingCountry,
      _PrfrdCommMediumType,
      _DeliveryServiceTypeCode,
      _CorrespondenceLanguage,
      _AddressRepresentationCode,
      _TimeZone,
      _SecondaryRegion,
      _TertiaryRegion,
      _PostalCity,
      _RegionalStructureCheckStatus,
      _Street
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRORGNAMEPOSTALADDRESS"
],
"ASSOCIATED":
[
"I_ADDRESSCOMMUNICATIONMETHOD",
"I_ADDRESSDELIVERYSERVICETYPE",
"I_ADDRESSNONDELIVERABLEREASON",
"I_ADDRESSREPRESENTATION",
"I_COUNTRY",
"I_LANGUAGE",
"I_POSTALCITY",
"I_REGION",
"I_REGIONALSTRUCTURECHECKSTATUS",
"I_SECONDARYREGION",
"I_STREET",
"I_TERTIARYREGION",
"I_TIMEZONE",
"I_TRANSPORTATIONZONE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/