FINOC_RULE_NWA_EXAMPLE

@AbapCatalog.sqlViewName: 'FINOCV_RULENWAE'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Organizational Change: Customer Rule NWA'

// default logic for all network activites not bound to plant '0001'


define view FINOC_RULE_NWA_EXAMPLE as
  select from FINOC_RULE_NWA_DEFAULT as default
  inner join  aufk                   as network  on network.aufnr = default.aufnr
  inner join  prps                   as wbs_elmt on wbs_elmt.pspnr = network.pspel
  inner join  proj                   as project  on project.pspnr = wbs_elmt.psphi
{
  key default.aufnr,
  key default.vornr,
  key default.orgl_change,
      default.kokrs,
      default.bukrs,
      default.prctr_old,
      default.prctr,
      default.prctr_drvtn_source_type,
      default.srce_ps_psp_pnr,
      default.srce_ps_prj_pnr,
      default.srce_aufnr,
      default.aufpl,
      default.aplzl,
      project.werks
}
where project.werks <> '0001' // plant restriction


union all

// fixed value for all network activites bound to plant '0001'


select from FINOC_RULE_NWA_BASE as base
inner join  proj                as project on project.pspnr = base.ps_prj_pnr
{
  key base.aufnr,
  key base.vornr,
  key base.orgl_change,
      base.kokrs,
      base.bukrs,
      base.prctr_old,
      cast( 'A-0420-000' as finoc_prctr_new preserving type ) as prctr,
      base.prctr_drvtn_source_type, // initial by default

      base.srce_ps_psp_pnr,         // initial by default

      base.srce_ps_prj_pnr,         // initial by default

      base.srce_aufnr,              // initial by default

      base.aufpl,
      base.aplzl,
      project.werks
}
where project.werks = '0001' // plant restriction

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FINOC_RULE_NWA_BASE",
"FINOC_RULE_NWA_DEFAULT",
"AUFK",
"PROJ",
"PRPS"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/