C_SubstanceTextTP

/*----------------------------------------------------------------------------------------------------------------------
    View for Multi Language Name(s) of a Substance
------------------------------------------------------------------------------------------------------------------------*/
@EndUserText.label: 'Substance Name'

@VDM.viewType: #CONSUMPTION

@AccessControl.authorizationCheck: #CHECK

@AbapCatalog: {
  sqlViewName:            'CSUBTP',
  compiler.compareFilter: true,
  preserveKey:            true 
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@Metadata: {
  allowExtensions: true
}

@ObjectModel: {
   dataCategory: #TEXT,
   transactionalProcessingDelegated: true,
   createEnabled:                    true,
   updateEnabled:                    true,
   deleteEnabled:                    true,
   representativeKey:                'SubstanceUUID',
   semanticKey:                      ['LanguageForEdit'],
   usageType: {
     dataClass:      #MASTER,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}

@UI.headerInfo:{
  typeName: 'Substance Name',
  //typeNamePlural: 'Substance Names',

  title: {
    label: 'Substance Names',
    value: 'SubstanceName'
  }
}
@UI.presentationVariant.sortOrder : {
  by: 'LanguageISOCode',
  direction: #ASC
  }

@Search.searchable: true
define view C_SubstanceTextTP
  as select from I_SubstanceTextTP as text

  association [1..1] to C_SubstanceQryTP as _Substance    on $projection.SubstanceUUID = _Substance.SubstanceUUID

  association [0..*] to I_LanguageText   as _LanguageText on $projection.Language = _LanguageText.Language
{

  key   text.SubstanceUUID,

        @ObjectModel.foreignKey.association: '_Language'
  key   text.Language,

        @Consumption.valueHelp: '_LanguageForEdit'
        @ObjectModel.text.element: ['LanguageName']
        text.LanguageForEdit                                                        as LanguageForEdit,

        @ObjectModel.readOnly: true
        @Search:
        {
          defaultSearchElement: true,
          ranking: #MEDIUM,
          fuzzinessThreshold: 0.8
        }
        _LanguageForEdit._Text[1: Language = $session.system_language].LanguageName as LanguageName,

        @ObjectModel.readOnly: true
        _LanguageForEdit.LanguageISOCode                                            as LanguageISOCode,

        @Semantics.text: true
        @Search:
        {
          defaultSearchElement: true,
          ranking: #HIGH,
          fuzzinessThreshold: 0.8
        }
        text.SubstanceName,

        /* Associations */
        @ObjectModel.association.type: [#TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT]
        _Substance,
        _Language,
        _LanguageForEdit,
        _LanguageText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LANGUAGE",
"I_LANGUAGETEXT",
"I_SUBSTANCETEXTTP"
],
"ASSOCIATED":
[
"C_SUBSTANCEQRYTP",
"I_LANGUAGE",
"I_LANGUAGETEXT"
],
"BASE":
[
"I_SUBSTANCETEXTTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/