FINOC_RULE_OI

@AbapCatalog.sqlViewName: 'FINOCV_RULE_OI'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@EndUserText.label: 'OrgChange-Rule: Non-Assigned Open Items'
define view FINOC_RULE_OI
  as select from fagl_splinfo        as spl
      inner join bseg                as bseg    on bseg.bukrs  = spl.bukrs
                                               and bseg.belnr  = spl.belnr
                                               and bseg.gjahr  = spl.gjahr
                                               and bseg.buzei  = spl.buzei
     
{ 
  key case when spl.open_item_id is not initial 
           then spl.open_item_id 
           else concat(concat(concat(spl.belnr, spl.gjahr), concat(spl.bukrs, spl.buzei)), spl.spl_no)
           end as open_item_id,
  key cast('          ' as finoc_orgl_change preserving type) as orgl_change,          
  bseg.kokrs as kokrs,     
  spl.bukrs  as bukrs, 
  spl.prctr  as prctr_old,
  cast('          ' as prctr preserving type) as prctr,  
  case when spl.prctr_drvtn_source_type is not initial 
       then spl.prctr_drvtn_source_type
       else cast('OI' as finoc_prctr_drvtn_source_type preserving type) 
                                        end as prctr_drvtn_source_type,
  spl.belnr  as belnr, 
  spl.gjahr  as gjahr,
  spl.buzei  as buzei,
  spl.spl_no as spl_no
}

where   bseg.xopvw                  =  'X'
  and   bseg.augbl                  is initial
  and ( bseg.koart                  =  'K'
   or   bseg.koart                  =  'D'  ) // no OI managed G/L accounts  

  and ( spl.prctr_drvtn_source_type is initial
   or   spl.prctr_drvtn_source_type = 'OI' ) 

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"BSEG",
"FAGL_SPLINFO"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/