EHENV_ADEF_ADEF_DEFS

@AbapCatalog.sqlViewName: 'EHENV_ADEF_ADEF'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Location Aggregation - Loc. Aggregation'
@AccessControl.authorizationCheck: #NOT_REQUIRED
//CDS View Performance annotation

@ObjectModel.usageType:{ serviceQuality: #P,
                         sizeCategory:  #S,         // < 1000

                         dataClass: #MASTER }
define view EHENV_ADEF_ADEF_DEFS
  with parameters
    p_langu           : lang,
    p_subj_type       : ehfnd_amns_subj_type,
    p_unit            : ehfnd_unit_code,
    p_usage_period    : ehenv_usage_period,
    p_xsource_type    : ehfnd_amns_src_type,
    p_aggr_cla_keyref : /bobf/conf_key

  as select distinct from ehenvd_adef_root as adef_root
    left outer join       ehenvd_adef_acla as adef_acla on  adef_acla.parent_key                   = adef_root.db_key
                                                        and adef_acla.aggr_classifier_root_key_ref = $parameters.p_aggr_cla_keyref
    inner join            ehenvd_scen_aggr as scen_aggr on  scen_aggr.is_owned_indicator = 'X'
                                                        and adef_root.db_key             = scen_aggr.adef_root_key_ref
    inner join            ehenvd_scen_root as scen_root on scen_root.db_key = scen_aggr.parent_key
    association [0..1] to I_EHSCmplncScenNameFllbckLang as scen_text on scen_root.db_key = scen_text.EHSComplianceScenarioRootUUID
{

  adef_root.db_key,
  adef_root.db_key               as root_key,
  adef_root.loc_root_key_ref,
  adef_root.name,
  adef_root.title,
  adef_root.subject_root_key_ref as subject_root_key_ref,
  scen_root.db_key               as scenario_key,
  scen_text._ComplianceScenarioNameText.EHSComplianceScenarioName as scenario_name,
  scen_root.status               as scenario_status,
  $parameters.p_xsource_type     as source_type,
  case
     when adef_acla.set_ind = 'X'   then 'X'
     when adef_acla.set_ind = ' '   then ' '
     when adef_acla.set_ind is null then '-'
     else '-'
  end                            as set_ind
}
where
  adef_root.unit              = $parameters.p_unit
  and adef_root.usage_period      = $parameters.p_usage_period
  and adef_root.subject_type_code = $parameters.p_subj_type
  and scen_root.status            <> '02'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EHSCMPLNCSCENNAME",
"I_EHSCMPLNCSCENNAMEFLLBCKLANG",
"EHENVD_ADEF_ACLA",
"EHENVD_ADEF_ROOT",
"EHENVD_SCEN_AGGR",
"EHENVD_SCEN_ROOT"
],
"ASSOCIATED":
[
"I_EHSCMPLNCSCENNAMEFLLBCKLANG"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/