I_ARunOvwTotDmndCube

@AbapCatalog.sqlViewName: 'IARUNTOTDMNDCUBE'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #COMPOSITE
@Analytics.dataCategory: #CUBE
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Supply Assignment Run Demand Cube View'
@AccessControl.authorizationCheck: #CHECK
@Metadata.ignorePropagatedAnnotations:true
@Metadata.allowExtensions:true
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@AccessControl.personalData.blocking: #REQUIRED
define view I_ARunOvwTotDmndCube
  as select from    I_ARunOvwTotDmnd    as Demand
    left outer join I_CalendarDate      as CalDate          on Demand.ProductAvailabilityDate = CalDate.CalendarDate
    left outer join I_CalendarMonthName as CalMonth         on CalDate.CalendarMonth = CalMonth.CalendarMonth
    left outer join I_ARunTimeUnitText  as ARunTimeUnitText on  ARunTimeUnitText.ARunDisplayTimeUnit = '02'
                                                            and ARunTimeUnitText.Language            = $session.system_language
  association [0..1] to I_Currency as _DocCurrency on $projection.DocumentCurrency = _DocCurrency.Currency
  association [1..1] to I_Material as _Material    on $projection.Material = _Material.Material
{
      @EndUserText.label: 'BOP Run ID'
  key ATPCheckUUID,
      @EndUserText.label: 'Requirement Document Number'
  key RequirementDocumentNumber,
      @EndUserText.label: 'Requirement Document Item'
  key RequirementDocumentItem,
      @EndUserText.label: 'Requested Date'
  key RequestedDate,
  key ProductAvailabilityDate,
      @EndUserText.label: 'Requirement Type'
  key Demand.RequirementType,
      @EndUserText.label: 'Delivered Quantity'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      @DefaultAggregation: #SUM
      DeliveredQuantityInBaseUnit,
      @EndUserText.label: 'Order Quantity'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      @DefaultAggregation: #SUM
      RequestedRqmtQtyInBaseUnit,
      @EndUserText.label: 'Confirmed Quantity'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      @DefaultAggregation: #SUM
      ConfirmedRqmtQtyInBaseUnit,
      @EndUserText.label: 'Open Demand Quantity'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      @DefaultAggregation: #SUM
      case
        when RequirementType = 'VE' or RequirementType = 'VS'
        then 0
        else OpenDemandQuantity - AssignedQuantityInBaseUnit
      end                                                                  as OpenDemandQuantity,
      //Dummy UoM for ATC issues, Need single UOM for Chart Aggregation

      @Semantics.unitOfMeasure: true
      cast(' ' as meins)                                                   as SupAssgmtAggrgQtyUnit,
      @EndUserText.label: 'Tot. SUP Restriction Qty.'
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      ARunTotSupProtQty,
      @EndUserText.label: 'Act. SUP Restriction Qty.'
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      ARunActualSupProtQty,
      @EndUserText.label: 'BOP Variant UUID'
      ABOPVariantUUID,
      @EndUserText.label: 'BOP Variant Name'
      ABOPVariantName,
      StartedByUser,
      ATPCheckStartUTCDateTime,
      ATPCheckEndUTCDateTime,
      ATPCheckStatus,
      ABOPExecutionMode,
      ATPRlvtDocItmIsSupAssgmtRlvt,
      ABOPAssignmentPreviewIsActive,
      Material,
      Plant,
      RequirementSegment,
      BaseUnit,
      SalesOrganization,
      DistributionChannel,
      Division,
      SalesDistrict,
      CustomerGroup,
      @EndUserText.label: 'Company Code'
      CompanyCode,
      MaterialGroup,
      OrderType,
      OrderTypeName,
      SoldToParty,
      ShipToParty,
      CrossPlantConfigurableProduct,
      DeliveryGroup,
      ProductSeasonYear,
      ProductSeason,
      ProductCollection,
      ProductTheme,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      NetPriceAmount,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      NetPriceQuantity,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      NetAmount,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      cast ( NetPriceAmount * AssignedQuantityInBaseUnit as netwr )        as ActlAmt,
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_DocCurrency'
      DocumentCurrency,
      @EndUserText.label: 'Year'
      @Semantics.calendar.year: true
      CalDate.CalendarYear,
      @Semantics.calendar.month: true
      CalDate.CalendarMonth,
      @EndUserText.label: 'Month'
      CalMonth.CalendarMonthName,
      @EndUserText.label: 'Week'
      @Semantics.calendar.week: true
      concat_with_space( ARunDisplayTimeUnitText, CalDate.CalendarWeek, 1) as CalendarWeek,
      @EndUserText.label: 'Day'
      @Semantics.calendar.dayOfMonth: true
      CalDate.CalendarDay,
      @EndUserText.label: 'Total Assigned Quantity'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      @DefaultAggregation: #SUM
      AssignedQuantityInBaseUnit,
      @EndUserText.label: 'Actual Assigned Quantity'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      @DefaultAggregation: #SUM
      NormalAssignedQuantityInBsUnt,
      @EndUserText.label: 'Ready for Delivery Quantity'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      @DefaultAggregation: #SUM
      FixedQuantityInBaseUnit,
      @EndUserText.label: 'Reserved Quantity'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      @DefaultAggregation: #SUM
      SupAssgmtReservedQtyInBaseUnit,
      @EndUserText.label: 'Open for Release Check Quantity'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      @DefaultAggregation: #SUM
      ReadyForReleaseQtyInBaseUnit,
      @EndUserText.label: 'On Hold Quantity'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      @DefaultAggregation: #SUM
      OnHoldQuantityInBaseUnit,
      @EndUserText.label: 'IFO Assigned Quantity'
      @Semantics.quantity.unitOfMeasure: 'SupAssgmtAggrgQtyUnit'
      @DefaultAggregation: #SUM
      InboundAssignedQuantityInBsUnt,
      PurchaseOrderByCustomer,
      DeliveryBlockReason,
      ProductCharacteristic1,
      ProductCharacteristic2,
      ProductCharacteristic3,
      OrganizationDivision,
      SalesOffice,
      FashionCancelDate,
      _Material.ProdCharc1InternalNumber,
      _Material.ProdCharc2InternalNumber,
      _Material.ProdCharc3InternalNumber,
      _DocCurrency,
      _Material
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ARUNOVWTOTDMND",
"I_ARUNTIMEUNITTEXT",
"I_CALENDARDATE",
"I_CALENDARMONTHNAME",
"I_MATERIAL"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_MATERIAL"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/