C_SupplyProtectionGroupTP

@VDM.viewType: #CONSUMPTION

@ObjectModel:   { usageType: { serviceQuality: #C,
                               sizeCategory:   #XL,
                               dataClass:      #MIXED }
}
@AccessControl.authorizationCheck: #CHECK
@Metadata.allowExtensions: true
@EndUserText.label: 'Supply Protection Group'
define view entity C_SupplyProtectionGroupTP
  as projection on I_SupplyProtectionGroupTP
{
  key SupplyProtectionGroupUUID,

      SupplyProtectionUUID,

      _SupplyProtectionTP.SupProtCharcCatalogType,
      _SupplyProtectionTP.CoreCharc01CtlgPathIntID,
      _SupplyProtectionTP.SupProtCoreCharc01CtlgPathUUID,
      //      _SupplyProtectionTP.SupProtCoreCharc01Text,

      _SupplyProtectionTP.SupProtCoreCharc01ValueID,
      _SupplyProtectionTP.CoreCharc02CtlgPathIntID,
      _SupplyProtectionTP.SupProtCoreCharc02CtlgPathUUID,
      //      _SupplyProtectionTP.SupProtCoreCharc02Text,

      _SupplyProtectionTP.SupProtCoreCharc02ValueID,

      SupProtCharc01CtlgPathUUID,
      SupProtCharc01ValueID,
      SupProtCharc02CtlgPathUUID,
      SupProtCharc02ValueID,
      SupProtCharc03CtlgPathUUID,
      SupProtCharc03ValueID,
      SupProtCharc04CtlgPathUUID,
      SupProtCharc04ValueID,
      SupProtCharc05CtlgPathUUID,
      SupProtCharc05ValueID,
      SupProtCharc06CtlgPathUUID,
      SupProtCharc06ValueID,
      SupProtCharc07CtlgPathUUID,
      SupProtCharc07ValueID,
      SupProtCharc08CtlgPathUUID,
      SupProtCharc08ValueID,
      SupProtCharc09CtlgPathUUID,
      SupProtCharc09ValueID,
      SupProtCharc10CtlgPathUUID,
      SupProtCharc10ValueID,

      SupProtGroupPriorityValue,

      CharcValAuthznGroup,

      @Semantics.unitOfMeasure: true
      UnitOfMeasure,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_ATP_SUP_SADL_EXIT_QTY_GRP'
      cast(SupProtProtectedQuantity as sup_protected_quantity preserving type )     as SupProtProtectedQuantity,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_ATP_SUP_SADL_EXIT_QTY_GRP'
      cast(SupProtConsumedQuantity as sup_consumed_quantity preserving type )       as SupProtConsumedQuantity,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_ATP_SUP_SADL_EXIT_QTY_GRP'
      cast(SupProtRemainingProtectedQty as sup_remaining_quantity preserving type ) as SupProtRemainingProtectedQty,


      @UI.hidden: true
      LastChangeDateTime, //necessary for the eTag handling


      /* Associations */
      _SupplyProtectionTP           : redirected to parent C_SupplyProtectionTP,
      _SupplyProtectionTimeBucketTP : redirected to composition child C_SupplyProtectionTimeBucketTP,
      _SupProtTimeBucketCnsmpnTP    : redirected to C_SupProtTimeBucketCnsmpnTP,
      _SupProtTimeBucketChart

}
where
  SupplyProtectionGroupIsBlocked = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SUPPLYPROTECTIONGROUPTP",
"I_SUPPLYPROTECTIONTP"
],
"ASSOCIATED":
[
"C_SUPPLYPROTECTIONTIMEBUCKETTP",
"C_SUPPLYPROTECTIONTP",
"C_SUPPROTTIMEBUCKETCNSMPNTP",
"I_SUPPLYPROTECTIONTIMEBUCKETTP",
"I_SUPPLYPROTECTIONTP",
"I_SUPPROTTIMEBUCKETCHART",
"I_SUPPROTTIMEBUCKETCNSMPNTP"
],
"BASE":
[
"I_SUPPLYPROTECTIONGROUPTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/