I_ACMTrdgContractUnitOfMeasure

@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.representativeKey: 'UnitOfMeasure'

@Analytics.dataCategory: #DIMENSION

@VDM.viewType: #BASIC
@AccessControl.authorizationCheck:#NOT_REQUIRED

@AbapCatalog.sqlViewName: 'IACMUOM'
@AbapCatalog.preserveKey:true
@Analytics.internalName:#LOCAL
@AbapCatalog.compiler.compareFilter:true
@Metadata.ignorePropagatedAnnotations:true

@Search.searchable: true

@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Interface View For ACM Trdg Contract UOM'
define view I_ACMTrdgContractUnitOfMeasure
  as select from t006
  association [0..*] to I_ACMUnitOfMeasureText       as _Text          on $projection.UnitOfMeasure = _Text.UnitOfMeasure
  association [0..1] to I_UnitOfMeasureDimension     as _Dimension     on $projection.UnitOfMeasureDimension = _Dimension.UnitOfMeasureDimension
  association [0..*] to I_UnitOfMeasureDimensionText as _DimensionText on $projection.UnitOfMeasureDimension = _DimensionText.UnitOfMeasureDimension
{
      @Semantics.unitOfMeasure: true
      @ObjectModel.filter.enabled: true
      @EndUserText:{ label: 'Internal UoM' }
      @ObjectModel.text.association: '_Text'
  key cast ( msehi as msehiunit preserving type )                                         as UnitOfMeasure,

      @ObjectModel.filter.enabled: false
      cast ( msehi as meinsint )                                                          as UnitOfMeasureSAPCode, //internal unit without conversion


      @ObjectModel.foreignKey.association: '_Dimension'
      @ObjectModel.filter.enabled: false
      @EndUserText:{ label: 'UoM Text' }
      dimid                                                                              as UnitOfMeasureDimension,

      @ObjectModel.filter.enabled: false
      @Consumption.filter.hidden: true
      _Dimension,

      @ObjectModel.filter.enabled: false
      @Consumption.filter.hidden: true
      _DimensionText,

      @ObjectModel.filter.enabled: true
      _Text,
      @ObjectModel.filter.enabled: false
      _DimensionText[ 1: Language = $session.system_language ].UnitOfMeasureDimensionName as UnitOfMeasureDimensionName,

      @ObjectModel.filter.enabled: true
      _Text[ 1: Language = $session.system_language ].UnitOfMeasureLongName               as UnitOfMeasureText,

      @ObjectModel.filter.enabled: true
      _Text[ 1: Language = $session.system_language ].UnitOfMeasureName                   as UnitOfMeasureName,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.filter.enabled: true
      _Text[ 1: Language = $session.system_language ].UnitOfMeasure_E                     as UnitOfMeasure_E
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACMUNITOFMEASURETEXT",
"I_UNITOFMEASUREDIMENSIONTEXT",
"T006"
],
"ASSOCIATED":
[
"I_ACMUNITOFMEASURETEXT",
"I_UNITOFMEASUREDIMENSION",
"I_UNITOFMEASUREDIMENSIONTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/