I_AccountingCostRate

@AbapCatalog.sqlViewName: 'IFIACCOSTRATE'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Interface view for search model CostRate'
@ClientHandling: {
  type:      #CLIENT_DEPENDENT,
  algorithm: #SESSION_VARIABLE
}
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass: #TRANSACTIONAL
    }
}
@VDM.viewType: #BASIC
define view I_AccountingCostRate
  as select from P_AccountingCostRate           as _Rate
    inner join   I_Ledger                       as _Ledger                      on  _Rate.Ledger            = _Ledger.Ledger
                                                                                and _Ledger.IsLeadingLedger = 'X'
    inner join   P_CostRateBusinessTransTypeTxt as _P_CostRateBusinessTransType on  _Rate.BusinessTransactionType         = _P_CostRateBusinessTransType.BusinessTransactionType
                                                                                and _P_CostRateBusinessTransType.Language = $session.system_language
    inner join I_CostCenterActivityTypeText as _I_CostCenterActivityTypeText on _Rate.ControllingArea               = _I_CostCenterActivityTypeText.ControllingArea
                                                                            and _Rate.ActivityType                  = _I_CostCenterActivityTypeText.CostCtrActivityType
                                                                            and _I_CostCenterActivityTypeText.ValidityStartDate <= _Rate.ValidityStartDate
                                                                            and _I_CostCenterActivityTypeText.ValidityEndDate   >= _Rate.ValidityEndDate  
                                                                            and _I_CostCenterActivityTypeText.Language          = $session.system_language  
    inner join I_CostCenterText                as _CurrentCostCenterText            on  _Rate.ControllingArea          = _CurrentCostCenterText.ControllingArea
                                                                                      and _Rate.CostCenter               = _CurrentCostCenterText.CostCenter
                                                                                      and _CurrentCostCenterText.ValidityStartDate <= _Rate.ValidityStartDate
                                                                                      and _CurrentCostCenterText.ValidityEndDate   >= _Rate.ValidityEndDate  
                                                                                      and _CurrentCostCenterText.Language =  $session.system_language                                                                                                                                                      
  association [0..1] to I_CompanyCode                as _CompanyCode                  on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_Currency                   as _Currency                     on  $projection.Currency = _Currency.Currency
  //  association [0..*] to I_CostCenter             as _CostCenter             on  $projection.ControllingArea = _CostCenter.ControllingArea

  //                                                                            and $projection.CostCenter      = _CostCenter.CostCenter

  association [0..*] to I_CostCenter                 as _CurrentCostCenter            on  $projection.ControllingArea          = _CurrentCostCenter.ControllingArea
                                                                                      and $projection.CostCenter               = _CurrentCostCenter.CostCenter
                                                                                      and _CurrentCostCenter.ValidityStartDate <= $projection.ValidityStartDate
                                                                                      and _CurrentCostCenter.ValidityEndDate   >= $projection.ValidityEndDate

  association [0..1] to I_PlanningCategory           as _PlanningCategory             on  $projection.PlanningCategory = _PlanningCategory.PlanningCategory

  association [0..1] to I_UnitOfMeasure              as _UnitOfMeasure                on  $projection.CostCtrActivityTypeQtyUnit = _UnitOfMeasure.UnitOfMeasure
  //  association [0..1] to P_CostRateBusinessTransType as _P_CostRateBusinessTransType on $projection.BusinessTransactionType = _P_CostRateBusinessTransType.BusinessTransactionType

{
  key AccountingCostRateUUID,

      _Rate.Ledger,
      _Rate.CompanyCode,
      _Rate.ControllingArea,
      _Rate.CostCenter,
      ActivityType,
      PlanningCategory,
      _P_CostRateBusinessTransType.BusinessTransactionTypeName,
      @Semantics.businessDate.from: true
      _Rate.ValidityStartDate,
      @Semantics.businessDate.to: true
      _Rate.ValidityEndDate,
      @Semantics.unitOfMeasure:true
      _Rate.CostCtrActivityTypeQtyUnit,
      @Semantics.currencyCode: true
      Currency,
      @Semantics.amount.currencyCode: 'Currency'
      CostRateTotalAmount,
      CostRateScaleFactor,
      AccountingCostRateDesc,
      _I_CostCenterActivityTypeText.CostCtrActivityTypeName,
      _CompanyCode,
      // _CostCenter,

      _CurrentCostCenterText.CostCenterName,
      _CurrentCostCenter,
      //_CostCtrActivityType,

//      _CurrentCostCtrActyType,

//      _I_CostCenterActivityTypeText,

      _Currency,
      _UnitOfMeasure,
      _PlanningCategory
//      _Text

      //  _P_CostRateBusinessTransType


}
where
  CostRateIsDeleted = '' and _Rate.CurrencyRole = '00'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COSTCENTERACTIVITYTYPETEXT",
"I_COSTCENTERTEXT",
"I_LEDGER",
"P_ACCOUNTINGCOSTRATE",
"P_COSTRATEBUSINESSTRANSTYPETXT"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_COSTCENTER",
"I_CURRENCY",
"I_PLANNINGCATEGORY",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/