@AbapCatalog.sqlViewName: 'CSROVRDUEINVC'
@AbapCatalog.preserveKey:true
@VDM.viewType: #CONSUMPTION
@Analytics: { dataCategory: #CUBE }
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Overdue Invoices Cube for Stat.Reporting'
@Metadata.allowExtensions:true
define view C_StRpOverdueInvoicesCube with parameters
P_KeyDate : fipl_keydate
as select from I_OperationalAcctgDocItem // I_OperationalAcctgDocCube
association [0..*] to I_StRpJournalEntryLog as _ReportedItemsLog
on _ReportedItemsLog.CompanyCode = $projection.CompanyCode
and _ReportedItemsLog.AccountingDocument = $projection.AccountingDocument
and _ReportedItemsLog.FiscalYear = $projection.FiscalYear
{
@ObjectModel.foreignKey.association: '_CompanyCode'
key CompanyCode,
@ObjectModel.foreignKey.association: '_FiscalYear'
key FiscalYear,
key AccountingDocument,
key AccountingDocumentItem, // buzei
// ACR Part
key _ReportedItemsLog.StatryRptgEntity as StatryRptgEntity,
key _ReportedItemsLog.StatryRptCategory as StatryRptCategory,
key _ReportedItemsLog.StatryRptRunID as StatryRptRunID,
_JournalEntry.DocumentReferenceID,
@ObjectModel.foreignKey.association: '_AccountingDocumentType'
AccountingDocumentType,
DocumentDate,
PostingDate,
_JournalEntry.TaxReportingDate as TaxReportingDate,
@ObjectModel.foreignKey.association: '_Customer'
Customer,
_Customer.CustomerName,
@ObjectModel.foreignKey.association: '_Supplier'
Supplier,
_Supplier.SupplierName,
DueCalculationBaseDate,
NetDueDate,
PaymentTerms,
CashDiscount1Days,
CashDiscount2Days,
NetPaymentDays,
@DefaultAggregation: #MAX
CashDiscount1Percent,
@DefaultAggregation: #MAX
CashDiscount2Percent,
@ObjectModel.foreignKey.association: '_GLAccountInChartOfAccounts'
GLAccount,
@Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
AmountInTransactionCurrency,
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
AmountInCompanyCodeCurrency,
@ObjectModel.foreignKey.association: '_TransactionCurrency'
TransactionCurrency,
@ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
CompanyCodeCurrency,
@ObjectModel.foreignKey.association: '_DebitCreditCode'
DebitCreditCode, //SHKZG
TaxCode,
DocumentItemText,
//@todo
//@AnalyticsDetails.query.axis: #ROWS
//_JournalEntry.SettlementFiscalYearPeriod,
ClearingDate,
// Computed fields
// If the invoice is cleared: ClearingDate - NetDueDate.
// If the invoice is not cleared: KeyDate - NetDueDate.
dats_is_valid( ClearingDate ) as IsCleared,
case ClearingDate
when '00000000' then dats_days_between( NetDueDate, :P_KeyDate )
else dats_days_between( NetDueDate, ClearingDate )
end as NetDueArrearsDays,
dats_days_between( DueCalculationBaseDate, NetDueDate ) as NetDueDays,
// Associations
_CompanyCode,
_FiscalYear,
_AccountingDocumentType,
_ReportedItemsLog,
_DebitCreditCode,
_Customer,
_Supplier,
_JournalEntry,
_TransactionCurrency,
_CompanyCodeCurrency,
I_OperationalAcctgDocItem.ChartOfAccounts,
_GLAccountInChartOfAccounts
}
// Where ..
where ( FinancialAccountType = 'K' or FinancialAccountType = 'D' ) and
AccountingDocumentCategory <> 'D' and //BSTAT 'D' - recurring entry
AccountingDocumentCategory <> 'M' and //BSTAT 'M' - sample
AccountingDocumentCategory <> 'S' //BSTAT 'S' - noted
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMER",
"I_JOURNALENTRY",
"I_OPERATIONALACCTGDOCITEM",
"I_STRPJOURNALENTRYLOG",
"I_SUPPLIER"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENTTYPE",
"I_COMPANYCODE",
"I_CURRENCY",
"I_CUSTOMER",
"I_DEBITCREDITCODE",
"I_FISCALYEARFORCOMPANYCODE",
"I_GLACCOUNTINCHARTOFACCOUNTS",
"I_JOURNALENTRY",
"I_STRPJOURNALENTRYLOG",
"I_SUPPLIER"
],
"BASE":
[
"I_OPERATIONALACCTGDOCITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/