FAA_CompDrvdAreaPlanVal01

@AbapCatalog.sqlViewName: 'FAAVPDAPV01'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Compare Derived Area PLAN_VALUES 01'

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XXL

define view FAA_CompDrvdAreaPlanVal01
  as select from    faagtt_plan_val          as plan_values
    left outer join acdoca                   as acdoca       on  plan_values.bukrs      = acdoca.rbukrs
                                                             and plan_values.anln1      = acdoca.anln1
                                                             and plan_values.anln2      = acdoca.anln2
                                                             and plan_values.gjahr      = acdoca.gjahr
                                                             and plan_values.afabe      = acdoca.afabe
                                                             and plan_values.poper      = acdoca.depr_period
                                                             and plan_values.slalittype = acdoca.slalittype
                                                             and acdoca.awtyp           = 'AMDP'
                                                             and acdoca.mig_source      = 'A'
    left outer join FAA_CompDrvdAreaSplitNum as split_number on  split_number.bukrs        = plan_values.bukrs
                                                             and split_number.anln1        = plan_values.anln1
                                                             and split_number.anln2        = plan_values.anln2
                                                             and split_number.gjahr        = plan_values.gjahr
                                                             and split_number.afabe        = plan_values.afabe
                                                             and split_number.poper        = plan_values.poper
                                                             and split_number.slalittype   = plan_values.slalittype
                                                             and split_number.source_table = 'PLAN_VALUES'
{
  key plan_values.bukrs,
  key plan_values.anln1,
  key plan_values.anln2,
  key plan_values.gjahr,
  key plan_values.afabe,
  key plan_values.poper,
  key plan_values.slalittype,
  key cast( acdoca.rldnr as fins_technical_ledger preserving type ) as rldnr,
  key acdoca.belnr,
  key acdoca.docln,
      cast( case
              when split_number.counter is null then 0
              else split_number.counter
            end as int4 preserving type )                           as split_number,

      plan_values.movcat                                            as s_movcat,
      acdoca.movcat                                                 as t_movcat,
      case
        when acdoca.rbukrs is null then 'X'
        when ( plan_values.movcat = '46' and acdoca.movcat <> '06' ) or
             ( plan_values.movcat = '65' and acdoca.movcat <> '06' ) or
             ( plan_values.movcat <> '46' and plan_values.movcat <> '65' and plan_values.movcat <> acdoca.movcat ) then 'X'
        else ''
      end                                                           as movcat_d,

      @Semantics.amount.currencyCode: 's_rhcur'
      plan_values.hsl                                               as s_hsl,
      @Semantics.amount.currencyCode: 't_rhcur'
      acdoca.hsl                                                    as t_hsl,
      case
        when acdoca.rbukrs is null then 'X'
        when plan_values.hsl <> acdoca.hsl then 'X'
        else ''
      end                                                           as hsl_d,

      @Semantics.amount.currencyCode: 's_rkcur'
      plan_values.ksl                                               as s_ksl,
      @Semantics.amount.currencyCode: 't_rkcur'
      acdoca.ksl                                                    as t_ksl,
      case
        when acdoca.rbukrs is null then 'X'
        when plan_values.ksl <> acdoca.ksl then 'X'
        else ''
      end                                                           as ksl_d,

      @Semantics.amount.currencyCode: 's_rocur'
      plan_values.osl                                               as s_osl,
      @Semantics.amount.currencyCode: 't_rocur'
      acdoca.osl                                                    as t_osl,
      case
        when acdoca.rbukrs is null then 'X'
        when plan_values.osl <> acdoca.osl then 'X'
        else ''
      end                                                           as osl_d,

      @Semantics.currencyCode: true
      plan_values.rhcur                                             as s_rhcur,
      @Semantics.currencyCode: true
      acdoca.rhcur                                                  as t_rhcur,
      case
        when acdoca.rbukrs is null then 'X'
        when plan_values.rhcur <> acdoca.rhcur then 'X'
        else ''
      end                                                           as rhcur_d,

      @Semantics.currencyCode: true
      plan_values.rkcur                                             as s_rkcur,
      @Semantics.currencyCode: true
      acdoca.rkcur                                                  as t_rkcur,
      case
        when acdoca.rbukrs is null then 'X'
        when plan_values.rkcur <> acdoca.rkcur then 'X'
        else ''
      end                                                           as rkcur_d,

      @Semantics.currencyCode: true
      plan_values.rocur                                             as s_rocur,
      @Semantics.currencyCode: true
      acdoca.rocur                                                  as t_rocur,
      case
        when acdoca.rbukrs is null then 'X'
        when plan_values.rocur <> acdoca.rocur then 'X'
        else ''
      end                                                           as rocur_d,

      plan_values.anlkl                                             as s_anlkl,
      acdoca.anlkl                                                  as t_anlkl,
      case
        when acdoca.rbukrs is null then 'X'
        when plan_values.anlkl = '' and acdoca.anlkl = '' then 'X'
        when plan_values.anlkl <> '' and plan_values.anlkl <> acdoca.anlkl then 'X'
        else ''
      end                                                           as anlkl_d,

      plan_values.ktogr                                             as s_ktogr,
      acdoca.ktogr                                                  as t_ktogr,
      case
        when acdoca.rbukrs is null then 'X'
        when plan_values.ktogr = '' and acdoca.ktogr = '' then 'X'
        when plan_values.ktogr <> '' and plan_values.ktogr <> acdoca.ktogr then 'X'
        else ''
      end                                                           as ktogr_d,

      plan_values.mig_source                                        as s_mig_source,
      acdoca.mig_source                                             as t_mig_source,
      case
        when acdoca.rbukrs is null then 'X'
        when ( plan_values.sdm_status = '20' and acdoca.mig_source <> 'A') or
             ( plan_values.sdm_status <> '20' and plan_values.mig_source <> acdoca.mig_source ) then 'X'
        else ''
      end                                                           as mig_source_d,

      plan_values.recid                                             as s_recid,
      acdoca.recid                                                  as t_recid,
      case
        when acdoca.rbukrs is null then 'X'
        when plan_values.recid <> acdoca.recid then 'X'
        else ''
      end                                                           as recid_d,

      @EndUserText.label: 'Different'
      @EndUserText.quickInfo: 'Has some differences'
      case
        when acdoca.rbukrs is null then 'Y'
        when plan_values.poper <> acdoca.poper then 'X'
        when ( plan_values.movcat = '46' and acdoca.movcat <> '06' ) or
             ( plan_values.movcat = '65' and acdoca.movcat <> '06' ) or
             ( plan_values.movcat <> '46' and plan_values.movcat <> '65' and plan_values.movcat <> acdoca.movcat ) then 'X'
        when plan_values.hsl <> acdoca.hsl then 'X'
        when plan_values.ksl <> acdoca.ksl then 'X'
        when plan_values.osl <> acdoca.osl then 'X'
        when plan_values.rhcur <> acdoca.rhcur then 'X'
        when plan_values.rkcur <> acdoca.rkcur then 'X'
        when plan_values.rocur <> acdoca.rocur then 'X'
        when ( plan_values.anlkl = '' and acdoca.anlkl = '' ) or
             ( plan_values.anlkl <> '' and plan_values.anlkl <> acdoca.anlkl ) then 'X'
        when ( plan_values.ktogr = '' and acdoca.ktogr = '' ) or
             ( plan_values.ktogr <> '' and plan_values.ktogr <> acdoca.ktogr ) then 'X'
        when ( plan_values.sdm_status = '20' and acdoca.mig_source <> 'A') or
             ( plan_values.sdm_status <> '20' and plan_values.mig_source <> acdoca.mig_source ) then 'X'
        when plan_values.recid <> acdoca.recid then 'X'
        else ''
      end                                                           as different,

      plan_values.sdm_status
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FAA_COMPDRVDAREASPLITNUM",
"ACDOCA",
"FAAGTT_PLAN_VAL"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/