FAC_CDS_UH_SEGMENTNODE

@AbapCatalog.sqlViewName: 'FACV_UH_SEGMEDGE'
@AccessControl.authorizationCheck: #CHECK
//@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Universal Hierarchy Segment Node'
@ObjectModel.usageType: {
  dataClass: #MIXED,
  serviceQuality: #C,
  sizeCategory: #S
}
define view FAC_CDS_UH_SEGMENTNODE as select from uhdt_node as node
inner join uhdt_vrsn as version on node.ver_id = version.ver_id
left outer join uhdt_ntxt as ntxt on node.node_id = ntxt.node_id
                         and ntxt.lang = $session.system_language
association[1..1] to fac_cds_uh_version as to_version on $projection.VersionId = to_version.VersionId
{
  key node.node_id as NodeId,
  node.node_type as NodeType,
  node.ver_id as VersionId,
  version.hier_hid as HierarchyId,
  version.ver_nbr as VersionNumber,
  version.ver_msg as VersionMessage,
  version.ver_vldfm as ValidFrom,
  case 
  when ( ver_status = 'R' or ver_status = 'A' ) and locked_by = $session.user
  then cast ( 'I' as vrsst ) 
  else version.ver_status end as VersionStatus,
  cast(node.node_lval as ncval) as NodeValue,
  ntxt.lval_txt as NodeText,
  case 
  when node.node_hval = '' then case 
               when ntxt.lval_txt is null or ntxt.lval_txt = '' then cast( node.node_lval as nltxt )
               else cast( concat( node.node_lval, concat(' (',concat( ntxt.lval_txt, ')' ) ) ) as nltxt ) end 
  else cast (concat(node.node_lval,concat('~',node.node_hval)) as nltxt) end as NodeValueText,
  cast( upper(ntxt.lval_txt) as nltxt ) as NodeTextUpper,
  to_version
}
where version.hier_catg = 'GL01'
and (node.node_type = 'N' or node.node_type = 'R' or node.node_type = 'Z')
and version.ver_status <> 'T'
and version.ver_status <> 'B' 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"UHDT_NODE",
"UHDT_NTXT",
"UHDT_VRSN"
],
"ASSOCIATED":
[
"FAC_CDS_UH_VERSION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/