I_ACMTradingContractTP

@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'ACM Tradng Contract - TP'
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MIXED
}
@VDM.viewType: #TRANSACTIONAL
define view entity I_ACMTradingContractTP
  as select from I_ACMTradingContract
  association [1..1] to I_CmmdtyDrvtvGenericDomainVH      as _AppDocSide       on  $projection.ACMDocumentSide         = _AppDocSide.DomainValue
                                                                               and _AppDocSide.SAPDataDictionaryDomain = 'WLF_PR_SIDE'
  association [1..1] to I_CmmdtyDrvtvGenericDomainVH      as _AppDocType       on  $projection.ContractApplicationType = _AppDocType.DomainValue
                                                                               and _AppDocType.SAPDataDictionaryDomain = '/ACCGO/D_APPL_TYPE'
  association        to parent R_ACMApplicationDocumentTP as _AppDocItem       on  $projection.ReferenceApplicationDocument = _AppDocItem.ApplicationDocument
                                                                               and $projection.ReferenceApplicationItem     = _AppDocItem.ApplicationDocumentItem
                                                                               and $projection.ACMDocumentSide              = _AppDocItem.ACMDocumentSide
                                                                               and $projection.ApplicationDocumentSubItem   = _AppDocItem.ApplicationDocumentSubItem
  association [0..1] to E_ApplicationDocument             as _ExtensionAppData on  $projection.ContractApplicationUUID    = _ExtensionAppData.ContractApplicationUUID
                                                                               and $projection.ContractApplicationVersion = _ExtensionAppData.ContractApplicationVersion
{
  key ContractApplicationUUID,
  key ContractApplicationVersion,
  key ReferenceApplicationDocument,
  key ReferenceApplicationItem,
  key ACMDocumentSide,
  key ApplicationDocumentSubItem,
  key TradingContractNumber,
  key TradingContractItem,
  key cast( ' ' as /accgo/e_dummy_source_lot_id )                                                     as ACMSourcePriceFixationID,
      //  key cast( ' ' as /accgo/e_source_lot_id )                                                           as ACMContractPricingLotID,

      concat( concat( ltrim( TradingContractNumber, '0' ), '/' ), ltrim( TradingContractItem, '0' ) ) as TradingContractNumberItem,
      OverfillID,
      ACMTrdgContrUnderFillID,
      TrdgContractApplUnitOfMeasure,
      ContrItmProvisionalOverFillQty,
      ACMContrItmPrvsnlUnderFillQty,
      TrdgContrItemOverFillQuantity,
      TrdgContrItemUnderFillQuantity,
      TrdgContrItemApplicationQty,
      TrdgContrItemReturnQuantity,
      ContractApplicationType,
      TrdgContrCommoditySubitem,
      Material,
      concat(
      concat(
          cast(
         concat(
           concat(
             concat(substring(ACMDeliveryPeriodStartDate, 7, 2), '.' ),
             concat(substring(ACMDeliveryPeriodStartDate, 5, 2), '.' )
           ),
           substring(ACMDeliveryPeriodStartDate, 1, 4)
         )
         as char10 preserving type), ' -   ' ) ,

         cast(
         concat(
           concat(
             concat(substring(ACMDeliveryPeriodEndDate, 7, 2), '.' ),
             concat(substring(ACMDeliveryPeriodEndDate, 5, 2), '.' )
           ),
           substring(ACMDeliveryPeriodEndDate, 1, 4)
         )
         as char10 preserving type)  )                                                                as ACMContractDeliveryPeriodText,
         ACMDeliveryPeriodStartDate,
         ACMDeliveryPeriodEndDate,
      //      ACMContractDeliveryPeriodText,

      _AppDocItem.AdjustedQuantity,
      _AppDocItem.AdjustedQuantityUoM,
      _AppDocItem.ACMDecimalGrossQuantity,
      _AppDocItem.ACMAppDocBaseUoM,
      //      _AppDocItem.ACMAllocatedQuantity,

      //      _AppDocItem.ACMAppDocDelivUoM,

      //      cast( ' ' as /accgo/e_source_lot_id )                                                           as ACMContractPricingLotID,

      cast( ' ' as /accgo/e_prcfix_stat )                                                             as ACMPrcgFixationStatus,
      cast( '0.000' as /accgo/e_openqty_dec )                                                         as ACMPrcgOpenQty,
      cast( '0.000' as /accgo/e_openqty_dec )                                                         as ACMContrPrcgOpenQty,
      cast( '0.000' as /accgo/e_cpe_total_price_dec )                                                 as ACMContrPrcgTotAmt,
      cast( ' ' as abap.char( 3 ) )                                                                   as ACMContrQtyPercentageValue,
      cast( ' ' as /accgo/e_asgt_dist_mfreeze )                                                       as ACMIndicatorManualFreeze,
      cast( ' ' as /accgo/e_sequence )                                                                as ACMContractSequenceNmbr,
      cast( ' ' as /accgo/e_csl_trade_qty_uom )                                                       as ACMPrcgTotQtyUnit,
      cast( '0.000' as /accgo/e_adjusted_qty_dec )                                                    as ACMApplDocAllocatedQuantity,
      //      cast( '0.000' as /accgo/e_delv_qty_dec )                                                        as ACMDecimalGrossQuantity,

      cast( ' ' as /accgo/cpe_overfill_indicator )                                                    as ACMIsOverfillAllowed,
      cast( ' ' as /accgo/cpe_overfill_indicator )                                                    as ACMIsOverfill,

      /*Associations*/
      _AppDocSide,
      _AppDocType,
      _AppDocItem
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACMTRADINGCONTRACT",
"R_ACMAPPLICATIONDOCUMENTTP"
],
"ASSOCIATED":
[
"I_CMMDTYDRVTVGENERICDOMAINVH",
"R_ACMAPPLICATIONDOCUMENTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/