F_Mmim_Matdoc

@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'FMMIMMATDOC'
@EndUserText.label: 'Help-View for material documents'
@AccessControl.authorizationCheck:#NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass:#MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE

define view F_Mmim_Matdoc
as
select from matdoc //nsdm_d_mtdcsa


{
 key mblnr as MaterialDocument,
 key mjahr as MaterialDocumentYear,
 key zeile as MaterialDocumentItem,
     matbf as Material,
cast(werks as werks_d) as Plant,
     charg     as Batch,
     lbbsa_sid as InventoryStockType,  
     lgort     as StorageLocation, 
case when lifnr_sid <> '' then lifnr_sid
       when lifnr <> '' then lifnr
       when emlif <> '' then emlif
       else ''
       end                              as Supplier,  
case when mat_kdauf <> '' then mat_kdauf
     else kdauf
     end                                as SalesOrder,
     kunnr      as Customer, 
case when mat_pspnr <> '' then mat_pspnr
     else ps_psp_pnr
     end                                as WBSElementInternalID,                
     umwrk      as IssuingOrReceivingPlant,
     umlgo      as IssuingOrReceivingStorageLoc,
     lbbsa_cid  as IssuingOrReceivingStockType,
     vbeln_im   as DeliveryDocument,
     ebeln      as PurchaseOrder,
     aufnr      as OrderID,
     usnam      as CreatedByUser,
     pernr      as PersonnelNumber,
     work_item_id as WorkItem,
     bwart as GoodsMovementType,
     erfme as EntryUnit,
     blart as AccountingDocumentType,
     sobkz as InventorySpecialStockType,
     sgt_scat as StockSegment,
     fsh_season_year as ProductSeasonYear,
     fsh_season      as ProductSeason,
     fsh_collection  as ProductCollection,
     fsh_theme       as ProductTheme

}
where record_type = 'MDOC' and xauto = ''

               
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"MATDOC"
],
"ASSOCIATED":
[],
"BASE":
[],
"VERSION":0
}
}*/