C_StRpWhldgTaxItmForClearing

@AbapCatalog.sqlViewName: 'CSRWHLDGTXCLR'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@AbapCatalog.preserveKey: true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Withholding Tax Open Line Items with clearing run status'
define view C_StRpWhldgTaxItmForClearing 
with parameters
    P_StatryRptgEntity:  srf_reporting_entity,
    P_StatryRptCategory: srf_rep_cat_id
as select from I_StRpJournalEntryLog as jourdocitm
                                      
inner join I_GLAccountLineItem on  I_GLAccountLineItem.CompanyCode = jourdocitm.CompanyCode
                               and I_GLAccountLineItem.AccountingDocument = jourdocitm.AccountingDocument
                               and I_GLAccountLineItem.FiscalYear = jourdocitm.FiscalYear                                      
{
    key jourdocitm.CompanyCode,
    key jourdocitm.AccountingDocument,
    key I_GLAccountLineItem.AccountingDocumentItem,
    key jourdocitm.FiscalYear,
    key jourdocitm.StatryRptgEntity,
    key jourdocitm.StatryRptCategory,
    key jourdocitm.StatryRptRunID,
        I_GLAccountLineItem.GLAccount,
        I_GLAccountLineItem.CompanyCodeCurrency,
     @DefaultAggregation: #SUM
     @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }    
        I_GLAccountLineItem.AmountInCompanyCodeCurrency,
        I_GLAccountLineItem._PostingKey.PostingKey,
        I_GLAccountLineItem.FinancialAccountType,
        I_GLAccountLineItem.DebitCreditCode,
        I_GLAccountLineItem.DocumentDate,
        I_GLAccountLineItem.PostingDate,
        I_GLAccountLineItem.FiscalPeriod,
        I_GLAccountLineItem.AccountingDocumentType,
        I_GLAccountLineItem.FiscalYearVariant,
        I_GLAccountLineItem.ClearingJournalEntry,
        I_GLAccountLineItem.AccountingDocumentCategory,
        I_GLAccountLineItem.ClearingDate,
        I_GLAccountLineItem.Ledger,
        I_GLAccountLineItem.IsOpenItemManaged,
        I_GLAccountLineItem.IsReversed,
        I_GLAccountLineItem.IsReversal,        
        I_GLAccountLineItem.TransactionTypeDetermination
        
}
where   jourdocitm.StatryRptgEntity = $parameters.P_StatryRptgEntity
    and    jourdocitm.StatryRptCategory = $parameters.P_StatryRptCategory
    and I_GLAccountLineItem.FinancialAccountType = 'S'
    and I_GLAccountLineItem.ClearingJournalEntry = ''
    and I_GLAccountLineItem.AccountingDocumentCategory <> 'D'
    and I_GLAccountLineItem.AccountingDocumentCategory <> 'M'
    and I_GLAccountLineItem.AccountingDocumentCategory <> 'O'
    and I_GLAccountLineItem.AccountingDocumentCategory <> 'J'
    and I_GLAccountLineItem.ClearingDate = '00000000'
    and I_GLAccountLineItem.Ledger = '0L'
    and I_GLAccountLineItem.IsOpenItemManaged = 'X'
    and I_GLAccountLineItem.IsReversed = ' '
    and I_GLAccountLineItem.IsReversal = ' '
    and ( I_GLAccountLineItem.TransactionTypeDetermination = 'WIT' )                 

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_GLACCOUNTLINEITEM",
"I_POSTINGKEY",
"I_STRPJOURNALENTRYLOG"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/