FINCS_UH_GLACCOUNTHIER

@AbapCatalog.sqlViewName: 'FINCS_UH_CS02H'
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType: {
  dataClass: #MIXED,
  serviceQuality: #C,
  sizeCategory: #S
}
@EndUserText.label: 'Universal Hierarchy G/L Account Hierarchy'
define view FINCS_UH_GLACCOUNTHIER as select from uhdt_vrsn as version
left outer join uhdt_hier as hier on version.hier_hid = hier.hier_hid and
                                version.hier_catg = hier.hier_catg and
                                hier.lang = $session.system_language
inner join uhdt_clfd_val as clfdvalue on version.ver_id = clfdvalue.obj_id
association [1..1] to fac_cds_uh_category   as to_category   on $projection.HierarchyCategory = to_category.CategoryKey
{
  version.ver_id as VersionId,
  version.ver_vldfm as ValidityStartDate,
  version.ver_vldto as ValidityEndDate,
  version.ver_msg as VersionMessage,
  case
  when ( ver_status = 'R' or ver_status = 'A' ) and locked_by = $session.user
  then 'I' 
  else version.ver_status end as VersionStatus,
  cast( '' as vrstxt) as VersionStatusText,
  version.hier_catg as HierarchyCategory,
  version.hier_hid as HierarchyId,
  hier.hier_desc as HierarchyText,
  cast( concat(concat(version.hier_hid, concat(' (',version.ver_vldfm) ), concat(concat('~',version.ver_vldto), ')') ) as vhdec) as HierarchyVersionText,
  case clfdvalue.val_sign
  when 'S' then cast( clfdvalue.val_low as fincs_uhcoa )
  when 'R' then cast( concat(clfdvalue.val_low,concat('~',clfdvalue.val_high)) as fincs_uhcoa )
  else cast( clfdvalue.val_low as fincs_uhcoa ) end as ChartOfAccounts,
  to_category
}
where version.hier_catg = 'CS02'
and clfdvalue.fld_name = 'CHARTOFACCOUNTS'
and version.ver_status <> 'T'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"UHDT_CLFD_VAL",
"UHDT_HIER",
"UHDT_VRSN"
],
"ASSOCIATED":
[
"FAC_CDS_UH_CATEGORY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/