C_Weightuom

@AbapCatalog:{
  sqlViewName: 'CWEIGHTUOM',
  compiler.compareFilter: true,
  preserveKey: true
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Unit of measure for weight'
@ObjectModel.representativeKey : 'WeightUnit'
@Search.searchable: true
@VDM.viewType: #CONSUMPTION

@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory : #S
@ObjectModel.usageType.dataClass: #CUSTOMIZING


define view C_Weightuom
  as select from I_UnitOfMeasure

  association [0..*] to I_UnitOfMeasureText as _Text on $projection.WeightUnit = _Text.UnitOfMeasure
{

      @Semantics.unitOfMeasure: true
      @ObjectModel.text.association: '_Text'
      @Search:{                     //required. Else search set as false as other searchable fields are hidden

        defaultSearchElement: true,
        fuzzinessThreshold: 0.6
      }
  key cast ( I_UnitOfMeasure.UnitOfMeasure as gewei preserving type ) as WeightUnit,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Consumption.hidden: true
      I_UnitOfMeasure.UnitOfMeasure_E,
      
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Consumption.hidden: true
      _Text[1: Language = $session.system_language ].UnitOfMeasureLongName as UnitOfMeasureLongName,
      _Text
}

where
  UnitOfMeasureDimension = 'MASS'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_UNITOFMEASURE",
"I_UNITOFMEASURETEXT"
],
"ASSOCIATED":
[
"I_UNITOFMEASURETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/