C_StdEHSCtrlForIdentifyRisks

@AbapCatalog.sqlViewName: 'CSTDEHSCTRLIR'
@EndUserText.label: 'Standard EHS Control'
@AbapCatalog.preserveKey:true 
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK

@VDM.viewType: #CONSUMPTION

@ObjectModel.semanticKey: ['EHSControlInstanceUUID'] // this will make the title column bold in smart templates


@UI: {
  headerInfo: {
    typeName: 'Catalog Control',
    typeNamePlural: 'Catalog Controls'
  }
}

@Consumption.semanticObject: 'EHSControl'

// Client handling by session

@ClientHandling.algorithm: #SESSION_VARIABLE

// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #D,        // < 100 msec

                         sizeCategory:  #L,         // < 10.000.000

                         dataClass: #MIXED }

define view C_StdEHSCtrlForIdentifyRisks
  as select from I_EHSRiskControl
//    join         I_EHSControlImplmtnImageURL as _EHSControlImageURL on I_EHSRiskControl.EHSControlUUID = _EHSControlImageURL.EHSControlUUID

  association [1..1] to C_EHSRisksForIdentifyRisks as _EHSRisk                  on $projection.EHSRiskUUID = _EHSRisk.EHSRiskUUID
  association [0..*] to I_EHSCtrlTitleText         as _EHSControlTitleText      on $projection.EHSControlUUID = _EHSControlTitleText.EHSControlUUID
  association [0..*] to I_EHSCtrlCatalogText       as _EHSControlCatalogText    on $projection.ehscontrolcatalog = _EHSControlCatalogText.EHSControlCatalog
  association [0..*] to I_EHSCtrlImplmtnStatusText as _EHSControlImplmtnStatusText on $projection.EHSControlImplStatus = _EHSControlImplmtnStatusText.EHSControlImplStatus
{

  key EHSControlInstanceUUID,
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_EHSRiskStdVH', element: 'EHSRiskUUID' }}]      
      EHSRiskUUID,      
      _EHSRisk,
      _EHSRiskRoot,
      EHSRiskRevisionUUID,
      _EHSRiskRevision,

      //--[ GENERATED:012:GlBfhyFV7jY4i}8L6{LzUW

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_EHSControlStdVH',
                     element: 'EHSControlUUID' }
        }]
      // ]--GENERATED

      @ObjectModel.text.association: '_EHSControlTitleText'
      I_EHSRiskControl.EHSControlUUID,
      _EHSControl,

      @Semantics.imageUrl
      //_EHSControlImageURL.EHSControlImageURL,

      @ObjectModel: {
        readOnly: true,
        virtualElement: true,
        virtualElementCalculatedBy: 'ABAP:CL_EHFND_CTRL_IMAGE_EXIT'
      }
      cast('' as text1024)                   as EHSControlImageURL,

      @ObjectModel.text.association: '_EHSControlImplmtnStatusText'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'C_EHSCtrlImplmtnStatusVH', element: 'EHSControlImplStatus' }}]      
      EHSControlImplStatus,
      _EHSCtrlImplementationStatus,

      @ObjectModel.text.association: '_EHSControlCatalogText'
      _EHSControl.EHSControlCatalog,

      _EHSControlTitleText,
      _EHSControlCatalogText,
      _EHSControlImplmtnStatusText

}
where
  I_EHSRiskControl.EHSControlIsAdhoc != 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EHSCONTROL",
"I_EHSRISKCONTROL"
],
"ASSOCIATED":
[
"C_EHSRISKSFORIDENTIFYRISKS",
"I_EHSCONTROL",
"I_EHSCTRLCATALOGTEXT",
"I_EHSCTRLIMPLMTNSTATUSTEXT",
"I_EHSCTRLIMPLSTATUS",
"I_EHSCTRLTITLETEXT",
"I_EHSRISKREVISION",
"I_EHSRISKROOT"
],
"BASE":
[
"I_EHSRISKCONTROL"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/