I_AccountAssignmentWBSElmntVH

@AbapCatalog.sqlViewName: 'IACCASSGMTWBSVH'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XL
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Account Assignment WBS Elmnt Value Help'
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API
define view I_AccountAssignmentWBSElmntVH
  as select from P_AcctgWBSBusTransPrmssnAggrg as BusinessTransactionsPermission
    inner join   I_WBSElement                  as WBSElement on BusinessTransactionsPermission.StatusObject = WBSElement.WBSElementObject
  //left outer join I_CustomerProject             as CustomerProject on WBSElement.Project = CustomerProject.CustomerProject

    inner join I_PPM_ProjectSummaryTask        as pst on WBSElement.ProjectInternalID = pst.ProjectInternalID
    association [1..*] to I_StatusObjectActiveStatus as I_StatusObjectActiveStatus on WBSElementObject = I_StatusObjectActiveStatus.StatusObject and I_StatusObjectActiveStatus.StatusCode       <> 'I0001'
{
      @UI.hidden: true
  key WBSElement.WBSElementInternalID                                                                                          as WBSElementInternalID,
      WBSElement.WBSElementWithCodingMask                                                                                      as WBSElement,
      WBSElement.WBSDescription                                                                                               as WBSDescription,
      WBSElement.WBSElementObject                                                                                               as WBSElementObject,
      WBSElement._Project.Project                                                                                              as Project,
      WBSElement._Project.ProjectDescription                                                                                   as ProjectDescription,
      WBSElement.ControllingArea                                                                                               as ControllingArea,
      WBSElement._ControllingArea.ControllingAreaName                                                                          as ControllingAreaName,
      WBSElement.ProfitCenter                                                                                                  as ProfitCenter,
      WBSElement._ProfitCenter[1: ValidityEndDate   >= $session.system_date
      and ValidityStartDate <= $session.system_date ]._Text[1: Language = $session.system_language ].ProfitCenterName          as ProfitCenterName,
      WBSElement.CompanyCode                                                                                                   as CompanyCode,
      WBSElement._CompanyCode.CompanyCodeName                                                                                  as CompanyCodeName,
      WBSElement.Plant                                                                                                         as Plant,
      WBSElement._Plant.PlantName                                                                                              as PlantName,
      
      @UI.hidden: true
      pst.ProjectSummaryTaskUUID,
      @UI.hidden: true
      pst._AuthUser,
      @UI.hidden: true
      pst._AuthSubst,
      @UI.hidden: true
      pst._AuthRole,
      @UI.hidden: true
      pst._AuthGroup

}
where
       WBSIsAccountAssignmentElement                           = 'X'
  //and  CustomerProject.CustomerProject                         is null

  // and  WBSElement._Project.ProjectProfileCode                  = 'YP01'

  and  pst.ProjectCategory                                     = '6'
 
  and(
       BusinessTransactionsPermission.BusTransacTypePermission = '1'
    or BusinessTransactionsPermission.BusTransacTypePermission = '2'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_PLANT",
"I_PPM_PROJECTSUMMARYTASK",
"I_PROFITCENTER",
"I_PROFITCENTERTEXT",
"I_PROJECTBYINTERNALKEY",
"I_WBSELEMENT",
"P_ACCTGWBSBUSTRANSPRMSSNAGGRG"
],
"ASSOCIATED":
[
"I_PPM_AUTHZNBYSUBSTITH",
"I_PPM_AUTHZNBYUSERROLEH",
"I_PPM_AUTHZNBYUSRGRPH",
"I_PPM_AUTHZNBYUSRH",
"I_STATUSOBJECTACTIVESTATUS"
],
"BASE":
[
"I_PPM_PROJECTSUMMARYTASK"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/