C_SrvcQtanProcFlowInformation

@EndUserText.label: 'Srvc Quotation Info for Transaction History'
@VDM: {
  viewType: #CONSUMPTION
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  semanticKey: ['ServiceQuotation'],
  representativeKey: 'ServiceQuotation',
  usageType: {serviceQuality: #C,
              sizeCategory: #XXL,
              dataClass: #TRANSACTIONAL}
}
@Metadata: {
  ignorePropagatedAnnotations: true
}
@ClientHandling: {
  algorithm: #SESSION_VARIABLE
}
@AbapCatalog: {
  sqlViewName: 'CSRVQTPRCFLWINF',
  compiler.compareFilter: true,
  preserveKey: true
}

define root view C_SrvcQtanProcFlowInformation
  with parameters @Consumption.hidden: true
                  @Environment.systemField: #SYSTEM_LANGUAGE
                  P_Language : spras
  as select from I_ServiceDocument

  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_SrvcMgmtObjectStatus as _SrvcMgmtObjectStatus on  $projection.ServiceDocumentUUID                      = _SrvcMgmtObjectStatus.SrvcMgmtObjectUUID
                                                                        and _SrvcMgmtObjectStatus.SrvcMgmtObjectStatusIsInactive = ''
                                                                        and (
                                                                           _SrvcMgmtObjectStatus.SrvcMgmtObjectStatus            = 'I1002'
                                                                           or _SrvcMgmtObjectStatus.SrvcMgmtObjectStatus         = 'I1003'
                                                                           or _SrvcMgmtObjectStatus.SrvcMgmtObjectStatus         = 'I1004'
                                                                           or _SrvcMgmtObjectStatus.SrvcMgmtObjectStatus         = 'I1005'
                                                                            )


{
  key ServiceDocument                  as ServiceQuotation,
      ServiceDocumentUUID,

      cast (case _SrvcMgmtObjectStatus.SrvcMgmtObjectStatus
              when 'I1002' then 'A'
              when 'I1003' then 'B'
              when 'I1005' then case ServiceDocumentIsRejected
                              when 'X' then 'E'
                              when ' ' then 'D'
                            end
              when 'I1004' then 'C'
            end as crms4_qtan_stat_lc) as ServiceQuotationStatus,

      PostingDate,

      // The following fields are required for authorization checks

      @Consumption.hidden: true
      ServiceObjectType,
      @Consumption.hidden: true
      ServiceDocumentType,
      @Consumption.hidden: true
      SalesOrganization,
      @Consumption.hidden: true
      SalesOffice,
      @Consumption.hidden: true
      SalesGroup,
      @Consumption.hidden: true
      DistributionChannel,
      @Consumption.hidden: true
      Division,
      @Consumption.hidden: true
      ResponsibleEmployee,
      @Consumption.hidden: true
      SalesOrganizationOrgUnitID,
      @Consumption.hidden: true
      SalesOfficeOrgUnitID,
      @Consumption.hidden: true
      SalesGroupOrgUnitID,
      @Consumption.hidden: true
      ServiceOrganization,
      
      //The following fields are required to map node title dinamically

      I_ServiceDocument._ServiceDocumentType._ServiceDocumentTypeText[1: Language = :P_Language].ServiceDocumentTypeName as ProcessFlowNodeTitle,
      I_ServiceDocument._ServiceDocumentType._ServiceDocumentTypeText[1: Language = :P_Language].ServiceDocumentTypeShortName as ProcessFlowNodeShortTitle
}
where
      ServiceObjectType          = 'BUS2000116'
  and ServiceDocumentIsQuotation = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENT",
"I_SERVICEDOCUMENTTYPE",
"I_SERVICEDOCUMENTTYPETEXT",
"I_SRVCMGMTOBJECTSTATUS"
],
"ASSOCIATED":
[
"I_SRVCMGMTOBJECTSTATUS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/