FAC_CDS_UH_GLACCOUNTHIER

@AbapCatalog.sqlViewName: 'FAC_UH_GLACCHIER'
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType: {
  dataClass: #MIXED,
  serviceQuality: #C,
  sizeCategory: #S
}
@EndUserText.label: 'Universal Hierarchy G/L Account'
define view FAC_CDS_UH_GLACCOUNTHIER
  as select from    uhdt_vrsn     as version
    left outer join uhdt_hier     as hier      on  version.hier_hid  = hier.hier_hid
                                               and version.hier_catg = hier.hier_catg
                                               and hier.lang         = $session.system_language
    inner join      uhdt_clfd_val as clfdvalue on version.ver_id = clfdvalue.obj_id
  association [1..1] to fac_cds_uh_category          as to_category       on  $projection.HierarchyCategory = to_category.CategoryKey
{
  version.ver_id                         as VersionId,
  version.ver_msg                        as VersionMessage,
  case
  when ( ver_status = 'R' or ver_status = 'A' ) and locked_by = $session.user
  then cast ( 'I' as vrsst )
  else version.ver_status end            as VersionStatus,
  cast( '' as vrstxt)                    as VersionStatusText,
  version.hier_catg                      as HierarchyCategory,
  version.hier_hid                       as HierarchyId,
  hier.hier_desc                         as HierarchyText,
  cast( version.hier_hid as vhdec )      as HierarchyVersionText,
  // cast( concat(concat(version.hier_hid, concat(' (',version.ver_vldfm) ), concat(concat('~',version.ver_vldto), ')') ) as vhdec) as HierarchyVersionText,

  cast( clfdvalue.val_low as ktopl)      as ChartOfAccounts,
  cast( upper(hier.hier_desc) as vhdec ) as HierarchyTextUpper,
  to_category
}
where
       version.hier_catg                       =  '0109'
  and  clfdvalue.fld_name                      =  'CHARTOFACCOUNTS'
  and  version.ver_status                      <> 'T'
  and  version.ver_status                      <> 'B'

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"UHDT_CLFD_VAL",
"UHDT_HIER",
"UHDT_VRSN"
],
"ASSOCIATED":
[
"FAC_CDS_UH_CATEGORY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/