I_AccrEngineAccrSubobjRawData

@AbapCatalog.sqlViewName: 'IACESORW'
@EndUserText.label: 'Accrual Sub Object Raw Data'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType: {
  serviceQuality: #B,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
 }
@ObjectModel.representativeKey: 'AccrualSubobject'
@ObjectModel.entityChangeStateId: 'AccrSubobjLastChangeDateTime'
@VDM.viewType: #BASIC
@AbapCatalog.preserveKey:true

@ObjectModel.supportedCapabilities:[#CDS_MODELING_DATA_SOURCE,#SQL_DATA_SOURCE]
define view I_AccrEngineAccrSubobjRawData as select from acesobj {
  key acesobj.comp as AccrualEngineAccrualObjectType,
  key acesobj.logsys as AccrualObjectLogicalSystem,
  key acesobj.bukrs as CompanyCode,
  key acesobj.ref_key as AccrualObject,
  key acesobj.ref_subkey as AccrualSubobject,
  
      acesobj.objid as AccrualObjectInternalID,
      acesobj.subid as AccrualSubobjectInternalID,

      cast (  case status
                when 'U' then premtre_fdate
                else '00000000' end as ace_pause_date)                        as AccrSubobjPauseDate,
      // Status S "Suspended": Date ACESOBJ-PREMTRE_FDATE is shown as Suspension Date:

      cast (  case status
                when 'S' then premtre_fdate
                else '00000000' end as ace_suspension_date )                  as AccrSubobjSuspensionDate,
      // Status F "Prematurely Finished": Date ACESOBJ-PREMTRE_FDATE is shown as Premature Finish Date:

      cast (  case status
                when 'F' then premtre_fdate
                else '00000000' end as ace_premtre_fdate )                    as AccrSubobjPrematureFinishDate,

      cast(case xarchived when 'X' then 'A'
           else status end as ace_subobject_lifecycle_status preserving type) as AccrSubobjectLifeCycleStatus,

      /*admin infor */
      @Semantics.user.createdBy: true
      createdby                                                               as AccrualSubobjectCreatedByUser,
      @Semantics.systemDate.createdAt: true
      createdon                                                               as AccrualSubobjectCreationDate,
      @Semantics.systemTime.createdAt: true
      createdat                                                               as AccrualSubobjectCreationTime,
      @Semantics.user.lastChangedBy: true
      cast( case when changedby is initial then uname
            else changedby end as ace_ds_changed_by preserving type )         as AccrSubobjLastChangedByUser,
      @Semantics.systemDate.lastChangedAt: true
      changedon                                                               as AccrualSubobjectLastChangeDate,
      @Semantics.systemTime.lastChangedAt: true
      changedat                                                               as AccrualSubobjectLastChangeTime,

      /*Etag */
      @Semantics.systemDateTime.lastChangedAt: true
      cast( dats_tims_to_tstmp(changedon,
                         changedat,
                         abap_system_timezone( $session.client,'NULL' ),
                         $session.client,
                         'NULL' )  as timestamp preserving type )             as AccrSubobjLastChangeDateTime

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ACESOBJ"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/