I_AddressPhoneNumber

@AbapCatalog.sqlViewName: 'IADDRPHONENUMBER'
@AbapCatalog.preserveKey:true 
@EndUserText.label: 'Address Phone Number'
@Analytics : {dataCategory: #DIMENSION}
@Metadata.allowExtensions:true
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
//@AccessControl.privilegedAssociations: '_AddressCommunicationRemark'

@ObjectModel.representativeKey: 'AddressID'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_AddressPhoneNumber as select from adr2

  association [0..1] to I_AddressCommunicationRemark as _AddressCommunicationRemark on $projection.AddressID = _AddressCommunicationRemark.AddressID
                                                                                 and $projection.Person = _AddressCommunicationRemark.Person
                                                                                 and $projection.OrdinalNumber = _AddressCommunicationRemark.OrdinalNumber
                                                                                 and _AddressCommunicationRemark.CommunicationMediumType = 'TEL'
                                                                                 and _AddressCommunicationRemark.CorrespondenceLanguage = $session.system_language
{    
    key addrnumber as AddressID,
    key persnumber as Person,
//   , date_from as 

    key consnumber as OrdinalNumber,
    country as DestinationLocationCountry,
    flgdefault as IsDefaultPhoneNumber,
    flg_nouse as CommNumberIsNotUsed,
//  , home_flag as IsHomePhoneNumber

    tel_number as PhoneNumber,
    tel_extens as PhoneNumberExtension,
    telnr_long as InternationalPhoneNumber,
//  , telnr_call : system generated normalized number

    dft_receiv as PhoneIsSMSEnabled,
    r3_user as PhoneNumberType,   
    valid_from as ValidityStartDateTime,
    valid_to as ValidityEndDateTime,
  
    _AddressCommunicationRemark
    
} where date_from = '00010101' 
  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ADR2"
],
"ASSOCIATED":
[
"I_ADDRESSCOMMUNICATIONREMARK"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0
}
}*/