FAA_DUE_VALUES

@AbapCatalog.sqlViewName: 'FAAV_DUE_VALUES'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
@EndUserText.label: 'Ausstehende Abschreibungen Vorjahre zu GJ-Beginn'

define view FAA_DUE_VALUES

  as select from faat_plan_values as values
    inner join   faat_cmp_da      as area      on  area.comp_code = values.bukrs
                                               and area.depr_area = values.afabe
    inner join   faat_md_val      as valuation on  valuation.comp_code   = values.bukrs
                                               and valuation.asset_no    = values.anln1
                                               and valuation.asset_subno = values.anln2
                                               and valuation.depr_area   = values.afabe
    inner join   I_CalendarYear   as year      on year.CalendarYear > values.gjahr // Items in result year must be sum of PLAN_VALUES of prior years

  //                                               and year.CalendarYear <= valuation.current_fiscal_year // No items in future fiscal years

  //                                               and year.CalendarYear >  area.closed_fisc_year         // No items in closed years

    inner join   finsts_faa_bcf   as mapping   on values.slalittype = mapping.slalittype_srce

{
  key values.bukrs                    as bukrs,
  key values.anln1                    as anln1,
  key values.anln2                    as anln2,
  key values.afabe                    as afabe,
  key mapping.slalittype_trgt         as slalittype,
      year.CalendarYear               as gjahr,
      '000'                           as poper,
      '999'                           as bwasl,      
      '00'                            as movcat,
      @Semantics.amount.currencyCode: 'RHCUR'
      sum( values.hsl )               as hsl,
      @Semantics.amount.currencyCode: 'RKCUR'
      sum( values.ksl )               as ksl,
      @Semantics.amount.currencyCode: 'ROCUR'
      sum( values.osl )               as osl,
      @Semantics.amount.currencyCode: 'RVCUR'
      sum( values.vsl )               as vsl,
      @Semantics.amount.currencyCode: 'RBCUR'
      sum( values.bsl )               as bsl,
      @Semantics.amount.currencyCode: 'RCCUR'
      sum( values.csl )               as csl,
      @Semantics.amount.currencyCode: 'RDCUR'
      sum( values.dsl )               as dsl,
      @Semantics.amount.currencyCode: 'RECUR'
      sum( values.esl )               as esl,
      @Semantics.amount.currencyCode: 'RFCUR'
      sum( values.fsl )               as fsl,
      @Semantics.amount.currencyCode: 'RGCUR'
      sum( values.gsl )               as gsl,
      @Semantics.currencyCode: true
      values.rhcur                    as rhcur,
      @Semantics.currencyCode: true
      values.rkcur                    as rkcur,
      @Semantics.currencyCode: true
      values.rocur                    as rocur,
      @Semantics.currencyCode: true
      values.rvcur                    as rvcur,
      @Semantics.currencyCode: true
      values.rbcur                    as rbcur,
      @Semantics.currencyCode: true
      values.rccur                    as rccur,
      @Semantics.currencyCode: true
      values.rdcur                    as rdcur,
      @Semantics.currencyCode: true
      values.recur                    as recur,
      @Semantics.currencyCode: true
      values.rfcur                    as rfcur,
      @Semantics.currencyCode: true
      values.rgcur                    as rgcur,
      valuation.calculation_view_type as calc_view_Type
}

where
      year.CalendarYear <= valuation.current_fiscal_year // No items in future fiscal years

  and year.CalendarYear >  area.closed_fisc_year // No items in closed fiscal years 

  and values.xpost      =  'X'

group by
  values.bukrs,
  values.anln1,
  values.anln2,
  values.afabe,
  year.CalendarYear,
  mapping.slalittype_trgt,
  values.rhcur,
  values.rkcur,
  values.rocur,
  values.rvcur,
  values.rbcur,
  values.rccur,
  values.rdcur,
  values.recur,
  values.rfcur,
  values.rgcur,
  valuation.calculation_view_type
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CALENDARYEAR",
"FAAT_CMP_DA",
"FAAT_MD_VAL",
"FAAT_PLAN_VALUES",
"FINSTS_FAA_BCF"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/