FAC_AUDIT_Z3_POSTINGKEY

@AbapCatalog.sqlViewName: 'FAC_AUDPSTKEY'
@EndUserText.label: 'Posting Key'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass:  #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable

define view FAC_AUDIT_Z3_POSTINGKEY
  with parameters
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_LANGUAGE
    P_Language : sylangu
  as select from tbsl

  association [0..*] to I_PostingKeyWthSpclGLCodeTxt    as _Text                 on $projection.PostingKey = _Text.PostingKey
  association [0..1] to I_DebitCreditCode      as _DebitCreditCode      on $projection.DebitCreditCode = _DebitCreditCode.DebitCreditCode
  association [1..1] to I_FinancialAccountType as _FinancialAccountType on $projection.FinancialAccountType = _FinancialAccountType.FinancialAccountType
{
      @ObjectModel.text.association: '_Text'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
  key cast(tbsl.bschl as fis_bschl preserving type)   as PostingKey,
      cast(tbsl.shkzg as fis_shkzg preserving type )  as DebitCreditCode,
      _DebitCreditCode._Text[1: Language = $parameters.P_Language ].DebitCreditCodeName,
      cast(tbsl.koart as farp_koart preserving type ) as FinancialAccountType,
      _FinancialAccountType._Text[1: Language = $parameters.P_Language ].FinancialAccountTypeName,
      cast(tbsl.xumsw as farp_xumsw preserving type)  as IsSalesRelated,
      tbsl.xzahl                                      as IsUsedInPaymentTransaction,
      tbsl.stbsl                                      as ReversalPostingKey,
      tbsl.xsonu                                      as IsSpecialGLTransaction,
      _Text[1: Language = $parameters.P_Language].SpecialGLCode,
      _Text[1: Language = $parameters.P_Language]._SpecialGLCode._Text[1: Language = $parameters.P_Language].SpecialGLCodeName,
      _Text[1: Language = $parameters.P_Language].PostingKeyName,

      @EndUserText.label: 'System Client'
      mandt                                           as SystemClient,
      faus1                                           as AccountPostingKeyField1,
      faus2                                           as AccountPostingKeyField2,

      _Text
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DEBITCREDITCODE",
"I_DEBITCREDITCODETEXT",
"I_FINANCIALACCOUNTTYPE",
"I_FINANCIALACCOUNTTYPETEXT",
"I_POSTINGKEYWTHSPCLGLCODETXT",
"I_SPECIALGLCODE",
"I_SPECIALGLCODETEXT",
"TBSL"
],
"ASSOCIATED":
[
"I_DEBITCREDITCODE",
"I_FINANCIALACCOUNTTYPE",
"I_POSTINGKEYWTHSPCLGLCODETXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/