I_AE_CnsmpnTaxCtrlCodeTxt

@AbapCatalog.sqlViewName: 'IAECTRLCDTXT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Consumption Tax Control Code - Text'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@ObjectModel: {

  dataCategory: #TEXT,

  usageType: {
    dataClass: #MIXED,
    serviceQuality: #C,
    sizeCategory: #L
    }
 }
 
@ObjectModel.representativeKey: 'ConsumptionTaxCtrlCode'

@ObjectModel.modelingPattern:           #LANGUAGE_DEPENDENT_TEXT

@ObjectModel.supportedCapabilities:  [  #LANGUAGE_DEPENDENT_TEXT,
                                        #CDS_MODELING_DATA_SOURCE,
                                        #CDS_MODELING_ASSOCIATION_TARGET,
                                        #SQL_DATA_SOURCE                  ]

@ClientHandling.algorithm: #SESSION_VARIABLE  
@Metadata.ignorePropagatedAnnotations: true
                                                         
define view I_AE_CnsmpnTaxCtrlCodeTxt
  as select from t604n
  association [0..1] to I_Country              as _Country     on  $projection.CountryCode = _Country.Country
  association [0..1] to I_Language             as _Language    on  $projection.Language = _Language.Language
  association [0..1] to I_AE_CnsmpnTaxCtrlCode as _ControlCode on  $projection.CountryCode            = _ControlCode.CountryCode
                                                               and $projection.ConsumptionTaxCtrlCode = _ControlCode.ConsumptionTaxCtrlCode

{
       @Semantics.language: true
       @ObjectModel.foreignKey.association: '_Language'
  key  spras as Language,

       @ObjectModel.foreignKey.association: '_Country'
  key  land1 as CountryCode,

       @ObjectModel.foreignKey.association: '_ControlCode'
  key  steuc as ConsumptionTaxCtrlCode,

       @Semantics.text: true
       text1 as ConsumptionTaxCtrlCodeText1,

       @Semantics.text: true
       text2 as ConsumptionTaxCtrlCodeText2,

       @Semantics.text: true
       text3 as ConsumptionTaxCtrlCodeText3,

       @Semantics.text: true
       text4 as ConsumptionTaxCtrlCodeText4,

       @Semantics.text: true
       text5 as ConsumptionTaxCtrlCodeText5,

       _Language,

       _Country,

       _ControlCode //Make association public


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T604N"
],
"ASSOCIATED":
[
"I_AE_CNSMPNTAXCTRLCODE",
"I_COUNTRY",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/