I_ARunReleaseCheckCube

@EndUserText.label: 'Cube view for Release Check'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
  viewType: #COMPOSITE
}
@AbapCatalog: {
  sqlViewName: 'IRELCHKCUBE',
  compiler.compareFilter: true
 }
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: {
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #X,
     sizeCategory:   #XXL
   }
}
@Analytics.dataCategory: #CUBE
@AccessControl.personalData.blocking: #REQUIRED
@Metadata.ignorePropagatedAnnotations:true
@Metadata.allowExtensions: true
define view I_ARunReleaseCheckCube
  as select from        I_ARunReleaseCheckLevel   as ReleaseLevel
  inner join            P_ARunDmnd                as Demand               on  ReleaseLevel.RequirementDocumentNumber = Demand.RequirementDocumentNumber
                                                                          and ReleaseLevel.RequirementDocumentItem   = Demand.RequirementDocumentItem
  left outer join       I_CalendarDate            as CalDate              on  ReleaseLevel.ProductAvailabilityDate = CalDate.CalendarDate
  left outer join       I_CalendarMonthName       as CalMonth             on  CalDate.CalendarMonth = CalMonth.CalendarMonth
  association [0..1] to I_MaterialText            as _MaterialText        on  $projection.Material   = _MaterialText.Material
                                                                          and _MaterialText.Language = $session.system_language
  association [0..1] to I_MaterialGroupText       as _MaterialGroup       on  $projection.MaterialGroup = _MaterialGroup.MaterialGroup
                                                                          and _MaterialGroup.Language   = $session.system_language
  association [0..1] to I_CustomerGroupText       as _CustomerGroup       on  $projection.CustomerGroup = _CustomerGroup.CustomerGroup
                                                                          and _CustomerGroup.Language   = $session.system_language
  association [0..1] to I_SalesOrganizationText   as _SalesOrgText        on  $projection.SalesOrganization = _SalesOrgText.SalesOrganization
                                                                          and _SalesOrgText.Language        = $session.system_language
  association [0..1] to I_DistributionChannelText as _DistributionChannel on  $projection.DistributionChannel = _DistributionChannel.DistributionChannel
                                                                          and _DistributionChannel.Language   = $session.system_language
  association [0..1] to I_DivisionText            as _Division            on  $projection.Division = _Division.Division
                                                                          and _Division.Language   = $session.system_language
  association [0..1] to I_SalesDistrictText       as _SalesDist           on  $projection.SalesDistrict = _SalesDist.SalesDistrict
                                                                          and _SalesDist.Language       = $session.system_language
  association [0..1] to I_Plant                   as _Plant               on  $projection.Plant = _Plant.Plant
  association [0..1] to I_CompanyCode             as _CompanyCode         on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_Customer                as _SoldToParty         on  $projection.SoldToParty = _SoldToParty.Customer
  association [0..1] to I_Customer                as _ShipToParty         on  $projection.ShipToParty = _ShipToParty.Customer
  association [0..1] to I_ARunReleaseRuleText     as _DateRelRule         on  $projection.ARunMatlAvailyDateRelChkRule = _DateRelRule.ARunSupplyAssgmtReleaseRule
                                                                          and _DateRelRule.Language                    = $session.system_language
  association [0..1] to I_ARunReleaseRuleText     as _ItemRelRule         on  $projection.ARunItemRelChkRule = _ItemRelRule.ARunSupplyAssgmtReleaseRule
                                                                          and _ItemRelRule.Language          = $session.system_language
  association [0..1] to I_ARunReleaseRuleText     as _HeaderRelRule       on  $projection.ARunHeaderRelChkRule = _HeaderRelRule.ARunSupplyAssgmtReleaseRule
                                                                          and _HeaderRelRule.Language          = $session.system_language
  association [0..1] to I_ARunReleaseRuleText     as _GenArticleRelRule   on  $projection.ARunGenericArticleRelChkRule = _GenArticleRelRule.ARunSupplyAssgmtReleaseRule
                                                                          and _GenArticleRelRule.Language              = $session.system_language
  association [0..1] to I_ARunReleaseRuleText     as _DelivGrpRelRule     on  $projection.ARunDelivGrpRelChkRule = _DelivGrpRelRule.ARunSupplyAssgmtReleaseRule
                                                                          and _DelivGrpRelRule.Language          = $session.system_language
  association [0..1] to I_ARunReleaseRuleText     as _ShipgGrpRelRule     on  $projection.ARunShipgGrpRelChkRule = _ShipgGrpRelRule.ARunSupplyAssgmtReleaseRule
                                                                          and _ShipgGrpRelRule.Language          = $session.system_language
  association [0..1] to I_ARunReleaseRuleText     as _DocItemGrpRelRule   on $projection.ARunDocItemGrpRelChkRule = _DocItemGrpRelRule.ARunSupplyAssgmtReleaseRule
                                                                          and _DocItemGrpRelRule.Language         = $session.system_language
  association [0..1] to I_ARunReleaseRuleText     as _HdrGrpRelRule       on $projection.ARunHdrGrpRelChkRule     = _HdrGrpRelRule.ARunSupplyAssgmtReleaseRule
                                                                          and _HdrGrpRelRule.Language             = $session.system_language
  association [0..1] to I_SupDmndRqmtTypeText     as _SupRqmtType          on  $projection.RequirementType        = _SupRqmtType.RequirementType
                                                                          and _SupRqmtType.Language                 = $session.system_language   
  association [0..1] to I_ARunDemandGroupRule     as _ARunDocumentItemGroupRule on $projection.ARunDocumentItemGroupRuleUUID = _ARunDocumentItemGroupRule.ARunDemandGroupRuleUUID
  association [0..1] to I_ARunDemandGroupRule     as _ARunHeaderGroupRule on $projection.ARunHeaderGroupRuleUUID = _ARunHeaderGroupRule.ARunDemandGroupRuleUUID                                                                    
{     @EndUserText.label: 'Release Check Variant Run ID'
  key ReleaseLevel.ARunReleaseCheckRunUUID,
  key ReleaseLevel.ARunReleaseCheckResultUUID,
      ReleaseLevel.ARunReleaseCheckVariantUUID,
      @EndUserText.label: 'Release Check Variant'
      ReleaseLevel.ARunReleaseCheckVariantName,
      ReleaseLevel.SupAssgmtExecutionMode,
      ReleaseLevel.SupAssignRunIsSimulation,
      @EndUserText.label: 'Requirement Document Number'
      ReleaseLevel.RequirementDocumentNumber,
      @EndUserText.label: 'Requirement Document Item'
      ReleaseLevel.RequirementDocumentItem,
      @EndUserText.label: 'Demand Type'
      @ObjectModel.text.association: '_SupRqmtType'
      ReleaseLevel.RequirementType,
      @ObjectModel.text.element: ['OrderTypeName'] 
      Demand.OrderType,
      @EndUserText.label: 'Order Type'
      case when Demand.OrderTypeName is not null then Demand.OrderTypeName else '' end as OrderTypeName,
      @EndUserText.label: 'Requested Date'
      ReleaseLevel.RequestedDate,
      @EndUserText.label: 'Delivery Date'
      ReleaseLevel.ProductAvailabilityDate,
      @EndUserText.label: 'Supply Assignment Status'
      ReleaseLevel.SupplyAssignmentStatus,
      @EndUserText.label: 'Previous Supply Assignment Status'
      ReleaseLevel.PreviousSupplyAssignmentStatus,
      ReleaseLevel.AssignedSupplyType,
      Demand.DeliveryGroup,
      @EndUserText.label: 'Company Code'
      @ObjectModel.text.element: ['CompanyCodeName'] 
      Demand.CompanyCode,
      _CompanyCode.CompanyCodeName,
      @ObjectModel.text.element: ['PlantName']   
      Demand.Plant,
      _Plant.PlantName,
      Demand.SalesOffice,
      Demand.SalesGroup,
      @ObjectModel.text.association: '_SalesDist' 
      Demand.SalesDistrict,
      @ObjectModel.text.association: '_SalesOrgText' 
      Demand.SalesOrganization,
      @ObjectModel.text.association: '_DistributionChannel'    
      Demand.DistributionChannel,
      @ObjectModel.text.association: '_Division' 
      Demand.Division,
      @ObjectModel.text.element: ['SoldToPartyName']
      Demand.SoldToParty,
      _SoldToParty.CustomerName as SoldToPartyName,
      @ObjectModel.text.element: ['ShipToPartyName']
      @EndUserText.label: 'Ship To Party'
      Demand.ShipToParty as ShipToParty,
      _ShipToParty.CustomerName as ShipToPartyName,
      @ObjectModel.text.association: '_CustomerGroup'
      Demand.CustomerGroup,
      Demand.AdditionalCustomerGroup1,
      Demand.AdditionalCustomerGroup2,
      Demand.AdditionalCustomerGroup3,
      Demand.AdditionalCustomerGroup4,
      Demand.AdditionalCustomerGroup5,
      Demand.CustomerReferenceNumber,
      Demand.PartnerFunction,
      Demand.SalesDocumentItemCategory,
      @EndUserText.label: 'Product'
      @ObjectModel.text.association: '_MaterialText'
      Demand.Material,
      @EndUserText.label: 'Product Group'
      @ObjectModel.text.association: '_MaterialGroup'
      Demand.MaterialGroup,
      Demand.SalesDocumentRjcnReason,
      Demand.ItemBillingBlockReason,
      Demand.BusinessArea,
      Demand.ProfitCenter,
      Demand.DeliveryPriority,
      Demand.StorageLocation,
      Demand.ShippingCondition,
      Demand.ShippingPoint,
      @Semantics.currencyCode: true
      Demand.DocumentCurrency,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode:'DocumentCurrency'
      Demand.NetAmount,      
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode:'DocumentCurrency'
      Demand.NetPriceAmount,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      Demand.NetPriceQuantity,
      Demand.RequirementSegment,
      Demand.ProductSeasonYear,
      Demand.ProductSeason,
      Demand.ProductCollection,
      Demand.ProductTheme,
      Demand.FashionCancelDate,
      Demand.ShippingGroupRule,
      Demand.ShippingGroupNumber,
      Demand.ProductCharacteristic1,
      Demand.ProductCharacteristic2,
      Demand.ProductCharacteristic3,      
      Demand.PaymentTerms,
      Demand.SupAssgmtOrdStatus,
      @EndUserText.label: 'Generic Product'
      Demand.CrossPlantConfigurableProduct,
      Demand.FreeDefinedProductAttribute01,
      Demand.FreeDefinedProductAttribute02,
      Demand.FreeDefinedProductAttribute03,
      @ObjectModel.text.element: ['CalendarMonthName']
      CalDate.CalendarMonth,
      @EndUserText.label: 'Week'
      concat_with_space('Week',CalDate.CalendarWeek, 1)                                as CalendarWeek,
      @EndUserText.label: 'Year'
      CalDate.CalendarYear,
      @EndUserText.label: 'Month'
      case when CalMonth.CalendarMonthName is not null then CalMonth.CalendarMonthName else '' end as CalendarMonthName,
      ReleaseLevel.ARunDocumentItemGroupRuleUUID,
      ReleaseLevel.ARunHeaderGroupRuleUUID,
      @DefaultAggregation: #SUM
      @EndUserText.label: 'Order Quantity'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      ReleaseLevel.OrderQuantity,
      @DefaultAggregation: #SUM
      @EndUserText.label: 'Confirmed Quantity'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      ReleaseLevel.ConfirmedRqmtQtyInBaseUnit,
      @DefaultAggregation: #SUM
      @EndUserText.label: 'Delivered Quantity'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      ReleaseLevel.DeliveredQuantityInBaseUnit,
      @DefaultAggregation: #SUM
      @EndUserText.label: 'Assigned Quantity'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      ReleaseLevel.AssignedQuantityInBaseUnit,
      @DefaultAggregation: #SUM
      @EndUserText.label: 'Ready for Delivery Quantity (F)'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      ReleaseLevel.FixedQuantityInBaseUnit,
      @DefaultAggregation: #SUM
      @EndUserText.label: 'On Hold for Delivery Quantity (H)'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      ReleaseLevel.OnHoldQuantityInBaseUnit,
      @DefaultAggregation: #SUM
      @EndUserText.label: 'On Reservation Quantity (R)'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      ReleaseLevel.SupAssgmtReservedQtyInBaseUnit,
      @DefaultAggregation: #SUM
      @EndUserText.label: 'Unassigned Quantity'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      ReleaseLevel.UnassignedQtyInBaseUnit,
      ReleaseLevel.BaseUnit,
      @EndUserText.label: 'Material Availability Date Status'
      ReleaseLevel.ARunMatlAvailyDateRelChkStatus,
      @EndUserText.label: 'Article Item Release Status'
      ReleaseLevel.ARunItemRelChkStatus,
      @EndUserText.label: 'Generic Product Release Status'
      ReleaseLevel.ARunGenericArticleRelChkStatus,
      @EndUserText.label: 'Delivery Group Release Status'
      ReleaseLevel.ARunDelivGrpRelChkStatus,
      @EndUserText.label: 'Item Group Release Status'
      ReleaseLevel.ARunDocItemGrpRelChkStatus,
      @EndUserText.label: 'Document Header Release Status'
      ReleaseLevel.ARunHeaderRelChkStatus,
      @EndUserText.label: 'PSST Group Release Status'
      ReleaseLevel.ARunShipgGrpRelChkStatus,
      @EndUserText.label: 'Document Group Release Status'
      ReleaseLevel.ARunHdrGrpRelChkStatus,
      @EndUserText.label: 'Material Availability Date Release Rule'
      @ObjectModel.text.association: '_DateRelRule'
      ReleaseLevel.ARunMatlAvailyDateRelChkRule,
      @EndUserText.label: 'Article Item Release Rule'
      @ObjectModel.text.association: '_ItemRelRule'
      ReleaseLevel.ARunItemRelChkRule,
      @ObjectModel.text.association: '_GenArticleRelRule'
      @EndUserText.label: 'Generic Product Release Rule'
      ReleaseLevel.ARunGenericArticleRelChkRule,
      @ObjectModel.text.association: '_DelivGrpRelRule'
      @EndUserText.label: 'Delivery Group Release Rule'
      ReleaseLevel.ARunDelivGrpRelChkRule,
      @EndUserText.label: 'Document Header Release Rule'
      @ObjectModel.text.association: '_HeaderRelRule'
      ReleaseLevel.ARunHeaderRelChkRule,
      @ObjectModel.text.association: '_ShipgGrpRelRule'
      @EndUserText.label: 'PSST Group Release Rule'
      ReleaseLevel.ARunShipgGrpRelChkRule,
      @ObjectModel.text.association: '_DocItemGrpRelRule'
      @EndUserText.label: 'Item Group Release Rule'
      ReleaseLevel.ARunDocItemGrpRelChkRule,
      @ObjectModel.text.association: '_HdrGrpRelRule'
      @EndUserText.label: 'Document Group Release Rule'
      ReleaseLevel.ARunHdrGrpRelChkRule,
      @DefaultAggregation: #NONE
      @EndUserText.label: 'Material Availability Date Release Quota'
      ReleaseLevel.ARunMatlAvailyDateRelChkPct,
      @DefaultAggregation: #NONE
      @EndUserText.label: 'Article Item Release Quota'
      ReleaseLevel.ARunItemRelChkPct,
      @DefaultAggregation: #NONE
      @EndUserText.label: 'Generic Product Release Quota'
      ReleaseLevel.ARunGenericArticleRelChkPct,
      @DefaultAggregation: #NONE
      @EndUserText.label: 'Delivery Group Release Quota'
      ReleaseLevel.ARunDelivGrpRelChkPct,
      //@DefaultAggregation: #NONE

      @EndUserText.label: 'Item Group Release Quota'
      ReleaseLevel.ARunDocItemGrpRelChkPct,
      @DefaultAggregation: #NONE
      @EndUserText.label: 'Document Header Release Quota'
      ReleaseLevel.ARunHeaderRelChkPct,
      @DefaultAggregation: #NONE
      @EndUserText.label: 'PSST Group Release Quota'
      ReleaseLevel.ARunShipgGrpRelChkPct,
      //@DefaultAggregation: #NONE

      @EndUserText.label: 'Document Group Release Quota'
      ReleaseLevel.ARunHdrGrpRelChkPct,
      @DefaultAggregation: #NONE
      ReleaseLevel.ARunMatlAvailyDateRelFlfmtPct,
      @DefaultAggregation: #NONE
      ReleaseLevel.ARunItemRelFlfmtPct,
      @DefaultAggregation: #NONE
      ReleaseLevel.ARunGenericArticleRelFlfmtPct,
      @DefaultAggregation: #NONE
      ReleaseLevel.ARunDelivGrpRelFlfmtPct,
      //@DefaultAggregation: #NONE

      ReleaseLevel.ARunDocItemGrpRelChkFlfmtPct,
      @DefaultAggregation: #NONE
      ReleaseLevel.ARunHeaderRelFlfmtPct,
      @DefaultAggregation: #NONE
      ReleaseLevel.ARunShipgGrpRelFlfmtPct, 
      //@DefaultAggregation: #NONE

      ReleaseLevel.ARunHdrGrpRelChkFlfmtPct,
      _ARunDocumentItemGroupRule.ARunDemandGroupRule as ARunDocItemGroupRuleName,
      _ARunHeaderGroupRule.ARunDemandGroupRule as ARunHdrGroupRuleName,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode:'DocumentCurrency'
      cast ( NetPriceAmount * FixedQuantityInBaseUnit as netwr)  as  ActlAmt,                        
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      ReleaseLevel.ARunRelChkMatAvailyDateCalcQty,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      ReleaseLevel.ARunRelChkCalcQty,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      case ARunMatlAvailyDateRelChkPct
      when 0
         then 0
      else ReleaseLevel.ARunRelChkMatAvailyDateCalcQty
      end as ARunMatAvailyDateRelChkQty,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      case ARunItemRelChkPct
      when 0
         then 0
      else ReleaseLevel.ARunRelChkCalcQty
      end as ARunItemRelChkQty,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      case ARunGenericArticleRelChkPct
      when 0
         then 0
      else
         case CrossPlantConfigurableProduct
         when ''
            then 0
               else ReleaseLevel.ARunRelChkCalcQty
         end
      end as ARunGenericArticleRelChkQty,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      case ARunDelivGrpRelChkPct
      when 0
         then 0
      else
         case DeliveryGroup
         when '000'
            then 0
               else ReleaseLevel.ARunRelChkCalcQty
         end
      end as ARunDelivGrpRelChkQty,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      case ReleaseLevel.ARunDocItemGrpRelChkPct
      when 0
         then 0
      else
         case _ARunDocumentItemGroupRule.ARunDemandGroupRule
            when ''
               then 0
               else ReleaseLevel.ARunRelChkCalcQty
         end
      end as ARunDocItemGrpRelChkQty,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      case ARunHeaderRelChkPct
      when 0
         then 0
      else ReleaseLevel.ARunRelChkCalcQty
      end as ARunHeaderRelChkQty,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      case ARunShipgGrpRelChkPct
      when 0
         then 0
      else
         case ShippingGroupNumber
            when ''
               then 0
                  else ReleaseLevel.ARunRelChkCalcQty
          end
      end as ARunShipgGrpRelChkQty,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      case ReleaseLevel.ARunHdrGrpRelChkPct
      when 0
         then 0
      else 
         case _ARunHeaderGroupRule.ARunDemandGroupRule
         when ''
            then 0
               else ReleaseLevel.ARunRelChkCalcQty
         end
      end as ARunHdrGrpRelChkQty,
      @Semantics.unitOfMeasure: true
      cast( ' ' as meins ) as SupAssgmtAggrgQtyUnit,
      ReleaseLevel.ARunRelChkRunDocItemGrpVal,
      ReleaseLevel.ARunRelChkRunHdrGrpVal,
      _DateRelRule,
      _ItemRelRule,
      _HeaderRelRule,
      _GenArticleRelRule,
      _DelivGrpRelRule,
      _ShipgGrpRelRule,
      _MaterialText,
      _MaterialGroup,
      _CustomerGroup,
      _SalesOrgText,
      _DistributionChannel,
      _Division,
      _SalesDist,
      _Plant,
      _CompanyCode,
      _SoldToParty,
      _ShipToParty,
      _SupRqmtType,
      _DocItemGrpRelRule,
      _HdrGrpRelRule,
      _ARunDocumentItemGroupRule,
      _ARunHeaderGroupRule
}
where IsBusinessPurposeCompleted = ''
and   AllocationRunStatus = 'X'

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ARUNDEMANDGROUPRULE",
"I_ARUNRELEASECHECKLEVEL",
"I_CALENDARDATE",
"I_CALENDARMONTHNAME",
"I_COMPANYCODE",
"I_CUSTOMER",
"I_PLANT",
"P_ARUNDMND"
],
"ASSOCIATED":
[
"I_ARUNDEMANDGROUPRULE",
"I_ARUNRELEASERULETEXT",
"I_COMPANYCODE",
"I_CUSTOMER",
"I_CUSTOMERGROUPTEXT",
"I_DISTRIBUTIONCHANNELTEXT",
"I_DIVISIONTEXT",
"I_MATERIALGROUPTEXT",
"I_MATERIALTEXT",
"I_PLANT",
"I_SALESDISTRICTTEXT",
"I_SALESORGANIZATIONTEXT",
"I_SUPDMNDRQMTTYPETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/