FINOC_SPL_DC_OI

@AbapCatalog.sqlViewName: 'FINOCV_SPL_DC_OI'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@EndUserText.label: 'OrgChg: Document chains to reconstruct'
define view FINOC_SPL_DC_OI
  as select distinct from fagl_splinfo    as s

    inner join            bkpf            as h  on  s.mandt = h.mandt
                                                and s.bukrs = h.bukrs
                                                and s.belnr = h.belnr
                                                and s.gjahr = h.gjahr

    inner join            bseg            as i  on  s.mandt = i.mandt
                                                and s.bukrs = i.bukrs
                                                and s.belnr = i.belnr
                                                and s.gjahr = i.gjahr
                                                and s.buzei = i.buzei

    left outer join       finoc_split_wl as wl on  wl.mandt = s.mandt
                                               and wl.bukrs = s.bukrs
                                               and wl.belnr = s.belnr
                                               and wl.gjahr = s.gjahr
{
  h.bvorg as bvorg,
  s.bukrs as bukrs,
  s.belnr as belnr,
  s.gjahr as gjahr,
  s.buzei as buzei,
  h.budat as budat,
  i.augdt as augdt,
  i.auggj as auggj,
  i.augbl as augbl,
  i.augcp as augcp,
  i.rebzg as rebzg,
  i.rebzt as rebzt,
  i.rebzz as rebzz,
  i.rebzj as rebzj,
  i.koart as koart,
  h.cpudt as cpudt,
  h.cputm as cputm
}

where   i.xopvw                   =  'X'
  and ( i.koart                   =  'K'
   or   i.koart                   =  'D'  ) // no OI managed G/L accounts

  and   h.glbtgrp                 <> '1'    // no CO documents

  and   wl.status                 is null  
  and ( s.prctr_drvtn_source_type is initial
  
   or ( s.prctr_drvtn_source_type = 'MA'    // Material

  and ( s.matnr is initial or s.werks is initial ) ) 
  
   or ( s.prctr_drvtn_source_type = 'PR'    // Project

  and   s.ps_psp_pnr is initial ) 
  
   or ( s.prctr_drvtn_source_type = 'VB'    // Sales order item

  and ( s.kdauf is initial or s.kdpos is initial ) )  
  
   or ( s.prctr_drvtn_source_type = 'OR'    // Order

  and   s.aufnr is initial ) )
  
  
  
  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"BKPF",
"BSEG",
"FAGL_SPLINFO",
"FINOC_SPLIT_WL"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/