C_WBSElementGraphOverview
WBS Element Graph Overview
C_WBSElementGraphOverview is a Consumption CDS View that provides data about "WBS Element Graph Overview" in SAP S/4HANA. It reads from 1 data source (I_WBSElementByInternalKey) and exposes 82 fields with key fields WBSElementExternalID, Version. It has 7 associations to related views.
Data Sources (1)
| Source | Alias | Join Type |
|---|---|---|
| I_WBSElementByInternalKey | ProjectWBSElement | from |
Associations (7)
| Cardinality | Target | Alias | Condition |
|---|---|---|---|
| [0..1] | I_StsObjConcatActiveStsILL | _Status | _Status.StatusObject = $projection.WBSElementObject |
| [1..1] | C_ProjectForNetworkGraph | _Project | _Project.ProjectInternalID = $projection.ProjectInternalID |
| [0..1] | I_FreeDfndTblFieldSemanticText | _FieldKeyLabel | $projection.FreeDefinedTableFieldSemantic = _FieldKeyLabel.FreeDefinedTableFieldSemantic and _FieldKeyLabel.Language = $session.system_language |
| [0..1] | I_ProjectApplicant | _ProjectApplicant | $projection.ApplicantCode = _ProjectApplicant.ApplicantCode |
| [0..*] | I_CostCenter | _ResponsibleCostCenter | _ResponsibleCostCenter.CostCenter = $projection.ResponsibleCostCenter and _ResponsibleCostCenter.ControllingArea = $projection.RespCostCenterControllingArea |
| [0..1] | I_Plant | _Plant | $projection.Plant = _Plant.Plant |
| [0..*] | I_ProfitCenter | _ProfitCenter | $projection.ProfitCenter = _ProfitCenter.ProfitCenter and $projection.ControllingArea = _ProfitCenter.ControllingArea |
Annotations (12)
| Name | Value | Level | Field |
|---|---|---|---|
| AbapCatalog.sqlViewName | CPROJWBSELEMOVW | view | |
| AbapCatalog.compiler.compareFilter | true | view | |
| AbapCatalog.preserveKey | true | view | |
| AccessControl.authorizationCheck | #CHECK | view | |
| EndUserText.label | WBS Element Graph Overview | view | |
| VDM.viewType | #CONSUMPTION | view | |
| ObjectModel.usageType.serviceQuality | #D | view | |
| ObjectModel.usageType.sizeCategory | #XL | view | |
| ObjectModel.usageType.dataClass | #MIXED | view | |
| ClientHandling.algorithm | #SESSION_VARIABLE | view | |
| Metadata.ignorePropagatedAnnotations | true | view | |
| Metadata.allowExtensions | true | view |
Fields (82)
| Key | Field | Source Table | Source Field | Description |
|---|---|---|---|---|
| KEY | WBSElementExternalID | |||
| KEY | Version | |||
| WBSElementInternalID | WBSElementInternalID | |||
| WBSDescriptionendasWBSDescription | ||||
| ProjectTypeName | Project Type | |||
| PriorityCodeName | Priority | |||
| WBSElementObject | I_WBSElementByInternalKey | WBSElementObject | ||
| ProjectInternalID | I_WBSElementByInternalKey | ProjectInternalID | ||
| FreeDefinedTableFieldSemantic | I_WBSElementByInternalKey | FreeDefinedTableFieldSemantic | ||
| FreeDfndTableFieldSemanticName | _FieldKeyLabel | FreeDfndTableFieldSemanticName | ||
| ProjectType | I_WBSElementByInternalKey | ProjectType | ||
| ControllingArea | I_WBSElementByInternalKey | ControllingArea | ||
| RespCostCenterControllingArea | I_WBSElementByInternalKey | RespCostCenterControllingArea | ||
| ProfitCenter | I_WBSElementByInternalKey | ProfitCenter | ||
| IsMarkedForDeletion | I_WBSElementByInternalKey | IsMarkedForDeletion | ||
| Plant | I_WBSElementByInternalKey | Plant | ||
| PlantName | _Plant | PlantName | ||
| WBSElementHierarchyLevel | I_WBSElementByInternalKey | WBSElementHierarchyLevel | ||
| ResponsiblePersonName | I_WBSElementByInternalKey | ResponsiblePersonName | Person Responsible Name | |
| ApplicantName | I_WBSElementByInternalKey | ApplicantName | Applicant Name | |
| ControllingObjectClassName | ||||
| ControllingAreaName | ||||
| CompanyCodeName | ||||
| BusinessAreaName | ||||
| BasicStartDate | I_WBSElementByInternalKey | BasicStartDate | Start Date | |
| BasicEndDate | I_WBSElementByInternalKey | BasicEndDate | End Date | |
| SchedldBasicEarliestStartDate | I_WBSElementByInternalKey | SchedldBasicEarliestStartDate | Earliest Start Date | |
| SchedldBasicEarliestEndDate | I_WBSElementByInternalKey | SchedldBasicEarliestEndDate | Earliest End Date | |
| SchedldBasicLatestStartDate | I_WBSElementByInternalKey | SchedldBasicLatestStartDate | Latest Start Date | |
| ScheduledBasicLatestEndDate | I_WBSElementByInternalKey | ScheduledBasicLatestEndDate | Latest End Date | |
| ActualStartDate | I_WBSElementByInternalKey | ActualStartDate | Actual Start Date | |
| ActualEndDate | I_WBSElementByInternalKey | ActualEndDate | Actual End Date | |
| BasicDuration | I_WBSElementByInternalKey | BasicDuration | Duration | |
| BasicDurationUnit | I_WBSElementByInternalKey | BasicDurationUnit | Duration Unit | |
| TentativeActualStartDate | I_WBSElementByInternalKey | TentativeActualStartDate | Tentative Actual Start Date | |
| TentativeActualEndDate | I_WBSElementByInternalKey | TentativeActualEndDate | Tentative Actual End Date | |
| ActualDuration | I_WBSElementByInternalKey | ActualDuration | Actual Duration | |
| ActualDurationUnit | I_WBSElementByInternalKey | ActualDurationUnit | Actual Duration Unit | |
| SchedldFcstdEarliestStartDate | I_WBSElementByInternalKey | SchedldFcstdEarliestStartDate | Forecast Earliest Start Date | |
| SchedldFcstdEarliestEndDate | I_WBSElementByInternalKey | SchedldFcstdEarliestEndDate | Forecast Earliest End Date | |
| LatestSchedldFcstdStartDate | I_WBSElementByInternalKey | LatestSchedldFcstdStartDate | Forecast Latest Start Date | |
| LatestSchedldFcstdEndDate | I_WBSElementByInternalKey | LatestSchedldFcstdEndDate | Forecast Latest End Date | |
| WBSElementIsPlanningElement | I_WBSElementByInternalKey | WBSElementIsPlanningElement | ||
| WBSIsAccountAssignmentElement | I_WBSElementByInternalKey | WBSIsAccountAssignmentElement | ||
| WBSElementIsBillingElement | I_WBSElementByInternalKey | WBSElementIsBillingElement | ||
| CostCenter | I_WBSElementByInternalKey | CostCenter | Cost Center to which costs are posted | |
| ResponsibleCostCenter | I_WBSElementByInternalKey | ResponsibleCostCenter | ||
| ProjectExternalID | ||||
| ProjectDescription | _Project | ProjectDescription | ||
| FreeDefinedAttribute01 | I_WBSElementByInternalKey | FreeDefinedAttribute01 | ||
| FreeDefinedAttribute02 | I_WBSElementByInternalKey | FreeDefinedAttribute02 | ||
| FreeDefinedAttribute03 | I_WBSElementByInternalKey | FreeDefinedAttribute03 | ||
| FreeDefinedAttribute04 | I_WBSElementByInternalKey | FreeDefinedAttribute04 | ||
| FreeDefinedQuantity1Unit | I_WBSElementByInternalKey | FreeDefinedQuantity1Unit | ||
| FreeDefinedQuantity1 | I_WBSElementByInternalKey | FreeDefinedQuantity1 | ||
| FreeDefinedQuantity2Unit | I_WBSElementByInternalKey | FreeDefinedQuantity2Unit | ||
| FreeDefinedQuantity2 | I_WBSElementByInternalKey | FreeDefinedQuantity2 | ||
| FreeDefinedAmount1Currency | I_WBSElementByInternalKey | FreeDefinedAmount1Currency | ||
| FreeDefinedAmount1 | ||||
| FreeDefinedAmount2Currency | I_WBSElementByInternalKey | FreeDefinedAmount2Currency | ||
| FreeDefinedAmount2 | ||||
| FreeDefinedDate1 | I_WBSElementByInternalKey | FreeDefinedDate1 | ||
| FreeDefinedDate2 | I_WBSElementByInternalKey | FreeDefinedDate2 | ||
| FreeDefinedIndicator1 | I_WBSElementByInternalKey | FreeDefinedIndicator1 | ||
| FreeDefinedIndicator2 | I_WBSElementByInternalKey | FreeDefinedIndicator2 | ||
| FreeDefinedAttribute01Label | _FieldKeyLabel | FreeDefinedAttribute01Label | ||
| FreeDefinedAttribute02Label | _FieldKeyLabel | FreeDefinedAttribute02Label | ||
| FreeDefinedAttribute03Label | _FieldKeyLabel | FreeDefinedAttribute03Label | ||
| FreeDefinedAttribute04Label | _FieldKeyLabel | FreeDefinedAttribute04Label | ||
| FreeDefinedQuantity1Label | _FieldKeyLabel | FreeDefinedQuantity1Label | ||
| FreeDefinedQuantity2Label | _FieldKeyLabel | FreeDefinedQuantity2Label | ||
| FreeDefinedAmount1Label | _FieldKeyLabel | FreeDefinedAmount1Label | ||
| FreeDefinedAmount2Label | _FieldKeyLabel | FreeDefinedAmount2Label | ||
| FreeDefinedDate1Label | _FieldKeyLabel | FreeDefinedDate1Label | ||
| FreeDefinedDate2Label | _FieldKeyLabel | FreeDefinedDate2Label | ||
| FreeDefinedIndicator1Label | _FieldKeyLabel | FreeDefinedIndicator1Label | ||
| FreeDefinedIndicator2Label | _FieldKeyLabel | FreeDefinedIndicator2Label | ||
| _Project | _Project | |||
| _ProjectApplicant | _ProjectApplicant | |||
| _ResponsibleCostCenter | _ResponsibleCostCenter | |||
| _Plant | _Plant | |||
| _ProfitCenter | _ProfitCenter |
@AbapCatalog.sqlViewName: 'CPROJWBSELEMOVW'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'WBS Element Graph Overview'
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory : #XL
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata: { ignorePropagatedAnnotations: true,
allowExtensions:true }
define view C_WBSElementGraphOverview
as select from I_WBSElementByInternalKey as ProjectWBSElement
association [0..1] to I_StsObjConcatActiveStsILL as _Status on _Status.StatusObject = $projection.WBSElementObject
association [1..1] to C_ProjectForNetworkGraph as _Project on _Project.ProjectInternalID = $projection.ProjectInternalID
association [0..1] to I_FreeDfndTblFieldSemanticText as _FieldKeyLabel on $projection.FreeDefinedTableFieldSemantic = _FieldKeyLabel.FreeDefinedTableFieldSemantic
and _FieldKeyLabel.Language = $session.system_language
association [0..1] to I_ProjectApplicant as _ProjectApplicant on $projection.ApplicantCode = _ProjectApplicant.ApplicantCode
association [0..*] to I_CostCenter as _ResponsibleCostCenter on _ResponsibleCostCenter.CostCenter = $projection.ResponsibleCostCenter
and _ResponsibleCostCenter.ControllingArea = $projection.RespCostCenterControllingArea
association [0..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
association [0..*] to I_ProfitCenter as _ProfitCenter on $projection.ProfitCenter = _ProfitCenter.ProfitCenter
and $projection.ControllingArea = _ProfitCenter.ControllingArea
{
//Header and keys
@ObjectModel.text.element: ['WBSDescription']
key cast (ProjectWBSElement.WBSElementExternalID as ps_posid_edit ) as WBSElementExternalID,
key cast( '' as vsnmr_v ) as Version,
WBSElementInternalID,
@Semantics.text: true
case
when ProjectWBSElement._WBSElementShortText.LanguageBasedShortText is not initial
then ProjectWBSElement._WBSElementShortText.LanguageBasedShortText
else ProjectWBSElement.WBSDescription
end as WBSDescription ,
//ProjectWBSElement.WBSDescription as WBSDescription,
@EndUserText.label: 'Project Type'
cast ( ProjectWBSElement._ProjectType._Text[1:Language = $session.system_language].ProjectTypeName as ps_s4_pratx preserving type ) as ProjectTypeName,
@EndUserText.label: 'Priority'
cast ( ProjectWBSElement._PriorityCode._Text[1:Language = $session.system_language].PriorityCodeName as ps_s4_priotext preserving type ) as PriorityCodeName,
ProjectWBSElement.WBSElementObject as WBSElementObject,
ProjectWBSElement.ProjectInternalID as ProjectInternalID,
@ObjectModel.text.element: ['FreeDfndTableFieldSemanticName']
ProjectWBSElement.FreeDefinedTableFieldSemantic as FreeDefinedTableFieldSemantic,
@Semantics.text: true
@ObjectModel.filter.enabled: false
_FieldKeyLabel.FreeDfndTableFieldSemanticName as FreeDfndTableFieldSemanticName,
ProjectWBSElement.ProjectType as ProjectType,
ProjectWBSElement.ControllingArea as ControllingArea,
ProjectWBSElement.RespCostCenterControllingArea as RespCostCenterControllingArea,
ProjectWBSElement.ProfitCenter as ProfitCenter,
ProjectWBSElement.IsMarkedForDeletion as IsMarkedForDeletion,
cast ( _ProfitCenter[1: ValidityEndDate >= $session.system_date
and ValidityStartDate <= $session.system_date]._Text[1:Language = $session.system_language].ProfitCenterName as fis_mcpct ) as ProfitCenterName,
ProjectWBSElement.Plant as Plant,
_Plant.PlantName as PlantName,
cast( case
when ProjectWBSElement.ApplicantCode = '00000000'
then ''
else ProjectWBSElement.ApplicantCode
end as ps_s4_astnr ) as ApplicantCode,
//General Information
ProjectWBSElement.WBSElementHierarchyLevel as WBSElementHierarchyLevel,
@EndUserText.label: 'Person Responsible Name'
ProjectWBSElement.ResponsiblePersonName as ResponsiblePersonName,
@EndUserText.label: 'Applicant Name'
ProjectWBSElement.ApplicantName as ApplicantName,
cast ( ProjectWBSElement._ControllingObjectClass._Text[1:Language = $session.system_language].ControllingObjectClassName as ps_s4_scope_cvtext ) as ControllingObjectClassName,
cast ( ProjectWBSElement._ControllingArea.ControllingAreaName as ps_s4_bezei preserving type ) as ControllingAreaName,
cast ( ProjectWBSElement._CompanyCode.CompanyCodeName as ps_s4_butxt preserving type ) as CompanyCodeName,
cast ( ProjectWBSElement._BusinessArea._Text[1:Language = $session.system_language].BusinessAreaName as fis_gtext preserving type ) as BusinessAreaName,
@EndUserText.label: 'Start Date'
ProjectWBSElement.BasicStartDate as BasicStartDate,
@EndUserText.label: 'End Date'
ProjectWBSElement.BasicEndDate as BasicEndDate,
@EndUserText.label: 'Earliest Start Date'
ProjectWBSElement.SchedldBasicEarliestStartDate as SchedldBasicEarliestStartDate,
@EndUserText.label: 'Earliest End Date'
ProjectWBSElement.SchedldBasicEarliestEndDate as SchedldBasicEarliestEndDate,
@EndUserText.label: 'Latest Start Date'
ProjectWBSElement.SchedldBasicLatestStartDate as SchedldBasicLatestStartDate,
@EndUserText.label: 'Latest End Date'
ProjectWBSElement.ScheduledBasicLatestEndDate as ScheduledBasicLatestEndDate,
@EndUserText.label: 'Actual Start Date'
ProjectWBSElement.ActualStartDate as ActualStartDate,
@EndUserText.label: 'Actual End Date'
ProjectWBSElement.ActualEndDate as ActualEndDate,
@EndUserText.label: 'Duration'
@Semantics.quantity.unitOfMeasure: 'BasicDurationUnit'
ProjectWBSElement.BasicDuration as BasicDuration,
@EndUserText.label: 'Duration Unit'
@Semantics.unitOfMeasure: true
ProjectWBSElement.BasicDurationUnit as BasicDurationUnit,
@EndUserText.label: 'Tentative Actual Start Date'
ProjectWBSElement.TentativeActualStartDate as TentativeActualStartDate,
@EndUserText.label: 'Tentative Actual End Date'
ProjectWBSElement.TentativeActualEndDate as TentativeActualEndDate,
@EndUserText.label: 'Actual Duration'
@Semantics.quantity.unitOfMeasure: 'ActualDurationUnit'
ProjectWBSElement.ActualDuration as ActualDuration,
@EndUserText.label: 'Actual Duration Unit'
@Semantics.unitOfMeasure: true
ProjectWBSElement.ActualDurationUnit as ActualDurationUnit,
@EndUserText.label: 'Forecast Start Date'
ProjectWBSElement.ForecastedStartDate as ForecastedStartDate,
@EndUserText.label: 'Forecast End Date'
ProjectWBSElement.ForecastedEndDate as ForecastedEndDate,
@EndUserText.label: 'Forecast Earliest Start Date'
ProjectWBSElement.SchedldFcstdEarliestStartDate as SchedldFcstdEarliestStartDate,
@EndUserText.label: 'Forecast Earliest End Date'
ProjectWBSElement.SchedldFcstdEarliestEndDate as SchedldFcstdEarliestEndDate,
@EndUserText.label: 'Forecast Latest Start Date'
ProjectWBSElement.LatestSchedldFcstdStartDate as LatestSchedldFcstdStartDate,
@EndUserText.label: 'Forecast Latest End Date'
ProjectWBSElement.LatestSchedldFcstdEndDate as LatestSchedldFcstdEndDate,
@EndUserText.label: 'Forecast Duration'
@Semantics.quantity.unitOfMeasure: 'ForecastedDurationUnit'
ProjectWBSElement.ForecastedDuration as ForecastedDuration,
@EndUserText.label: 'Forecast Duration Unit'
@Semantics.unitOfMeasure: true
ProjectWBSElement.ForecastedDurationUnit as ForecastedDurationUnit,
ProjectWBSElement.WBSElementIsPlanningElement as WBSElementIsPlanningElement,
ProjectWBSElement.WBSIsAccountAssignmentElement as WBSIsAccountAssignmentElement,
ProjectWBSElement.WBSElementIsBillingElement as WBSElementIsBillingElement,
@EndUserText.label: 'Cost Center to which costs are posted'
ProjectWBSElement.CostCenter as CostCenter,
ProjectWBSElement.ResponsibleCostCenter as ResponsibleCostCenter,
cast( _ResponsibleCostCenter[1: ValidityEndDate >= $session.system_date
and ValidityStartDate <= $session.system_date ]._Text[1: Language = $session.system_language ].CostCenterName as ps_s4_respktext preserving type ) as ResponsibleCostCenterName,
//Status
case
when _Status.ConcatenatedActiveSystStsName is null
then ''
else _Status.ConcatenatedActiveSystStsName
end as ConcatenatedActiveSystStsName,
case
when _Status.ConcatenatedActiveUserStsName is null
then ''
else _Status.ConcatenatedActiveUserStsName
end as ConcatenatedActiveUserStsName,
//
@EndUserText.quickInfo: 'Project Definition'
@ObjectModel.text.element: ['ProjectDescription']
cast (_Project.ProjectExternalID as ps_pspid_edit preserving type) as ProjectExternalID,
@Semantics.text: true
_Project.ProjectDescription as ProjectDescription,
//User Fields
ProjectWBSElement.FreeDefinedAttribute01 as FreeDefinedAttribute01,
ProjectWBSElement.FreeDefinedAttribute02 as FreeDefinedAttribute02,
ProjectWBSElement.FreeDefinedAttribute03 as FreeDefinedAttribute03,
ProjectWBSElement.FreeDefinedAttribute04 as FreeDefinedAttribute04,
@Semantics.unitOfMeasure: true
ProjectWBSElement.FreeDefinedQuantity1Unit as FreeDefinedQuantity1Unit,
@Semantics.quantity.unitOfMeasure: 'FreeDefinedQuantity1Unit'
ProjectWBSElement.FreeDefinedQuantity1 as FreeDefinedQuantity1,
@Semantics.unitOfMeasure: true
ProjectWBSElement.FreeDefinedQuantity2Unit as FreeDefinedQuantity2Unit,
@Semantics.quantity.unitOfMeasure: 'FreeDefinedQuantity2Unit'
ProjectWBSElement.FreeDefinedQuantity2 as FreeDefinedQuantity2,
@Semantics.currencyCode: true
ProjectWBSElement.FreeDefinedAmount1Currency as FreeDefinedAmount1Currency,
@Semantics.amount.currencyCode: 'FreeDefinedAmount1Currency'
cast ( ProjectWBSElement.FreeDefinedAmount1 as abap.curr( 13, 2 ) ) as FreeDefinedAmount1,
@Semantics.currencyCode: true
ProjectWBSElement.FreeDefinedAmount2Currency as FreeDefinedAmount2Currency,
@Semantics.amount.currencyCode: 'FreeDefinedAmount2Currency'
cast ( ProjectWBSElement.FreeDefinedAmount2 as abap.curr( 13, 2 ) ) as FreeDefinedAmount2,
ProjectWBSElement.FreeDefinedDate1 as FreeDefinedDate1,
ProjectWBSElement.FreeDefinedDate2 as FreeDefinedDate2,
ProjectWBSElement.FreeDefinedIndicator1 as FreeDefinedIndicator1,
ProjectWBSElement.FreeDefinedIndicator2 as FreeDefinedIndicator2,
_FieldKeyLabel.FreeDefinedAttribute01Label as FreeDefinedAttribute01Label,
_FieldKeyLabel.FreeDefinedAttribute02Label as FreeDefinedAttribute02Label,
_FieldKeyLabel.FreeDefinedAttribute03Label as FreeDefinedAttribute03Label,
_FieldKeyLabel.FreeDefinedAttribute04Label as FreeDefinedAttribute04Label,
_FieldKeyLabel.FreeDefinedQuantity1Label as FreeDefinedQuantity1Label,
_FieldKeyLabel.FreeDefinedQuantity2Label as FreeDefinedQuantity2Label,
_FieldKeyLabel.FreeDefinedAmount1Label as FreeDefinedAmount1Label,
_FieldKeyLabel.FreeDefinedAmount2Label as FreeDefinedAmount2Label,
_FieldKeyLabel.FreeDefinedDate1Label as FreeDefinedDate1Label,
_FieldKeyLabel.FreeDefinedDate2Label as FreeDefinedDate2Label,
_FieldKeyLabel.FreeDefinedIndicator1Label as FreeDefinedIndicator1Label,
_FieldKeyLabel.FreeDefinedIndicator2Label,
_Project,
_ProjectApplicant,
_ResponsibleCostCenter,
_Plant,
_ProfitCenter
}
where
WBSElementObject like 'PR%'
or WBSElementObject like 'V2%'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_PROJECTFORNETWORKGRAPH",
"I_BUSINESSAREA",
"I_BUSINESSAREATEXT",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_CONTROLLINGOBJECTCLASS",
"I_CONTROLLINGOBJECTCLASST",
"I_COSTCENTER",
"I_COSTCENTERTEXT",
"I_FREEDFNDTBLFIELDSEMANTICTEXT",
"I_PLANT",
"I_PRIORITYCODE",
"I_PRIORITYCODETEXT",
"I_PROFITCENTER",
"I_PROFITCENTERTEXT",
"I_PROJECTOBJECTSHORTTEXT",
"I_PROJECTTYPE",
"I_PROJECTTYPETEXT",
"I_STSOBJCONCATACTIVESTSILL",
"I_WBSELEMENTBYINTERNALKEY"
],
"ASSOCIATED":
[
"C_PROJECTFORNETWORKGRAPH",
"I_COSTCENTER",
"I_FREEDFNDTBLFIELDSEMANTICTEXT",
"I_PLANT",
"I_PROFITCENTER",
"I_PROJECTAPPLICANT",
"I_STSOBJCONCATACTIVESTSILL"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/Learn More
- What Is a CDS View in SAP S/4HANA?
- Types of CDS Views: Basic, Composite, Consumption, and Transactional
- SAP Tables vs CDS Views — Key Differences
- Understanding Data Lineage in SAP S/4HANA
- VDM (Virtual Data Model) in SAP S/4HANA Explained
- CDS View Annotations — A Complete Guide
- CDS View Field Mapping and Associations
- Understanding the SAP S/4HANA Data Model
- CDS View Extensions and Custom Fields in SAP S/4HANA
- Released APIs and Stability Contracts in SAP S/4HANA