C_WorkPermitOrderOperationTP

@EndUserText.label: 'Work Permit Order and Operations'
@Metadata.allowExtensions:true
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #M, dataClass: #TRANSACTIONAL}
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@UI: {
  headerInfo: { typeName: 'Assigned Operations',
                typeNamePlural: 'Assigned Operations',
                title: { type: #STANDARD,label: 'Assigned Operations' } },
                presentationVariant: [{ sortOrder: [{ by: 'MaintOrderOperationCounter' }],
                          groupBy: [ 'MaintOrderOperationCounter'  ],visualizations: [{ type: #AS_LINEITEM }],
                          requestAtLeast: [ 'MaintOrderOperationCounter' ]  }]
     }
define view entity C_WorkPermitOrderOperationTP
  as projection on R_WorkPermitOrderOperationTP
{
      @UI.hidden: true
  key WorkPermit,
      @UI.hidden: true
  key OperationOrderRoutingNumber,
  key MaintOrderOperationCounter,
      @UI.lineItem: [{ position:  10, label: 'Operation Number' }]
      @EndUserText:{ label: 'Operation Number', quickInfo: 'Operation Number'}
      @ObjectModel.text.element: ['OperationDescription']
      @Search.defaultSearchElement: true
      cast ( _MaintenanceOrderOperation.MaintenanceOrderOperation as vdm_vornr preserving type)          as MaintenanceOrderOperation,
      @UI.hidden: true
      _MaintenanceOrderOperation.OperationDescription,
      @UI.hidden: true
      MaintenanceOrder,
      @EndUserText:{ label: 'Work Center', quickInfo: 'Work Center'}
      @UI.lineItem: [{ position:  50, label: 'Work Center' }]
      @UI: {
      textArrangement: #TEXT_ONLY
      }
      @ObjectModel.text.element: ['WorkCenterText']
      @Search.defaultSearchElement: true
      _MaintenanceOrderOperation._WorkCenter.WorkCenter,
      @Search.defaultSearchElement: true
      @UI.hidden: true
      _MaintenanceOrderOperation._WorkCenter._Text[1:Language = $session.system_language].WorkCenterText as WorkCenterText,
      @Search.defaultSearchElement: true
      @ObjectModel.text.element: ['PlantName']
      @UI.lineItem: [{ position:  60, label: 'Plant Name' }]
      @UI: {
        textArrangement: #TEXT_ONLY
      }
      _MaintenanceOrderOperation.Plant,
      @Search.defaultSearchElement: true
      @UI.hidden: true
      _MaintenanceOrderOperation._Plant.PlantName,
      _MaintenanceOrderOperation.MaintOrderOperationInternalID,
      @EndUserText.label: 'System Status'
      @ObjectModel: {
        virtualElement: true,
        virtualElementCalculatedBy: 'ABAP:CL_EAM_ORDOP_STS_EXIT'
      }
      @Semantics.text: true
      @UI.lineItem: [{ position:  70, label: 'System Status' }]
      @Search.defaultSearchElement: true
      ConcatenatedActiveSystStsName,
      @UI.hidden: true
      _MaintenanceOrderOperation,
      _WorkPermit : redirected to parent C_WorkPermitTP
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTENANCEORDEROPERATION",
"I_PLANT",
"I_WORKCENTER",
"I_WORKCENTERTEXT",
"R_WORKPERMITORDEROPERATIONTP"
],
"ASSOCIATED":
[
"C_WORKPERMITTP",
"I_MAINTENANCEORDEROPERATION",
"R_WORKPERMITTP"
],
"BASE":
[
"R_WORKPERMITORDEROPERATIONTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/