C_WrkCtrObjPgInProcOp

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Wrk Ctr Obj Pg In Process Operations'
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@UI.headerInfo.typeName: 'Operation In Progress'
@UI.headerInfo.typeNamePlural: 'Operations In Progress'
@UI.lineItem: [{criticality: 'OperationStatusCriticality'}]

define view entity C_WrkCtrObjPgInProcOp
  as select from P_InProcessOperations
{
      @UI.hidden
  key OrderInternalBillOfOperations,
      @UI.hidden
  key OrderIntBillOfOperationsItem,
  
      @UI.hidden
  key WorkCenterInternalID,

      @Consumption.semanticObject: 'ProductionOrder'
      @UI.lineItem: [ { position: 10, label: 'Production Order'}]             
      @EndUserText.label: 'Production Order'
      @UI.identification: [{type: #FOR_INTENT_BASED_NAVIGATION, semanticObject: 'ProductionOrder'}]
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderStdVH', element: 'ManufacturingOrder' } } ]
      ManufacturingOrder,

      @ObjectModel.text.element: ['MfgOrderOperationText']
      @UI.lineItem: [{position: 20}]
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrdOpBySemanticKeyStdVH', element: 'ManufacturingOrderOperation' } } ]
      ManufacturingOrderOperation,
      @UI.hidden
      ManufacturingOrderCategory,
      @UI.hidden: true
      MfgOrderOperationText,
      @Consumption.semanticObject: 'Material'
      @UI.lineItem: [ { position: 30, label: 'Material'}]   
      @UI.identification: [{type: #FOR_INTENT_BASED_NAVIGATION, semanticObject: 'Material'}]           
      @EndUserText.label: 'Material'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      Material,
      @UI.lineItem: [{position:35}]
      @EndUserText:{label:'Material Description',quickInfo: 'Material Description'}
      _Material._Text[1:Language=$session.system_language].MaterialName,
      @UI.lineItem: [{position:40}]
      @EndUserText:{label:'Operation Is Partially Confirmed',quickInfo: 'Operation Is Partially Confirmed'}
      OperationIsPartiallyConfirmed,
      @EndUserText.label: 'Operation Is Released'
      @EndUserText.quickInfo: 'Operation Is Released'
      OperationIsReleased,
      @UI.lineItem: [{position:50}]
      @EndUserText.label: 'Planned Start Date'
      OpErlstSchedldExecStrtDte,
      @EndUserText.label: 'Planned Start Time'
      @UI.lineItem: [{position:60}]
      OpErlstSchedldExecStrtTme,
      @EndUserText.label: 'Planned End Date'
      @UI.lineItem: [{position:70}]
      OpErlstSchedldExecEndDte,
      @EndUserText.label: 'Planned End Time'
      @UI.lineItem: [{position:80}]
      OpErlstSchedldExecEndTme,
      @UI.lineItem: [{position:90}]
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      OpPlannedTotalQuantity,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_UnitOfMeasureStdVH', element: 'UnitOfMeasure' } } ]
      OperationUnit,
      @UI.lineItem: [{position:100}]
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @EndUserText.label: 'Confirmed Quantity'
      OpTotalConfirmedYieldQty,
      @EndUserText.label: 'Planned Duration'
      ErlstSchedldExecDurnInWorkdays,
      @EndUserText.label: 'Actual Duration'
      OpActualExecutionDays,
      @ObjectModel.foreignKey.association: '_MfgOrderSequence'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderSequenceStdVH', element: 'ManufacturingOrderSequence' } } ]
      ManufacturingOrderSequence,
      @EndUserText:{label:'Order Is Delivered ',quickInfo: 'Order Is Delivered'}
      OrderIsDelivered,
      @EndUserText:{label:'Order Is Technically Completed ',quickInfo: 'Order Is Technically Completed'}
      OrderIsTechnicallyCompleted,
      _Material,
      _MfgOrder,
      _MfgOrderSequence,
      @UI.hidden: true
       cast (case      
        when (OpErlstSchedldExecStrtDte = $session.system_date and  OpErlstSchedldExecStrtTme >    tstmp_to_tims( tstmp_current_utctimestamp(), abap_system_timezone( $session.client,'NULL' ),
                     $session.client,
                     'NULL' ) )
        then 0
        when( OpErlstSchedldExecStrtDte = $session.system_date and  OpErlstSchedldExecStrtTme  <   tstmp_to_tims( tstmp_current_utctimestamp(), abap_system_timezone( $session.client,'NULL' ),
                     $session.client,
                     'NULL' ) )
        then 1        
        when OpErlstSchedldExecStrtDte < $session.system_date 
        then 1   
       end as mpe_opstatuscritly )    as OperationStatusCriticality
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIAL",
"I_MATERIALTEXT",
"P_INPROCESSOPERATIONS"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_MFGORDER",
"I_MFGORDERSEQUENCE"
],
"BASE":
[
"P_INPROCESSOPERATIONS"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/