@AbapCatalog.sqlViewName: 'IMPEACTVSFIOAVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM.viewType: #COMPOSITE
@ObjectModel:
{
dataCategory: #VALUE_HELP,
usageType.dataClass: #MIXED,
usageType.serviceQuality: #C,
usageType.sizeCategory: #XL
}
@Search.searchable: true
@EndUserText.label: 'Active shop floor items at operation activity'
define view I_ActvShopFloorItemAtOpActyVH
as select from I_ActiveShopFloorItemAtOpActy as ActiveShopFloorItemAtOpActy
inner join I_OpActyNtwkInstance as OpActyNtwkInstance on OpActyNtwkInstance.OpActyNtwkInstance = ActiveShopFloorItemAtOpActy.OpActyNtwkInstance
inner join I_OrderOperationBasic as MfgOrderOperationBasic on MfgOrderOperationBasic.OrderInternalID = OpActyNtwkInstance.OrderInternalID
and MfgOrderOperationBasic.OrderOperationInternalID = OpActyNtwkInstance.OrderOperationInternalID
inner join I_OpActyNtwkElement as OpActyNtwkElement on OpActyNtwkElement.OperationActivityNetwork = OpActyNtwkInstance.OperationActivityNetwork
and OpActyNtwkElement.OpActyNtwkVersionCounter = OpActyNtwkInstance.OpActyNtwkVersionCounter
and OpActyNtwkElement.OpActyNtwkElement = ActiveShopFloorItemAtOpActy.OpActyNtwkElement
inner join I_OpActyInstanceStatusBasic as OpActyInstanceStatusBasic on ActiveShopFloorItemAtOpActy.OpActyNtwkInstance = OpActyInstanceStatusBasic.OpActyNtwkInstance
and ActiveShopFloorItemAtOpActy.OpActyNtwkElement = OpActyInstanceStatusBasic.OpActyNtwkElement
association [0..1] to I_WorkCenterBySemanticKey as _WorkCenterBySemanticKey on $projection.ProductionPlant = _WorkCenterBySemanticKey.Plant
and $projection.WorkCenter = _WorkCenterBySemanticKey.WorkCenter
association [1..1] to C_SASSchemaTypeSFIAtOpActySts as _SASSchemaTypeSFIAtOpActySts on $projection.StatusAndActionSchemaStatus = _SASSchemaTypeSFIAtOpActySts.StatusAndActionSchemaStatus
{
@UI.hidden: true
@ObjectModel.foreignKey.association: '_ShopFloorItem'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ShopFloorItemStdVH', element: 'ShopFloorItem' } } ]
key ActiveShopFloorItemAtOpActy.ShopFloorItem,
@UI.hidden: true
@ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_OpActyNtwkInstanceStdVH', element: 'OpActyNtwkInstance' } } ]
key ActiveShopFloorItemAtOpActy.OpActyNtwkInstance,
@UI.hidden: true
@ObjectModel.foreignKey.association: '_OperationActivityInstance'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_OpActyInstceStdVH', element: 'OpActyNtwkElement' } } ]
key ActiveShopFloorItemAtOpActy.OpActyNtwkElement,
@UI.hidden: true
@ObjectModel.foreignKey.association: '_SASSchema'
ActiveShopFloorItemAtOpActy.StatusAndActionSchema,
@ObjectModel.text.element: ['SASStatusName']
@UI.textArrangement: #TEXT_ONLY
@Consumption.valueHelpDefinition: [ { entity: { name: 'C_SASSchemaTypeSFIAtOpActySts', element: 'StatusAndActionSchemaStatus'} }]
ActiveShopFloorItemAtOpActy.StatusAndActionSchemaStatus,
@Semantics.text: true
ActiveShopFloorItemAtOpActy._SASStatusText[1: Language=$session.system_language].SASStatusName,
@Search:{defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
ActiveShopFloorItemAtOpActy.SerialNumber,
@Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
@ObjectModel.foreignKey.association: '_Material'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
ActiveShopFloorItemAtOpActy.Material,
@Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
@ObjectModel.foreignKey.association: '_MfgOrder'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderStdVH', element: 'ManufacturingOrder' } } ]
ActiveShopFloorItemAtOpActy.ManufacturingOrder,
@Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
@ObjectModel.text.element: 'MfgOrderOperationText'
cast(MfgOrderOperationBasic.Operation as manufacturingorderoperation preserving type) as ManufacturingOrderOperation,
@Semantics.text: true
cast(MfgOrderOperationBasic.OperationText as mfgorderoperationtext preserving type) as MfgOrderOperationText,
MfgOrderOperationBasic.Plant as ProductionPlant,
@UI.hidden: true
@ObjectModel.text.element: 'WorkCenter'
@ObjectModel.foreignKey.association: '_WorkCenterByInternalID'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_WorkCenterStdVH', element: 'WorkCenterInternalID' } } ]
MfgOrderOperationBasic.WorkCenterInternalID,
@UI.hidden: true
@ObjectModel.foreignKey.association: '_WorkCenterBySemanticKey'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_WrkCtrBySemanticKeyStdVH', element: 'WorkCenter'} } ]
MfgOrderOperationBasic._WorkCenterByInternalID.WorkCenter as WorkCenter,
OpActyNtwkInstance.OpActyNtwkSegmentType,
@Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
@ObjectModel.text.element: 'OperationActivityName'
OpActyNtwkElement.OpActyNtwkElementExternalID,
@Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
@Semantics.text: true
_OperationActivityText[1: Language=$session.system_language].OperationActivityName, --OperationActivityDescription
@UI.hidden: true
OpActyInstanceStatusBasic.OpActyIsSeldForRtactvPostg,
ActiveShopFloorItemAtOpActy._ShopFloorItem,
ActiveShopFloorItemAtOpActy._OpActyNtwkInstance,
ActiveShopFloorItemAtOpActy._OperationActivityInstance,
ActiveShopFloorItemAtOpActy._SASSchema,
ActiveShopFloorItemAtOpActy._SASStatus,
ActiveShopFloorItemAtOpActy._Material,
ActiveShopFloorItemAtOpActy._MfgOrder,
MfgOrderOperationBasic._WorkCenterByInternalID,
_WorkCenterBySemanticKey,
OpActyNtwkInstance._OANSegmentType,
_SASSchemaTypeSFIAtOpActySts
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACTIVESHOPFLOORITEMATOPACTY",
"I_OPACTYINSTANCESTATUSBASIC",
"I_OPACTYNTWKELEMENT",
"I_OPACTYNTWKINSTANCE",
"I_OPERATIONACTIVITYTEXT",
"I_ORDEROPERATIONBASIC",
"I_SASSTATUSTEXT",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"C_SASSCHEMATYPESFIATOPACTYSTS",
"I_MATERIAL",
"I_MFGORDER",
"I_OANSEGMENTTYPE",
"I_OPACTYNTWKINSTANCE",
"I_OPERATIONACTIVITYINSTANCE",
"I_SASSCHEMA",
"I_SASSTATUS",
"I_SHOPFLOORITEM",
"I_WORKCENTER",
"I_WORKCENTERBYSEMANTICKEY"
],
"BASE":
[
"I_ACTIVESHOPFLOORITEMATOPACTY",
"I_OPACTYNTWKINSTANCE",
"I_ORDEROPERATIONBASIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/