I_ARunSupProtCnsmpn

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
  viewType: #BASIC
}
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED,
  personalData.blocking: #NOT_REQUIRED
}
@AbapCatalog: {
  sqlViewName: 'IARUNSUPPROTCNS',
  compiler.compareFilter: true,
  preserveKey: true
 }
@ObjectModel: {
   usageType: {
     dataClass:      #MASTER,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@EndUserText.label: 'Supply Protection Consumption Details'
define view I_ARunSupProtCnsmpn
  as select from            sup_object                   as SupProt
    inner join              I_SupDmndMaterialPlant       as MaterialPlant     on  SupProt.material = MaterialPlant.Material
                                                                              and SupProt.plant    = MaterialPlant.Plant
    left outer to many join sup_cvc                      as SupProtGroup      on SupProt.uuid = SupProtGroup.supobjectuuid
    left outer to many join I_SupplyProtectionTimeBucket as SupProtTimeBucket on SupProtGroup.uuid = SupProtTimeBucket.SupplyProtectionGroupUUID
    left outer to many join I_SupProtPermConsumption     as SupProtCnsmpn     on SupProtTimeBucket.SupProtTimeBucketUUID = SupProtCnsmpn.SupProtTimeBucketUUID

{
  key SupProtCnsmpn.SupProtPermConsumptionUUID,
      SupProtTimeBucket.SupProtTimeBucketUUID,
      SupProt.name                              as SupplyProtectionName,
      SupProt.material                          as Material,
      SupProt.plant                             as Plant,
      'SP'                                      as RequirementType,
      cast(tstmp_to_dats( SupProtTimeBucket.SupProtPeriodStartUTCDateTime, 'UTC', $session.client, 'NULL' )
      as vdm_v_start_date)                      as RequestedDeliveryDate,
      cast(tstmp_to_dats( SupProtTimeBucket.SupProtPeriodStartUTCDateTime, 'UTC', $session.client, 'NULL' )
      as vdm_v_start_date)                      as ProductAvailabilityDate,
      cast(tstmp_to_dats( SupProtTimeBucket.SupProtPeriodStartUTCDateTime, 'UTC', $session.client, 'NULL' )
      as vdm_v_start_date)                      as StartDate,
      cast(tstmp_to_dats( SupProtTimeBucket.SupProtPeriodEndUTCDateTime,'UTC', $session.client, 'NULL' )
      as vdm_v_end_date)                        as EndDate,
      @Semantics.unitOfMeasure: true
      SupProtCnsmpn.SupProtConsumedQuantityUnit as BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      SupProtCnsmpn.SupProtConsumedQuantity,
      @EndUserText.label: 'Requirement Document Number'
      SupProtAssignedDocument,
      @EndUserText.label: 'Requirement Document Item'
      SupProtAssignedDocumentItem,
      @EndUserText.label: 'Requirement Type'
      SupplyProtectionDocumentType,
      MaterialGroup,
      MaterialType,
      CrossPlantConfigurableProduct,
      SupProt.uuid                              as SupplyProtectionUUID,
      SupProtGroup.uuid                         as SupplyProtectionGroupUUID
}
where
      SupProt.status                             <> '03' -- Deactivated
  and SupProtCnsmpn.SupplyProtectionDocumentType is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SUPDMNDMATERIALPLANT",
"I_SUPPLYPROTECTIONTIMEBUCKET",
"I_SUPPROTPERMCONSUMPTION",
"SUP_CVC",
"SUP_OBJECT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/