FCML_ACT_PERDS_DDL

@AbapCatalog.sqlViewName: 'FCML_ACT_PERDS_V'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.type: #CLIENT_DEPENDENT
@ClientHandling.algorithm: #AUTOMATED
@EndUserText.label: 'CDS View for all relevant period (Actual Costing)'
define view FCML_ACT_PERDS_DDL 
  as select distinct from finsc_period     as per
    inner join            t001             as t001   on per.fiscal_year_variant = t001.periv
    inner join            t001k            as t001k  on t001k.bukrs = t001.bukrs
    inner join            t001w            as t001w  on t001k.bwkey = t001w.bwkey
    inner join            fcml_perminmax_v as minmax on per.fiscal_year_period between minmax.min_jahrper and minmax.max_jahrper
{
  key        per.fiscal_year_period as jahrper
}
  where
        t001w.mgvupd          = 'X'
    and per.is_special_period = ''

  union 
  select distinct from finsc_period     as per
    inner join               t001             as t001   on per.fiscal_year_variant = t001.periv
    inner join               t001k            as t001k  on t001k.bukrs = t001.bukrs
    inner join               t001w            as t001w  on t001k.bwkey = t001w.bwkey
    inner join               fcml_perminmax_v as minmax on per.fiscal_year_period = minmax.max_jahrper
{
  cast ( concat(per.next_fiscal_period_fiscal_year , per.next_fiscal_period) as jahrper ) as jahrper
}
  where
        t001w.mgvupd          = 'X'
    and per.is_special_period = '';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FINSC_PERIOD",
"T001",
"T001K",
"T001W",
"FCML_PERMINMAX_V"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/