I_ABCIndicator

@AbapCatalog.sqlViewName: 'IABCINDICATOR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'ABC Indicator'
@ObjectModel.representativeKey: 'ABCIndicator'
@ObjectModel.resultSet.sizeCategory: #XS
@ObjectModel.semanticKey:  [ 'ABCIndicator' ]
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@VDM.viewType: #BASIC

@Metadata.ignorePropagatedAnnotations
@Search.searchable: true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET]
@ObjectModel.alternativeKey:[{id:'OID',element:['ABCIndicatorCodeOID']}] 
//@ObjectModel.sapObjectNodeType.name:'ABCIndicatorCode' 

@ObjectModel.objectIdentifier.oidElement:'ABCIndicatorCodeOID' 
define view I_ABCIndicator
  as select from           t370c
    left outer to one join I_MdiOidConfiguration on I_MdiOidConfiguration.ObjectTypeCode = '5727'
  association [0..*] to I_ABCIndicatorText as _Text on $projection.ABCIndicator = _Text.ABCIndicator
{

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.text.association: '_Text'
  key t370c.abckz as ABCIndicator,
      @ObjectModel.filter.enabled:false
      @ObjectModel.sort.enabled:false

      //Context ID is not specified

      case when I_MdiOidConfiguration.Context is initial

      //Composition is disabled

             or I_MdiOidConfiguration.ComposeOid is initial then

           cast( t370c.abckz as abcindicator_oid ) //use your own data element


      //Context ID is specified

           when I_MdiOidConfiguration.Context    is not initial
      //           and dd07l.domvalue_l                 is not initial

            and I_MdiOidConfiguration.ComposeOid is not initial then

           cast( concat( concat( I_MdiOidConfiguration.Context, ':' ), t370c.abckz ) as abcindicator_oid ) //use your own data element

           end    as ABCIndicatorCodeOID, //use your own OID field name



      _Text
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MDIOIDCONFIGURATION",
"T370C"
],
"ASSOCIATED":
[
"I_ABCINDICATORTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/