C_TranspChargeCalcBase

@EndUserText:   {label:             'Transportation Charge Calculation Base'}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog:   {sqlViewName:        'CTCCBASE',
                 compiler.compareFilter: true,
                 preserveKey:        true                }
@ObjectModel:   {representativeKey:  'TranspChrgCalcBaseUUID',
                 usageType:          { serviceQuality: #C,
                                       sizeCategory:   #XXL,
                                       dataClass:      #MIXED}}
@AccessControl: {authorizationCheck: #PRIVILEGED_ONLY,
                 personalData.blocking:#NOT_REQUIRED}
@VDM:           {viewType:          #CONSUMPTION}
@Metadata.allowExtensions: true
define view C_TranspChargeCalcBase
  as select from I_TranspChargeCalcBase
  /* Business Object related Node Associations*/
  association [1..1] to C_TranspChargeItemElement as _TranspChargeItemElement on $projection.TranspChargeItemElementUUID = _TranspChargeItemElement.TranspChargeItemElementUUID
{
  key TranspChrgCalcBaseNodeUUID,
  key TranspChrgCalcBaseUUID,
      TranspChargeItemElementUUID,
      TransportationChargesObjUUID,
      @ObjectModel.text.element: ['TranspCalculationBaseText']
      cast(TranspChrgCalculationBase as /scmtms/vdm_calc_base_dim)                                                                 as TranspChrgCalculationBase,
      @Semantics.text: true
      _TranspCalculationBase._Text[1: Language = $session.system_language].TranspCalculationBaseText,
      @Consumption.filter.hidden: true
      TranspScaleItemQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspScaleItemQuantityUnit'
      cast( TranspScaleItemQuantity as /scmtms/quantity_13_3)                                                                      as TranspScaleItemQuantity,
      TranspDataSourceQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspDataSourceQtyUnit'
      cast( TranspDataSourceQuantity as /scmtms/quantity_13_3)                                                                     as TranspDataSourceQuantity,
      TranspDataSourceQtyIsNumeric,

      cast( case
        when TranspScaleItemQtyIsNumeric = 'X' and TranspChrgCalculationBase = 'DAYS'
             then concat(cast(cast(TranspScaleItemQuantity as /scmtms/quantity_13_3 ) as abap.char( 33 )), TranspChrgCalculationBase )
        when TranspScaleItemQtyIsNumeric = 'X' and TranspChrgCalculationBase <> 'DAYS'
             then concat(cast(cast(TranspScaleItemQuantity as /scmtms/quantity_13_3 ) as abap.char( 33 )), TranspScaleItemQuantityUnit )
        when TranspScaleItemQtyIsCurrency = 'X'
             then concat(cast(TranspScaleItemAmount as abap.char( 33 )), TranspScaleItemCurrency )
        else
             TranspScaleItemQtyChar
        end                                                                                            as /scmtms/vdm_scale_value) as TranspScaleItemValue,

      cast( case
       when TranspDataSourceQtyIsNumeric = 'X' and TranspChrgCalculationBase = 'DAYS'
            then concat(cast(cast( TranspDataSourceQuantity as /scmtms/quantity_13_3 ) as abap.char( 33 )), TranspChrgCalculationBase )
       when TranspDataSourceQtyIsNumeric = 'X' and TranspChrgCalculationBase <> 'DAYS'
            then concat(cast(cast( TranspDataSourceQuantity as /scmtms/quantity_13_3 ) as abap.char( 33 )), TranspDataSourceQtyUnit )
       when TranspDataSourceQtyIsCurrency = 'X'
            then concat(cast(TranspDataSourceAmount as abap.char( 33 )), TranspDataSourceCurrency )
       else
            TranspDataSourceQtyChar
       end                                                                                      as /scmtms/vdm_data_src_value)     as TranspDataSourceValue,

      /* Associations */
      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT]
      _TranspChargeItemElement,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT]
      _TranspChargeObject
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_TRANSPCALCULATIONBASE",
"I_TRANSPCALCULATIONBASETXT",
"I_TRANSPCHARGECALCBASE"
],
"ASSOCIATED":
[
"C_TRANSPCHARGEITEMELEMENT",
"I_TRANSPCHARGEOBJECT"
],
"BASE":
[
"I_TRANSPCHARGECALCBASE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/