FCLM_BALANCE_ACCOUNT

@AbapCatalog.sqlViewName: 'VBALACCOUNT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Account with manual balance'
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #C
@ClientHandling.algorithm: #SESSION_VARIABLE
define view FCLM_BALANCE_ACCOUNT as select from fclm_bam_amd as account
left outer join FCLM_BAM_SINGLE_HBA as _hba on account.acc_id = _hba.BankAccountInternalID
                                        and account.revision = _hba.BankAccountRevision
left outer join fclm_bam_amd_t as _desc on account.acc_id   = _desc.acc_id
                                      and account.revision = _desc.revision
                                      and _desc.langu   = $session.system_language
                                      and _desc.deleted_flag <> 'X'
left outer join FCLM_BAM_LATEST_BALANCE as _balance on account.acc_id = _balance.BankAccountInternalID
association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_CountryText as _Country on $projection.BankCountry = _Country.Country and _Country.Language = $session.system_language
association [0..1] to I_CurrencyText as _Currency on $projection.BankAccountCurrency = _Currency.Currency and _Currency.Language = $session.system_language
association [0..1] to I_Bank as _Bank on $projection.BankCountry = _Bank.BankCountry and $projection.BankKey = _Bank.BankInternalID
association [0..1] to I_BankAccountTypeText as _BankAccountTypeText on $projection.BankAccountType = _BankAccountTypeText.BankAccountType and _BankAccountTypeText.Language = $session.system_language
association [0..1] to I_BankAccountStatus as _BankAccountStatus on $projection.BankAccountStatus = _BankAccountStatus.BankAccountStatus and _BankAccountStatus.Language = $session.system_language
association [0..1] to I_UserContactCard as _CreateUser on $projection.CreatedByUser = _CreateUser.ContactCardID                   //Note 3350469

association [0..1] to I_UserContactCard as _LastChangeUser on $projection.LastChangedByUser = _LastChangeUser.ContactCardID       //Note 3350469

association [0..1] to I_CashBalanceChannelText as _BalanceChannelText on $projection.CashBalanceChannel = _BalanceChannelText.CashBalanceChannel
                                                                     and _BalanceChannelText.Language = $session.system_language
{
   key account.acc_id as  BankAccountInternalID,
   key _balance.CashBalanceDate,
   key _balance.CashBalanceKey,
   @Semantics.amount.currencyCode : 'CashBalanceCurrency'
   _balance.CashBalanceAmount,
   _balance.CashBalanceCurrency,
   _balance.CashBalanceChannel,
   _BalanceChannelText.CashBalanceChannelText,
   _balance.LastChangedByUser,
   _balance.LastChangeDateTime,
   _LastChangeUser.FullName as LastChangedByUserName,  //Note 3350469

   _balance.CreatedByUser,
   _CreateUser.FullName as CreatedByUserName,          //Note 3350469

   _balance.CashBalanceCreatedAtDateTime,
   account.acc_num as BankAccountNumber,
   account.waers as BankAccountCurrency,
   _desc.description as BankAccountDescription,
   account.status as BankAccountStatus,
   account.acc_type_id as BankAccountType,
   account.banks as BankCountry,
   account.bankl as BankKey,
   account.iban,
   account.bukrs as CompanyCode,
   //remoteaccount.RemoteSystem,

   _hba.HouseBank,
   _hba.HouseBankAccount,
   _hba.GLAccount,
   //remoteaccount.RemoteAccount,

   _CompanyCode.CompanyCodeName,
   _Country.CountryShortName,
   _Currency.CurrencyShortName,
   _Bank.BankName,
   _BankAccountTypeText.BankAccountTypeText,
   _BankAccountStatus.BankAccountStatusName,
   _CompanyCode,
   _Country,
   _Currency,
   _Bank,
   _BankAccountTypeText,
   _BankAccountStatus,
   _CreateUser,
   _LastChangeUser
}
where account.revision = '0000' and (  account.status = '02' or account.status = '09' or account.status = '10' or account.status = '11' or account.status = '15' )
and _balance.CashBalanceDate <> '00000000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BANK",
"I_BANKACCOUNTSTATUS",
"I_BANKACCOUNTTYPETEXT",
"I_CASHBALANCECHANNELTEXT",
"I_COMPANYCODE",
"I_COUNTRYTEXT",
"I_CURRENCYTEXT",
"I_USERCONTACTCARD",
"FCLM_BAM_AMD",
"FCLM_BAM_AMD_T"
],
"ASSOCIATED":
[
"I_BANK",
"I_BANKACCOUNTSTATUS",
"I_BANKACCOUNTTYPETEXT",
"I_CASHBALANCECHANNELTEXT",
"I_COMPANYCODE",
"I_COUNTRYTEXT",
"I_CURRENCYTEXT",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/