C_WorkPermitOrderOperationVH

@AbapCatalog.sqlViewName: 'CWRKPMTORDEROPVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Work Permit Order Operations'
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #S, dataClass: #META}
@VDM.viewType: #CONSUMPTION
@ObjectModel.dataCategory:#VALUE_HELP
@ObjectModel.representativeKey: 'MaintenanceOrder'
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true
define view C_WorkPermitOrderOperationVH
  as select from I_MaintenanceOrderOperation as _MaintenanceOrderOperation
{
         @ObjectModel.foreignKey.association: '_MaintenanceOrder'
  key    _MaintenanceOrderOperation.MaintenanceOrder,
         @UI.lineItem: [{ position:  10, label: 'Operation Number' }]
         @EndUserText:{ label: 'Operation Number', quickInfo: 'Operation Number'}
         @Search.defaultSearchElement: true
         @Search.ranking: #HIGH
         @Consumption.filter.hidden:true
         @Search.fuzzinessThreshold: 0.8
  key    cast ( _MaintenanceOrderOperation.MaintenanceOrderOperation as vdm_vornr preserving type)          as MaintenanceOrderOperation,
         _MaintenanceOrderOperation.OperationDescription                                                    as OperationDescription,
         _MaintenanceOrderOperation.MaintOrderOperationCounter                                              as MaintOrderOperationCounter,
         _MaintenanceOrderOperation.MaintOrderRoutingNumber,
         @ObjectModel.text.element: ['PlantName']
         @UI.lineItem: [{ position:  60, label: 'Plant Name' }]
         @UI: {
           textArrangement: #TEXT_ONLY
         }
         _MaintenanceOrderOperation.Plant                                                                   as Plant,
         _MaintenanceOrderOperation._Plant.PlantName                                                        as PlantName,
         @EndUserText:{ label: 'Work Center', quickInfo: 'Work Center'}
         @UI.lineItem: [{ position:  50, label: 'Work Center' }]
         @UI: {
         textArrangement: #TEXT_ONLY
         }
         @ObjectModel.text.element: ['WorkCenterText']
         _MaintenanceOrderOperation._WorkCenter.WorkCenter                                                  as WorkCenter,
         _MaintenanceOrderOperation._WorkCenter._Text[1:Language = $session.system_language].WorkCenterText as WorkCenterText,
         _MaintenanceOrderOperation.MaintOrderOperationInternalID,
         @EndUserText.label: 'System Status'
         @ObjectModel: {
           virtualElement: true,
           virtualElementCalculatedBy: 'ABAP:CL_EAM_ORDOP_STS_EXIT'
         }
         @Semantics.text: true
         @UI.lineItem: [{ position:  70, label: 'System Status' }]
         @Search.defaultSearchElement: true
         cast ('' as vdm_j_system_status_concat_t)                                                          as ConcatenatedActiveSystStsName,


         _MaintenanceOrder

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTENANCEORDEROPERATION",
"I_PLANT",
"I_WORKCENTER",
"I_WORKCENTERTEXT"
],
"ASSOCIATED":
[
"I_MAINTENANCEORDER"
],
"BASE":
[
"I_MAINTENANCEORDEROPERATION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/