DHADM_MON_AccessPlanSummary

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Data for access plan summary tab'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity DHADM_MON_AccessPlanSummary
  as select from    dhcdc_rtobjcalc                as objinfo
    join            DHADM_MON_AcsPlanSummaryStatus as status       on status.acd_id = objinfo.acd_id
    left outer join dhcdc_objfilter                as objfilter    on  objfilter.subscriber_id = objinfo.subscriber_id
                                                                   and objfilter.objname       = objinfo.objname
                                                                   and objfilter.objtype       = objinfo.objtype
    left outer join DHADM_MON_TransferStatusText   as transfertext on  status.TransferStatus = transfertext.Status
                                                                   and transfertext.Language = $session.system_language
    left outer join DHADM_MON_ACPCalcStatusText    as calcText     on  status.CalculationStatus = calcText.Status
                                                                   and calcText.Language        = $session.system_language
    left outer join DHADM_MON_READING_TYPE         as readTypeText on  readTypeText.Status   = '5'
                                                                   and readTypeText.Language = $session.system_language
{
  key objinfo.subscriber_id    as SubscriberId,
  key objinfo.objtype          as Objtype,
  key objinfo.objname          as Objname,
      objinfo.max_delim_jobs   as MaxAcdJobs,
      objinfo.max_acp_jobs     as MaxAcpJobs,
      objinfo.max_acp_records  as MaxAcpRecords,
      objinfo.min_acp          as MinAcps,
      objinfo.max_block_size   as MaxBlockSizeBytes,
      objinfo.max_portion_rows as MaxPortionRows,
      status.TablePartitons,
      status.CalculationStatus,
      calcText.Text            as CalculationStatusText,
      status.TransferStatus,
      transfertext.Text        as TransferStatusText,
      status.AccessPlanTotal,
      status.AccessPlanCalcuated,
      status.AccessPlanFailed,
      status.AccessPlanInTransfer,
      status.AccessPlanTransferred,
      status.CalculationInSec,
      status.TransferInSec,
      status.TotalRuntimeInSec,
      status.CalculatedRows,
      status.CalculatedBytes,
      status.PortionsTotal,
      status.PortionsFinished,
      status.PortionsInTransfer,
      status.PortionsError,
      objfilter.expression     as Filter,
      readTypeText.Text        as ReadingTypeText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DHADM_MON_ACPCALCSTATUSTEXT",
"DHADM_MON_ACSPLANSUMMARYSTATUS",
"DHADM_MON_READING_TYPE",
"DHADM_MON_TRANSFERSTATUSTEXT",
"DHCDC_OBJFILTER",
"DHCDC_RTOBJCALC"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/