C_SupDmndOvwDmndItmQuery

@AbapCatalog: {
  sqlViewName: 'CSDODMNDITMQUERY',
  compiler.compareFilter: true
}
@ObjectModel:{
  usageType.serviceQuality: #D,
  usageType.sizeCategory: #XXL
  }
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
//@Analytics.query: true

@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Query View for Total Demand'
//@OData.publish: true

define view C_SupDmndOvwDmndItmQuery
  as select from    I_SupDmndOvwDmndItmCube   as Demand
    left outer join I_SalesOrganizationText   as SalesOrgText on  Demand.SalesOrganization = SalesOrgText.SalesOrganization
                                                              and SalesOrgText.Language    = $session.system_language
    left outer join I_MaterialText            as MaterialText on  Demand.Material       = MaterialText.Material
                                                              and MaterialText.Language = $session.system_language
    left outer join I_MaterialGroupText       as MatGrpText   on  Demand.MaterialGroup  = MatGrpText.MaterialGroup
                                                              and MatGrpText.Language   = $session.system_language
                                                              and MaterialText.Language = $session.system_language
    left outer join I_DistributionChannelText as DistChl      on  Demand.DistributionChannel = DistChl.DistributionChannel
                                                              and DistChl.Language           = $session.system_language
    left outer join I_DivisionText            as Div          on  Demand.Division = Div.Division
                                                              and Div.Language    = $session.system_language
    left outer join I_SalesDistrictText       as SalesDist    on  Demand.SalesDistrict = SalesDist.SalesDistrict
                                                              and SalesDist.Language   = $session.system_language
    left outer join I_Plant                   as Plant        on Demand.Plant = Plant.Plant
    left outer join I_CompanyCode             as CompanyCode  on Demand.CompanyCode = CompanyCode.CompanyCode
{
  @EndUserText.label: 'Requirement Document Number'
  key RequirementDocumentNumber,
  @EndUserText.label: 'Requirement Document Item'
  key RequirementDocumentItem,
  
  //      @EndUserText.label: 'Requested Date'

  //  key RequestedDate,

  //  key ProductAvailabilityDate,

  @EndUserText.label: 'Requirement Type'
  key RequirementType,
  key Demand.Material,
  key Demand.Plant,
  key StorageLocation,
  key CalendarMonth,
  @EndUserText.label: 'Week'
  key CalendarWeek,
  @EndUserText.label: 'Year'
  key CalendarYear,
  @EndUserText.label: 'Delivered Quantity'
  @DefaultAggregation: #SUM
  DeliveredQuantityInBaseUnit,
  @EndUserText.label: 'Order Quantity'
  @DefaultAggregation: #SUM
  RequestedRqmtQtyInBaseUnit,
  @EndUserText.label: 'Confirmed Quantity'
  @DefaultAggregation: #SUM
  ConfirmedRqmtQtyInBaseUnit,
  @EndUserText.label: 'Open Demand Quantity'
  @DefaultAggregation: #SUM
  OpenDemandQuantity,
  @EndUserText.label: 'Requirement Type Name'
  RequirementTypeName,
  @EndUserText.label: 'Document Type'
  OrderType,
  Demand.SalesOrganization,
  Demand.DistributionChannel,
  RequestedDeliveryDate,
  SoldToParty,
  ShipToParty,
  @EndUserText.label: 'Company Code'
  Demand.CompanyCode,
  //  FashionCustomerGroup6,

  //  FashionCustomerGroup7,

  //  FashionCustomerGroup8,

  //  FashionCustomerGroup9,

  //  FashionCustomerGroup10,

  PartnerFunction,
  SalesDocumentItemCategory,
  Demand.Division,
  Demand.MaterialGroup,
  BaseUnit,
  DeliveryGroup,
  ItemBillingBlockReason,
  @DefaultAggregation: #SUM
  NetAmount,
  DocumentCurrency,
  ShippingPoint,
  //      route,

  @DefaultAggregation: #SUM
  NetPriceAmount,
  @DefaultAggregation: #SUM
  NetPriceQuantity,
  @Feature:'SW:RFM_SEGMTN_UI'
  RequirementSegment,
  @Feature:'SW:RFM_SEASON_UI'
  ProductSeasonYear,
  @Feature:'SW:RFM_SEASON_UI'
  ProductSeason,
  @Feature:'SW:RFM_SEASON_UI'
  ProductCollection,
  @Feature:'SW:RFM_SEASON_UI'
  ProductTheme,
  @Feature:'SW:RFM_CANC_DTE_UI'
  FashionCancelDate,
  ShippingGroupRule,
  ShippingGroupNumber,
  CustomerGroup,
  Demand.SalesDistrict,
  @EndUserText.label: 'Month'
  CalendarMonthName,
  @EndUserText.label: 'Total Assigned Quantity'
  @DefaultAggregation: #SUM
  AssignedQuantityInBaseUnit,
  @EndUserText.label: 'Normal Assigned Quantity'
  @DefaultAggregation: #SUM
  NormalAssignedQuantityInBsUnt,
  @EndUserText.label: 'Ready for Delivery Quantity'
  @DefaultAggregation: #SUM
  FixedQuantityInBaseUnit,
  //      @EndUserText.label: 'Reserved Quantity'

  //      @DefaultAggregation: #SUM

  //      SupAssgmtReservedQtyInBaseUnit,

  @EndUserText.label: 'On Hold Quantity'
  @DefaultAggregation: #SUM
  OnHoldQuantityInBaseUnit,
  @EndUserText.label: 'Open for Release Check Quantity'
  @DefaultAggregation: #SUM
  ReadyForReleaseQtyInBaseUnit,
  @EndUserText.label: 'IFO Assigned Quantity'
  @DefaultAggregation: #SUM
  InboundAssignedQuantityInBsUnt,
  @EndUserText.label: 'Ready for Delivery (Preview)'
  @DefaultAggregation: #SUM
  PreviewFixedAssignedQtyInBsUnt,
  @EndUserText.label: 'Reserved (Preview)'
  @DefaultAggregation: #SUM
  PreviewReservedAssgdQtyInBsUnt,
  @EndUserText.label: 'On Hold (Preview)'
  @DefaultAggregation: #SUM
  PreviewOnHoldAssgdQtyInBsUnt,
  @EndUserText.label: 'Open for Release Check (Preview)'
  @DefaultAggregation: #SUM
  PreviewRdyForReleaseQtyInBsUnt,
  @EndUserText.label: 'Preview Assigned Quantity'
  @DefaultAggregation: #SUM
  PreviewAssignedQuantityInBsUnt,
  @DefaultAggregation: #SUM
  RequestedQuantityInBaseUnit,
  @EndUserText.label: 'SDO Category'
  SupAssgmtCategory,
  @EndUserText.label: 'SDO Category'
  SupAssgmtCategoryName,
  //      @EndUserText.label: 'Order Status'

  //      SupAssgmtOrdStatusName,

  @EndUserText.label: 'Generic Material'
  CrossPlantConfigurableProduct,
  @EndUserText.label: 'Demand/Supply'
  SupAssgmtSource,
  @EndUserText.label: 'Demand/Supply'
  SupAssgmtSourceName,
  @EndUserText.label: 'Sales Document'
  SalesDocument,
  SalesOrgText.SalesOrganizationName,
  MaterialText.MaterialName,
  MatGrpText.MaterialGroupName,
  DistChl.DistributionChannelName,
  Div.DivisionName,
  SalesDist.SalesDistrictName,
  Plant.PlantName,
  CompanyCode.CompanyCodeName,
  @EndUserText.label: 'To be Delivered'
  @DefaultAggregation: #SUM
  ConfdDelivQtyInOrderQtyUnit
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_DISTRIBUTIONCHANNELTEXT",
"I_DIVISIONTEXT",
"I_MATERIALGROUPTEXT",
"I_MATERIALTEXT",
"I_PLANT",
"I_SALESDISTRICTTEXT",
"I_SALESORGANIZATIONTEXT",
"I_SUPDMNDOVWDMNDITMCUBE"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/