FAC_CDS_VE_VALIDATION_GROUP

@AbapCatalog.sqlViewName: 'FACVEGROUP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['to_CreatedByContactCard', 'to_ChangedByContactCard']
@EndUserText.label: 'Validation Group'
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #C,
  sizeCategory: #L
}
define view FAC_CDS_VE_VALIDATION_GROUP
  as select from           fac_cds_uh_version             as Version
    inner join             fac_cds_uh_clfd_value          as CLASSFIED     on  Version.VersionId   = CLASSFIED.ObjectId
                                                                           and CLASSFIED.FieldName = 'VALIDATIONSCENARIOID'
    inner join             uhdt_node                      as node          on  Version.VersionId = node.ver_id
                                                                           and node.node_type    = 'R'
    inner join             FAC_CDS_VE_VALIDATION_SCENARIO as scenario      on scenario.ValidationScenarioID = CLASSFIED.LowValue
    left outer join        fac_ve_scenariot               as _ScenarioText on  _ScenarioText.scen_id = CLASSFIED.LowValue
                                                                           and _ScenarioText.langu   = $session.system_language

    left outer to one join I_User                         as usnam_user    on usnam_user.UserID = Version.CreatedBy
    left outer to one join I_User                         as ppnam_user    on ppnam_user.UserID = Version.UpdatedBy
    


  association [0..1] to FAC_VE_GRP_STATUST    as _StatusText   on  _StatusText.ValidationGroupStatus = $projection.ValidationGroupStatus
  association [1..*] to fac_cds_ve_group_node as to_node       on  $projection.VersionId = to_node.VersionId
  association [1..1] to fac_cds_uh_category   as to_category   on  $projection.HierarchyCategory = to_category.CategoryKey
  association [1..*] to fac_cds_uh_clfd_value as to_clfd_value on  $projection.VersionId = to_clfd_value.ObjectId
  association [0..*] to FAC_CDS_UH_CD         as to_changelog  on  $projection.VersionId = to_changelog.VersionId
                                                               and to_changelog.Langauge = $session.system_language
  association [0..1] to I_UserContactCard     as to_CreatedByContactCard on $projection.CreatedBy = to_CreatedByContactCard.ContactCardID
  association [0..1] to I_UserContactCard     as to_ChangedByContactCard on $projection.ChangedBy = to_ChangedByContactCard.ContactCardID
{
  key Version.VersionId                     as VersionId,
      Version.HierarchyCategory             as HierarchyCategory,
      node.node_lval                        as ValidationGroupID,
      Version.HierarchyText                 as ValidationGroupDescription,
      CLASSFIED.LowValue                    as ValidationScenarioID,
      Version.VersionStatus                 as ValidationGroupStatus,
      _StatusText.ValidationGroupStatusText as ValidationGroupStatusText,
      scenario.EnableAssignment             as EnableAssignment,
      Version.CreatedAt,
      usnam_user.UserDescription            as CreatedByFullName,
      @Consumption.semanticObject: 'CreatedBy'
      @ObjectModel.foreignKey.association: 'to_CreatedByContactCard'
      Version.CreatedBy,
      Version.UpdatedAt                     as ChangedAt,
      @Consumption.semanticObject: 'ChangedBy'
      @ObjectModel.foreignKey.association: 'to_ChangedByContactCard'
      Version.UpdatedBy                     as ChangedBy,
      ppnam_user.UserDescription            as ChangedByFullName,
      Version.LockedAt                      as LockedAt,
      Version.LockedBy                      as LockedBy,
      _ScenarioText.descr                   as ScenarioText,

      /* Associations */
      _StatusText,
      to_node,
      to_changelog,
      to_category,
      to_clfd_value,
      to_CreatedByContactCard,
      to_ChangedByContactCard
}
where
  Version.HierarchyCategory = 'GL05'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FAC_CDS_UH_CLFD_VALUE",
"FAC_CDS_UH_VERSION",
"FAC_CDS_VE_VALIDATION_SCENARIO",
"FAC_VE_GRP_STATUST",
"I_USER",
"FAC_VE_SCENARIOT",
"UHDT_NODE"
],
"ASSOCIATED":
[
"FAC_CDS_UH_CATEGORY",
"FAC_CDS_UH_CD",
"FAC_CDS_UH_CLFD_VALUE",
"FAC_CDS_VE_GROUP_NODE",
"FAC_VE_GRP_STATUST",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/