I_ARunMntrItemSTO

@AbapCatalog.sqlViewName: 'IARUNMNTRITEMSTO'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Basic View for Stock Transport Orders in ARun Monitor Runs'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #X,
     sizeCategory:   #XXL
   }
}
define view I_ARunMntrItemSTO
  as select from    ekpo as item
    inner join      ekko as head   on item.ebeln = head.ebeln
    inner join      eket as sched  on  item.ebeln = sched.ebeln
                                   and item.ebelp = sched.ebelp
    inner join      ekpv as ship   on  item.ebeln = ship.ebeln
                                   and item.ebelp = ship.ebelp
    left outer join kna1 as cust   on ship.kunnr = cust.kunnr
{ 
    
  item.ebeln                                                                                                                                                                                            as  RequirementDocumentNumber,
  item.ebelp                                                                                                                                                                                            as  RequirementDocumentItem,
  sched.menge                                                                                                                                                                                           as  ScheduleLineOrderQuantity,
  sched.mng02                                                                                                                                                                                           as  ConfdOrderQtyByMatlAvailCheck,
  item.netpr                                                                                                                                                                                            as  NetPriceAmount,
  head.waers                                                                                                                                                                                            as  DocumentCurrency
}
where
       head.reswk      <> ''
  and(
       item.elikz != 'X'
  ) -- delivery completed indicator at item level
  and(
       item.retpo != 'X'
  ) -- return po
  and(
       item.loekz      =  ' '
  ) -- deletion indicator
  and(
       item.eglkz != 'X'
  ) -- final delivery indicator
  and(
       item.pstyp      =  '0'
    or item.pstyp      =  '7'
    or item.pstyp      =  '2'
  ) -- item category in purchasing doc
  and(
       head.bstyp      =  'F'
  ) -- purchasing doc category  , F is PO

  and(
       head.memorytype =  ''
  ) -- Category of Incompletess
  and(
       head.loekz != 'X'
  ) -- deletion indicator
  and(
   sched.mbdat  <> '00000000'
  )
  and (cust.cvp_xblck = ' ' )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EKET",
"EKKO",
"EKPO",
"EKPV",
"KNA1"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/