I_AcctgDocPaytCardDataMaster

@AbapCatalog: {
    sqlViewName: 'IBSEGCARD',
    compiler.compareFilter: true,
    preserveKey:true
}
@AccessControl: {
    authorizationCheck: #CHECK,
    personalData.blocking: #REQUIRED
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Master Data on Payment Card Payments'
@ObjectModel.usageType: {
    dataClass: #MIXED,
    serviceQuality: #C,
    sizeCategory: #XL
}
@VDM.viewType: #COMPOSITE
define view I_AcctgDocPaytCardDataMaster
  as select from I_AcctgDocPaymentCardData as AcctgDoc
  association [1]    to I_Paymentcardtype            as _PaytCardType               on  $projection.PaymentCardType   = _PaytCardType.PaymentCardType
                                                                                    and $projection.PaymentCardNumber = _PaytCardType.PaymentCardNumber
  association [1]    to I_PaymentCardTypes           as _PaytCardTypes              on  $projection.PaymentCardType = _PaytCardTypes.PaymentCardType
  association [0..1] to I_PaymentCardMerchant        as _Merchant                   on  $projection.MerchantByClearingHouse = _Merchant.MerchantByClearingHouse
  association [0..1] to I_PaymentCardCheckResult     as _PaymCardAddressResultCheck on  $projection.PaytCardAddressVerificationSts             = _PaymCardAddressResultCheck.PaymentCardCheckResultCode
                                                                                    and _PaymCardAddressResultCheck.PaymentCardCheckResultType = 'A'
  association [0..1] to I_PaymentCardCheckResult     as _PaymCardAddressApprCheck   on  $projection.PaytCardAddressVerificationSts           = _PaymCardAddressApprCheck.PaymentCardCheckResultCode
                                                                                    and _PaymCardAddressApprCheck.PaymentCardCheckResultType = 'D'
  association [0..1] to I_PaymentCardCheckResult     as _PaymCardRespResultCheck    on  $projection.PaytCardAddressVerificationSts          = _PaymCardRespResultCheck.PaymentCardCheckResultCode
                                                                                    and _PaymCardRespResultCheck.PaymentCardCheckResultType = 'R'
  association [0..1] to I_PaymentCardCheckResult     as _PaymCardZipCheck           on  $projection.PaytCardAddressVerificationSts   = _PaymCardZipCheck.PaymentCardCheckResultCode
                                                                                    and _PaymCardZipCheck.PaymentCardCheckResultType = 'Z'
  association [0..1] to I_PaytCardSettlmtRsltRspText as _ResponseText               on  $projection.PaytCardSettlmtRsltRspCode = _ResponseText.PaytCardSettlmtRsltRspCode
                                                                                    and _ResponseText.Language                 = $session.system_language
  association [0..1] to I_PaytCardEntryModeText      as _EntryModeText              on  $projection.PaymentCardEntryMode = _EntryModeText.PaymentCardEntryMode
                                                                                    and _EntryModeText.Language          = $session.system_language
  association [0..1] to I_PaymentCardCategory        as _PaytCardCategory           on  $projection.PaymentCardCategoryCode = _PaytCardCategory.PaymentCardCategoryCode
  association [0..1] to P_AcctgDocItemPaytData       as _AcctgDocItem               on  AcctgDoc.CompanyCode        = _AcctgDocItem.CompanyCode
                                                                                    and AcctgDoc.AccountingDocument = _AcctgDocItem.AccountingDocument
                                                                                    and AcctgDoc.FiscalYear         = _AcctgDocItem.FiscalYear
                                                                                    and AcctgDoc.PaymentCardItem    = _AcctgDocItem.PaymentCardItem
                                                                                    and $projection.Customer =  _AcctgDocItem.Customer
  association [0..1] to I_Customer                   as _Customer                   on  $projection.Customer = _Customer.Customer

{
  key CompanyCode,
  key AccountingDocument,
  key FiscalYear,
  key PaymentCardItem,
      PaymentCardType,
      PaymentCardNumber,
      PaymentCardEntryMode,   // PaymentCardEntryModeName

      Customer,
      _Customer.AuthorizationGroup                                                                      as AuthorizationGroup,
      MerchantByClearingHouse,
      PaymentCardTerminal,
      PaytCardPointOfReceiptID,
      PaymentCardCategoryCode,
      PaymentCardValidityStartDate,
      PaymentCardValidityEndDate,
      PaymentCardHolderName,
      PaymentCardPaymentSettlement,
      //Authorization DATA

      AuthorizedAmountInAuthznCrcy,
      AuthorizationByPaytSrvcPrvdr,
      AuthorizationByAcquirer,
      AuthorizationCurrency,
      AuthorizationDate,
      AuthorizationTime,
      PaytCardSettlementIsCarriedOut,
      case PaytCardSettlementIsCarriedOut
        when 'X' then 3 // Green Status

        else 1 // Red Status

      end                                                                                               as StatusCriticality,

      PaytCardClrgHsSettlmtRefNumber,

      PaymentAdviceReference,
      PaymentByPaymentServicePrvdr,

      _AcctgDocItem.BillingDocument,
      _AcctgDocItem.GLAccount,
      _AcctgDocItem.PaymentServiceProvider                                                              as PaymentServiceProvider,
      _AcctgDocItem.PaymentRefByPaytSrvcProvider                                                        as PaymentRefByPaytSrvcProvider,
      _AcctgDocItem.DocumentDate,
      _AcctgDocItem.AmountInTransactionCurrency,
      _AcctgDocItem.TransactionCurrency,
      _AcctgDocItem.IsReferenceDocument,

      //rcavr

      @ObjectModel.text.element: 'PaytCardAddrVerificatStsName'
      PaytCardAddressVerificationSts,
      _PaymCardAddressResultCheck._Text[Language = $session.system_language].PaymentCardCheckResultText as PaytCardAddrVerificatStsName,

      PaytCardVerificationResult,
      PaytCardVerificatDetResultText,

      //rcava

      @ObjectModel.text.element: 'PaytCardAddrChkApprvlStsTxt'
      PaytCardAddrChkApprvlStsCode,
      _PaymCardAddressApprCheck._Text[Language = $session.system_language].PaymentCardCheckResultText   as PaytCardAddrChkApprvlStsTxt,

      //rcavz

      @ObjectModel.text.element: 'PaytCardAddrChkZipCodeStsTxt'
      PaytCardAddrChkZipCodeStsCode,
      _PaymCardZipCheck._Text[Language = $session.system_language].PaymentCardCheckResultText           as PaytCardAddrChkZipCodeStsTxt,

      //rcrsp

      @ObjectModel.text.element: 'PaytCardVerificationStatusName'
      PaymentCardVerificationStatus,
      _PaymCardRespResultCheck._Text[Language = $session.system_language].PaymentCardCheckResultText    as PaytCardVerificationStatusName,

      @ObjectModel.text.element: 'PaytCardSettlmtRsltRspName'
      PaytCardSettlmtRsltRspCode,
      _ResponseText.PaytCardSettlmtRsltRspName,

      PaymentCardAuthznRelationID,
      PaymentCardDataIsSent,

      // Make associations public

      _EntryModeText,
      _Merchant,
      _PaytCardType,
      _PaytCardTypes,
      _PaytCardCategory
}  
where _AcctgDocItem.IsReferenceDocument is null or _AcctgDocItem.IsReferenceDocument <> 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCTGDOCPAYMENTCARDDATA",
"I_CUSTOMER",
"I_PAYMENTCARDCHECKRESULT",
"I_PAYMENTCARDCHECKRESULTTEXT",
"I_PAYTCARDSETTLMTRSLTRSPTEXT",
"P_ACCTGDOCITEMPAYTDATA"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_PAYMENTCARDCATEGORY",
"I_PAYMENTCARDCHECKRESULT",
"I_PAYMENTCARDMERCHANT",
"I_PAYMENTCARDTYPE",
"I_PAYMENTCARDTYPES",
"I_PAYTCARDENTRYMODETEXT",
"I_PAYTCARDSETTLMTRSLTRSPTEXT",
"P_ACCTGDOCITEMPAYTDATA"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/