FAA_ES_ASSET_MD_TDD

@AbapCatalog.sqlViewName: 'FAAESMDTDD'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType: {
        serviceQuality: #P,
        sizeCategory: #L

    }
@EndUserText.label: 'Fixed Asset Time Dependent Data (current intervall) for Enterprise Search'

define view FAA_ES_ASSET_MD_TDD

  as select from    faat_md_tdd
    left outer join tka02 on tka02.bukrs = faat_md_tdd.comp_code

  association [0..1] to I_CompanyCode     as _CompanyCode     on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_CostCenter      as _CostCenter      on  $projection.CostCenter      = _CostCenter.CostCenter
                                                              and tka02.kokrs                 = _CostCenter.ControllingArea
                                                              and $projection.ValidityEndDate = _CostCenter.ValidityEndDate
  association [0..*] to cskt              as _TO_CSKT         on  $projection.ValidityEndDate = _TO_CSKT.datbi
                                                              and $projection.CostCenter      = _TO_CSKT.kostl
                                                              and $projection.ControllingArea = _TO_CSKT.kokrs

  association [0..1] to I_Plant           as _Plant           on  $projection.Plant = _Plant.Plant
  //Association required to retrieve PlantName, since Enterprise Search does not support fields with CAST

  association [0..1] to t001w             as _TO_T001W        on  $projection.Plant = _TO_T001W.werks
  association [0..1] to I_BusinessArea    as _BusinessArea    on  $projection.BusinessArea = _BusinessArea.BusinessArea
  //Association required to retrieve BusinessAreaName, since Enterprise Search does not support fields with CAST

  association [0..1] to tgsbt             as _TO_TGSBT        on  $projection.BusinessArea = _TO_TGSBT.gsber
                                                              and _TO_TGSBT.spras          = $session.system_language
  association [0..1] to I_InternalOrder   as _InternalOrder   on  $projection.internalorder = _InternalOrder.InternalOrder
  association [0..1] to I_ProfitCenter    as _ProfitCenter    on  $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
                                                              and $projection.ControllingArea = _ProfitCenter.ControllingArea
                                                              and $projection.ValidityEndDate = _ProfitCenter.ValidityEndDate
  association [0..1] to I_FunctionalArea  as _FunctionalArea  on  $projection.functionalarea = _FunctionalArea.FunctionalArea
  association [0..1] to I_ControllingArea as _ControllingArea on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_Location        as _AssetLocation   on  $projection.AssetLocation = _AssetLocation.Location
                                                              and $projection.Plant         = _AssetLocation.Plant
  association [0..1] to I_Employment      as _Employment      on  $projection.PersonnelNumber = _Employment.EmploymentInternalID

{
      @ObjectModel: {foreignKey: {association: '_CompanyCode'}}
  key comp_code               as CompanyCode,
  key asset_no                as MasterFixedAsset,
  key asset_subno             as FixedAsset,
  key valid_to_date           as ValidityEndDate,
      valid_from_date         as ValidityStartDate,
      @ObjectModel: {foreignKey: {association: '_CostCenter'}}
      cost_center             as CostCenter,

      tka02.kokrs             as ControllingArea,
      @ObjectModel: {foreignKey: {association: '_AssetLocation'}}
      location                as AssetLocation,
      @ObjectModel: {foreignKey: {association: '_BusinessArea'}}
      business_area           as BusinessArea,
      @ObjectModel: {foreignKey: {association: '_Plant'}}
      plant                   as Plant,
      personnel_number        as PersonnelNumber,
      car_license_plate       as vehiclelicenseplatenumber,
      budget_period           as budgetperiod,
      fund                    as Fund,
      functional_area         as functionalarea,
      grant_id                as grantid,
      @ObjectModel: {foreignKey: {association: '_ProfitCenter'}}
      profit_center           as ProfitCenter,
      internal_order          as internalorder,
      responsible_cost_center as responsiblecostcenter,

      _CompanyCode,
      _CostCenter,
      _TO_CSKT,
      _Plant,
      _TO_T001W,
      _BusinessArea,
      _TO_TGSBT,
      _InternalOrder,
      _ProfitCenter,
      _AssetLocation

}
where
      valid_to_date   >= $session.system_date
  and valid_from_date <= $session.system_date
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FAAT_MD_TDD",
"TKA02"
],
"ASSOCIATED":
[
"I_BUSINESSAREA",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_EMPLOYMENT",
"I_FUNCTIONALAREA",
"I_INTERNALORDER",
"I_LOCATION",
"I_PLANT",
"I_PROFITCENTER",
"CSKT",
"T001W",
"TGSBT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/